gentoo auto-resync : 13:04:2023 - 23:44:17

3 files changed, 141 insertions, 2 deletions

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index f2d508930ccd..890999cd6fc1 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -7,8 +7,11 @@ DIST poppler-23.02.0.tar.xz 1847612 BLAKE2B ca5187432c5088372f0b8f4fcd39a93998b2
 DIST poppler-23.02.0.tar.xz.sig 833 BLAKE2B 48b46b92d8d95f25a0619aaa50c29c652e91ba99c5f8d5f30cbb879a2145e3a21df0258585ee9e44d036f4a8c1d54023e1bb22aa0d90bf69403b37c601b37ef2 SHA512 68fe9d46ec6f7f1b6d0d7becf96675477454af9218ad20ad159d8a06def73f08db59915adbb77b520e3e43091aaf895e045c7ccaafb57d2b2b9390e84e70a963
 DIST poppler-23.03.0.tar.xz 1849324 BLAKE2B 1247b7cf62466f65c46b739f0784e8ba97911940e04f91a7db28bf0663c8fe182f79066aa3925cb338580ccedbf17aecd2a2d2795e859680d1fb721390a1cbe0 SHA512 1c370d9262141ff5b720a4c3cf6f01573047398f8950295e3e99f32700946e3241e26e3d909cf78a278fc402306811fd87977d0f86a744f3eaedb4f39b8e8a2c
 DIST poppler-23.03.0.tar.xz.sig 833 BLAKE2B a8a07aac9068a3edc6cdce4d59c2b5d3d792dd6addcd420d5b92f013041cfd934c0da04a21eabefdd25167fb89b940945f8ca03e7a7280d03a47b6df8490bdf4 SHA512 3d950ff4b1a368b6edd8333677d1d125f60b4b1a052e20a2be6a0d38489e7af393be8359fc2c75010b2a28673e201507da4bf4c8458904fa712247d8ebda4786
+DIST poppler-23.04.0.tar.xz 1853488 BLAKE2B a26003f6bc642c03580d61999ae7e1c1756b2f602f697b372faaab99df7b5ddec843d93da3593d0388bc8a49d19ef00fc0e780d5297d77032afa77709a1f8372 SHA512 83580d42c79c6c5d08c686f764710bf08c6919b3707015ab3423c6f2a7fb711d53dde51b301148e14dba90a6f4d69bb6a3e0c8c47c1534047b0ce91be18d87ef
+DIST poppler-23.04.0.tar.xz.sig 833 BLAKE2B 65b1f18330ff1e7088e3e1d427b6cf06563c82ada67b7fa1f2d90655ffb264b2c3db54a34cd6d91fb610c939dd76bcd15d3731dcb3b3be4ed532a8fa6845d60a SHA512 a7786ecd9dd7c160bfcad56bff6ac04d4503b2e2ef4f84b66c5ac67732dd9102d6156b791f2e356825ba7fe315b5ec566797b58ac18e3ac86a7b944f422994b2
 EBUILD poppler-23.01.0.ebuild 3708 BLAKE2B e6447e3be63e3b1af49b2af667b50517c92a709c94cd08cd327115cd6700baaaa5471e37ab698b8e3ed4af8b3db5803629d9bce24c69808d650ee66cc41e6e3b SHA512 29a5be0b1b0afa6e577b76e57c9ab3955511d34a20542088b85586694de99554b6b5863e2e6dadc2b9e801c236a43389a8c06457583e43d8ff9a2b2e059e7782
 EBUILD poppler-23.02.0.ebuild 3716 BLAKE2B 05482bef3faa8fc5d9209434fc001947182c0a2d794a45abde054a96e309ac5d76e661270b072f920cf147e017cba30f1b51c6ec855e57d15caab89ee5df9d3a SHA512 dc312fcd662d945bf522fca4c05b8bab83d9ac251a7676a36ae1cfabca17982984cf551c25f51d9a04488ff1972641ac44f687f4f3cfa21f89cac50ad54403ff
 EBUILD poppler-23.03.0.ebuild 3716 BLAKE2B 05482bef3faa8fc5d9209434fc001947182c0a2d794a45abde054a96e309ac5d76e661270b072f920cf147e017cba30f1b51c6ec855e57d15caab89ee5df9d3a SHA512 dc312fcd662d945bf522fca4c05b8bab83d9ac251a7676a36ae1cfabca17982984cf551c25f51d9a04488ff1972641ac44f687f4f3cfa21f89cac50ad54403ff
