reinit the tree, so we can have metadata

4 files changed, 128 insertions, 0 deletions

diff --git a/dev-db/lmdb/Manifest b/dev-db/lmdb/Manifest
new file mode 100644
index 000000000000..3cfc223e2d26
--- /dev/null
+++ b/dev-db/lmdb/Manifest
@@ -0,0 +1,7 @@
+DIST LMDB_0.9.18.tar.gz 139156 SHA256 dd35b471d6eea84f48f2feece13d121abf59ef255308b8624a36223ffbdf9989 SHA512 394e88d99d446eb30771d7cf7a661584683a0d6d8e976cc561b5eecbb2a5d0817bbd59994002afa4eae6c86a39f05f50ebc2eff77cd70dd8c67225df4611f5e6 WHIRLPOOL 067fdb080edfc338885358c5cfef39a6ca9cdab8f49fd0f62bc68005e1f7dac9cd69fc87d130cf19f818906d090b906ea8b9716440358f33982e96e91ae4c049
+DIST LMDB_0.9.19.tar.gz 143141 SHA256 108532fb94c6f227558d45be3f3347b52539f0f58290a7bb31ec06c462d05326 SHA512 1d9825f09592ad92a540a1dec232cf6649f41cc67b0d59dc8958a71f4090f347c84995f32a166e2c2efecb862981f455814dd07af99bc3489e42fe3fd8bc6191 WHIRLPOOL 968546a1ba458c9686353a4f497c070fd2f01087de68e91d92ae98aae9e371871d90a03645cd35d40208d670bfe5113144038739db8b53f5a9b7ec1b5ec13b75
+EBUILD lmdb-0.9.18.ebuild 1247 SHA256 66384181376e4ecf948286bea0be4eea5d389cc427441afc5876ed609682215f SHA512 b75fb4c52e5128665f29e6e0fbf977c1c01f55f56dcb9322888d8fcb25b07b1b32e6a9f337d2bf768a2a982a82d25872ed8617822d718d818cd832c26949e936 WHIRLPOOL 01cfd89509a807fad6c45f172052225a17f2913a4c2ca751fd7b245258e3dc36174d0fd85558900588e0e03e2591807ef0306aef1c49499083722f41ec38cd63
+EBUILD lmdb-0.9.19.ebuild 1754 SHA256 63411754ee3c0796fe845d465bb4ffed4a8a44a5bdcc342a864d0633fda79dc0 SHA512 92d6c497f1b60fda20edb7bfec617611b7310d0b008a6cb6253dd89fbbabc8a833ce2c0403922e1503714237b972e699e9994788277fecd1bb174664c366735f WHIRLPOOL 47193e85d94af70c4772647f77f2862cdc1efd96ad443b27c82c034af5383bd95fa03959be475d83394e417b34f29ee4e2ebe08245af869d672ab76c2ffffdff
+MISC ChangeLog 6409 SHA256 10e2bcf22a5d662da0fb1724ee9bcce2bb0dc2e6f8a5d2f2dd5f387d0bcf0a63 SHA512 a762689de509be2fbee0f18eb022ccd4da64bbdb669dcbf32d05db76f330ab41f34c153cdc5b930a7f15a07f0e871a16bf31a5e29dbb0370e6fe917c54800495 WHIRLPOOL 77ced34b779fcc62c354bec652e57487c37dba2b624d97b6e397752249a91e5b9e53d0722ed6dcbac9fd40de1b9597a61748d0177bf90f400063e260252be91a
+MISC ChangeLog-2015 2969 SHA256 c8be453c72fed6218ec06e0110e0ae0e4f0d2f1b7013075f791d687667f4b946 SHA512 2601794579e2081d9727ebef3f6af9f1e7a1f99683537a896149fde1d81c54a35279a9f6451e4b166daa0a74617d4bec9051011749f65882dee8311c5940cc1d WHIRLPOOL 5e11dddc945ecd8d212d33c3facb037714f5098c43072bb6324aef7bc5db47291eb6faa5fe2b0c401a3c13a64f2c6584c91c9e254b0cd2bf557f336908c60bb5
+MISC metadata.xml 540 SHA256 61eb9f33306e258f3c4e432818e0c17113d38e847d9e90026cbf490075c2bccc SHA512 7ff1fddaca73c5d7b4a6a9ada9a7aad60e16c8c7063ad5cd9cf57301f504f6e0fe53bf568dec83abf522c2c099d2b3b2463619df17077ebaa3b39bd67bd738c4 WHIRLPOOL c412ead07298b9f6996feec6851deab4b97222105543256ff93ea5836babe61627c88ac92f68b66b3a7ea84a48b4f84e3fd975c6cb4a77afdbbe2f581f4fa902
diff --git a/dev-db/lmdb/lmdb-0.9.18.ebuild b/dev-db/lmdb/lmdb-0.9.18.ebuild
new file mode 100644
index 000000000000..6071b64f9718
--- /dev/null
+++ b/dev-db/lmdb/lmdb-0.9.18.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit toolchain-funcs
+
+DESCRIPTION="An ultra-fast, ultra-compact key-value embedded data store"
+HOMEPAGE="http://symas.com/mdb/"
+SRC_URI="https://github.com/LMDB/lmdb/archive/LMDB_${PV}.tar.gz"
+
+LICENSE="OPENLDAP"
+SLOT="0/${PV}"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ppc ppc64 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="static-libs"
+
+DEPEND=""
+# =net-nds/openldap-2.4.40 installs lmdb files.
+RDEPEND="!=net-nds/openldap-2.4.40"
+
+S="${WORKDIR}/${PN}-LMDB_${PV}/libraries/liblmdb"
+
+src_prepare() {
+	sed -i -e "s!^CC.*!CC = $(tc-getCC)!" \
+		-e "s!^CFLAGS.*!CFLAGS = ${CFLAGS}!" \
+		-e "s!^AR.*!AR = $(tc-getAR)!" \
+		-e "/^prefix/s!/usr/local!${EPREFIX}/usr!" \
+		-e "/^libdir/s!lib\$!$(get_libdir)!" \
+		-e "s!shared!shared -Wl,-soname,liblmdb.so.0!" \
+		"${S}/Makefile" || die
+}
+
+src_configure() {
+	:
+}
+
+src_compile() {
+	emake LDLIBS+=" -pthread"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	mv "${ED}"usr/$(get_libdir)/liblmdb.so{,.0} || die
+	dosym liblmdb.so.0 /usr/$(get_libdir)/liblmdb.so
+
+	use static-libs || rm "${ED}"usr/$(get_libdir)/liblmdb.a || die
+}
diff --git a/dev-db/lmdb/lmdb-0.9.19.ebuild b/dev-db/lmdb/lmdb-0.9.19.ebuild
new file mode 100644
index 000000000000..c4452f3a228f
--- /dev/null
+++ b/dev-db/lmdb/lmdb-0.9.19.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit toolchain-funcs flag-o-matic multilib
+
+DESCRIPTION="An ultra-fast, ultra-compact key-value embedded data store"
+HOMEPAGE="http://symas.com/mdb/"
+SRC_URI="https://github.com/LMDB/lmdb/archive/LMDB_${PV}.tar.gz"
+
+LICENSE="OPENLDAP"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+DEPEND=""
+# =net-nds/openldap-2.4.40 installs lmdb files.
+RDEPEND="!=net-nds/openldap-2.4.40"
+
+S="${WORKDIR}/${PN}-LMDB_${PV}/libraries/liblmdb"
+
+src_prepare() {
+	local soname="-Wl,-soname,liblmdb$(get_libname 0)"
+	[[ ${CHOST} == *-darwin* ]] && \
+		soname="-dynamiclib -install_name ${EPREFIX}/usr/$(get_libdir)/liblmdb$(get_libname 0)"
+	sed -i -e "s!^CC.*!CC = $(tc-getCC)!" \
+		-e "s!^CFLAGS.*!CFLAGS = ${CFLAGS}!" \
+		-e "s!^AR.*!AR = $(tc-getAR)!" \
+		-e "s!^SOEXT.*!SOEXT = $(get_libname)!" \
+		-e "/^prefix/s!/usr/local!${EPREFIX}/usr!" \
+		-e "/^libdir/s!lib\$!$(get_libdir)!" \
+		-e "s!shared!shared ${soname}!" \
+		"${S}/Makefile" || die
+	eapply_user
+}
+
+src_configure() {
+	if [[ ${CHOST} == *-solaris* ]] ; then
+		# ensure sigwait has a second sig argument
+		append-cppflags -D_POSIX_PTHREAD_SEMANTICS
+	fi
+}
+
+src_compile() {
+	emake LDLIBS+=" -pthread"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	mv "${ED}"usr/$(get_libdir)/liblmdb$(get_libname) \
+		"${ED}"usr/$(get_libdir)/liblmdb$(get_libname 0) || die
+	dosym liblmdb$(get_libname 0) /usr/$(get_libdir)/liblmdb$(get_libname)
+
+	use static-libs || rm "${ED}"usr/$(get_libdir)/liblmdb.a || die
+}
diff --git a/dev-db/lmdb/metadata.xml b/dev-db/lmdb/metadata.xml
new file mode 100644
index 000000000000..160bf60c274e
--- /dev/null
+++ b/dev-db/lmdb/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<longdescription lang="en">
+	An ultra-fast, ultra-compact key-value embedded data store
+</longdescription>
+	<maintainer type="person">
+		<email>eras@gentoo.org</email>
+		<name>Eray Aslan</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>ldap-bugs@gentoo.org</email>
+		<name>Gentoo LDAP Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">LMDB/lmdb</remote-id>
+	</upstream>
+</pkgmetadata>