gentoo resync : 28.04.2019

1 files changed, 59 insertions, 0 deletions

diff --git a/app-text/xchm/xchm-1.29.ebuild b/app-text/xchm/xchm-1.29.ebuild
new file mode 100644
index 000000000000..8a1516c32201
--- /dev/null
+++ b/app-text/xchm/xchm-1.29.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER="3.0-gtk3"
+inherit autotools wxwidgets xdg-utils
+
+DESCRIPTION="Utility for viewing Compiled HTML Help (CHM) files"
+HOMEPAGE="https://github.com/rzvncj/xCHM/"
+SRC_URI="${HOMEPAGE}releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="nls"
+
+RDEPEND="
+	>=dev-libs/chmlib-0.36
+	x11-libs/wxGTK:${WX_GTK_VER}[X]
+	nls? ( virtual/libintl )
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+src_prepare() {
+	setup-wxwidgets
+	default
+	eautoreconf # Still needed on the next release?
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS README ChangeLog
+
+	cp "${D}"/usr/share/pixmaps/xchm-32.xpm "${D}"/usr/share/pixmaps/xchm.xpm
+	rm -f "${D}"/usr/share/pixmaps/xchm-*.xpm
+	rm -f "${D}"/usr/share/pixmaps/xchmdoc*.xpm
+
+	domenu "${FILESDIR}"/xchm.desktop
+	insinto /usr/share/mime/packages
+	doins "${FILESDIR}"/xchm.xml
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}