-EBUILD poppler-9999.ebuild 3762 BLAKE2B 7fe4aae2e80923428d9d85fbe21d433183b71a1efab3ebf979fc7f8e60ab80494ddb9f97a2a992c71c185cd32266f45a8acc4bcdbf16df452e45fc08d8edc09b SHA512 c33415cdfdecceae571eadc5dd695dc9cef313603f8f0616626a853325f94a0c3af18f4499780212de97b3329369de37350f4efebed97f85f4b83c933d1f9b97
+EBUILD poppler-23.04.0.ebuild 3762 BLAKE2B 409ebee16ed41580dcb05a9ab78a9e24f6f91a2e7d0b6b08f16b68e721c87f5a19b53e0ff73dbdfb319147059426b93802a115800bb7eaa578d70760f384e85b SHA512 5743d8dfd6ffb10a124549eb28164e299c989a8fb52a241924751461f4eb089b814d2b59b8988221ee3c78bc64f0df86982896a2562d07bdd58cba0dddc0244c
+EBUILD poppler-9999.ebuild 3762 BLAKE2B 409ebee16ed41580dcb05a9ab78a9e24f6f91a2e7d0b6b08f16b68e721c87f5a19b53e0ff73dbdfb319147059426b93802a115800bb7eaa578d70760f384e85b SHA512 5743d8dfd6ffb10a124549eb28164e299c989a8fb52a241924751461f4eb089b814d2b59b8988221ee3c78bc64f0df86982896a2562d07bdd58cba0dddc0244c
 MISC metadata.xml 1078 BLAKE2B c5ce2245efedc75eb39a6c649d27698da0ac07b87da3240aeb9fea1435d48c3282a8a3bb9f002c78b79de2a518cb73f3eef563c05f41528bb55ffeca84409e13 SHA512 22c83f7f6a7632fc4fe94223be9e5edac085099bf5c0f6621b0179b16e35b98b0027e467e76c0ca365008d765258e05faf48dbc4b1e8d5eb507f348a533f88f6
diff --git a/app-text/poppler/poppler-23.04.0.ebuild b/app-text/poppler/poppler-23.04.0.ebuild
new file mode 100644
index 000000000000..353dacb709f7
--- /dev/null
+++ b/app-text/poppler/poppler-23.04.0.ebuild
@@ -0,0 +1,136 @@
+# Copyright 2005-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/aacid.asc
+	inherit verify-sig
+
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SLOT="0/127"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="boost cairo cjk curl +cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=media-libs/fontconfig-2.13
+	>=media-libs/freetype-2.10
+	sys-libs/zlib
+	cairo? (
+		>=dev-libs/glib-2.64:2
+		>=x11-libs/cairo-1.16
+		introspection? ( >=dev-libs/gobject-introspection-1.64:= )
+	)
+	curl? ( net-misc/curl )
+	jpeg? ( >=media-libs/libjpeg-turbo-1.1.0:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.49 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( app-text/poppler-data )
+"
+DEPEND="${COMMON_DEPEND}
+	boost? ( >=dev-libs/boost-1.71 )
+"
+BDEPEND="
+	>=dev-util/glib-utils-2.64
+	virtual/pkgconfig
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-aacid-20230313 )"
+fi
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-20.12.1-qt5-deps.patch"
+	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if tc-is-clang ; then
+		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	append-lfs-flags # bug #898506
+
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=OFF
+		-DBUILD_CPP_TESTS=OFF
+		-DBUILD_MANUAL_TESTS=OFF
+		-DRUN_GPERF_IF_PRESENT=OFF
+		-DENABLE_BOOST="$(usex boost)"
+		-DENABLE_ZLIB=ON
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_CMS=$(usex lcms lcms2 none)
+		-DWITH_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		$(cmake_use_find_package qt5 Qt5Core)
+		-DWITH_TIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+		-DENABLE_QT6=OFF
+	)
+	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}
diff --git a/app-text/poppler/poppler-9999.ebuild b/app-text/poppler/poppler-9999.ebuild
index 4834fad51161..353dacb709f7 100644
--- a/app-text/poppler/poppler-9999.ebuild
+++ b/app-text/poppler/poppler-9999.ebuild
@@ -16,7 +16,7 @@ else
 	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
 	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-	SLOT="0/126"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+	SLOT="0/127"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
 fi
 
 DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"