gentoo resync : 07.10.2018

2 files changed, 97 insertions, 0 deletions

diff --git a/app-text/qpdfview/Manifest b/app-text/qpdfview/Manifest
index b41fa39dff49..4c5a7d40fe40 100644
--- a/app-text/qpdfview/Manifest
+++ b/app-text/qpdfview/Manifest
@@ -3,5 +3,6 @@ DIST qpdfview-0.4.18_pre2.tar.gz 668677 BLAKE2B 1c79a7f9f9d67c533660457ca74d27c1
 DIST qpdfview-0.4.18_pre3.tar.gz 747794 BLAKE2B 08420a350ae6f8bba65efe2a930a8941a00182900e33266a03d9b6ded4b8ba7ac446de9ed8095f8876dfd3ecfb26b20cc146c82d9c9228fd5c136ad36d749061 SHA512 c72f766b0ffb175e0577f08975490b985e859cb41ccf1d6bcdb618664b96b3c4d0fe4ffab2e493ac20b87b85aa658f3beb5b0d430d21deae78df4c503649f1c0
 EBUILD qpdfview-0.4.16.ebuild 2137 BLAKE2B d0ce86840680b56afd8b925b820d0641a0754776d4054b469c691f5da10db072febd5b04b34b80394bc08f47d6b5b7b58390332c30d445116528cbc238fe2144 SHA512 2d89740ee569287794935eb369c8a035a3ceeceb3e428e740f0b0adbe808f532a336dae9739c789bd4ee71b1a7f87af222ce91c19028bb179275184607489549
 EBUILD qpdfview-0.4.18_pre2.ebuild 2351 BLAKE2B aa38b631649b7d03be1a6e1df550cce81f44fe721d8b874b225ce6414a749a96dedc585b4d4482224d23c56cb2176c530e02bd47dc74ebdc45718642c8c39f28 SHA512 1c49e2ce7d9fedbbed5ea45b550403a11c68035d5943361d901b9df33c357c730d1b46ab66de6783576bcb562f64eeee61a9ca3857a93aa9759d4c756d98dbf6
+EBUILD qpdfview-0.4.18_pre3-r1.ebuild 2392 BLAKE2B 9b8d9bf46515c2e77b85fb0dbf6bbcc183c9bf8e2c0b0c837bb1442634885770806285c35094e91439da58482176a77deea8a0addbd9842804509b1aea3fd9bb SHA512 930ef2979ac45d7beb67b8da2074d476c393a00e0054e0a045ea14b62825688d53b19047faa57ac12ed155b46bfc6833fbdc93eddba5ecd9bcf7ac63dce707fe
 EBUILD qpdfview-0.4.18_pre3.ebuild 2388 BLAKE2B 17cea66141ca629186a310ff101e138a57ddb995b46df94d834524be2b0fa4a565973715022bb5adfa19dbc9423c742bf91ba2b7b08c7fb9d88873aa4658a5ad SHA512 52b2f4ea6c8c4a5a5eb673613c6e4cea1e503280f63093e5044c247724507495d633f673712a1bdc7743cb4c0f1f63a4922f9cedcd0b316db9e80c4d71c0e5ec
 MISC metadata.xml 534 BLAKE2B db66db041dd0875c8d4e36e3223d7f82263555f2d6a1dcc5270279b3fc8bc77499712253d43b56e278187f163af0495ca9e7e6aa0ba0dc8e9a5fe9cf7f2daf99 SHA512 e086f5e92c5ad9058f13c23c814a5cdc988a09cdbebecb1018b59d32a756dc2766b13ee1c3e09966cc7e221cc1c4ee26f9bf11c50610f94b28c20a34c316f133
diff --git a/app-text/qpdfview/qpdfview-0.4.18_pre3-r1.ebuild b/app-text/qpdfview/qpdfview-0.4.18_pre3-r1.ebuild
new file mode 100644
index 000000000000..a6c1da2e0daa
--- /dev/null
+++ b/app-text/qpdfview/qpdfview-0.4.18_pre3-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PLOCALES="ast az be bg bs ca cs da de el en_AU en_GB eo es eu fa fi fr gl he hr hu id it ja kk ko ku ky lt lv ms my nb nds oc pl pt pt_BR ro ru sk sr sv th tr ug uk uz vi zh_CN zh_TW"
+
+inherit l10n qmake-utils xdg-utils gnome2-utils
+
+DESCRIPTION="A tabbed document viewer"
+HOMEPAGE="https://launchpad.net/qpdfview"
+SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="cups +dbus djvu fitz +pdf postscript +sqlite +svg synctex"
+
+REQUIRED_USE="?? ( fitz pdf )"
+
+RDEPEND="
+	cups? ( net-print/cups )
+	djvu? ( app-text/djvu )
+	fitz? ( >=app-text/mupdf-1.7:= )
+	postscript? ( app-text/libspectre )
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5[cups?]
+	dev-qt/qtwidgets:5
+	dbus? ( dev-qt/qtdbus:5 )
+	pdf? ( >=app-text/poppler-0.35[qt5]
+		dev-qt/qtxml:5 )
+	sqlite? ( dev-qt/qtsql:5[sqlite] )
+	svg? ( dev-qt/qtsvg:5 )
+	!svg? ( virtual/freedesktop-icon-theme )
+	synctex? ( app-text/texlive-core )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+DOCS=( CHANGES CONTRIBUTORS README TODO )
+
+src_prepare() {
+	local mylrelease="$(qt5_get_bindir)"/lrelease
+
+	prepare_locale() {
+		"${mylrelease}" "translations/${PN}_${1}.ts" || die "preparing ${1} locale failed"
+	}
+
+	rm_help() {
+		rm -f "help/help_${1}.html" || die "removing ${1} help file failed"
+	}
+
+	l10n_find_plocales_changes translations ${PN}_ .ts
+	l10n_for_each_locale_do prepare_locale
+	l10n_for_each_disabled_locale_do rm_help
+
+	# adapt for prefix
+	sed -i -e "s:/usr:${EPREFIX}/usr:g" qpdfview.pri || die
+
+	default
+}
+
+src_configure() {
+	local myconfig=() i=
+	for i in cups dbus djvu pdf svg synctex; do
+		use ${i} || myconfig+=(without_${i})
+	done
+	use fitz && myconfig+=(with_fitz)
+	use postscript || myconfig+=(without_ps)
+	use sqlite || myconfig+=(without_sql)
+
+	local myqmakeargs=(
+		qpdfview.pro
+		CONFIG+="${myconfig[@]}"
+		PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}"
+	)
+	eqmake5 "${myqmakeargs[@]}"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}