gentoo auto-resync : 08:12:2023 - 05:11:04

2 files changed, 159 insertions, 0 deletions

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 1b385280dbb0..78b476b1c67e 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -8,9 +8,12 @@ DIST poppler-23.10.0.tar.xz 1892152 BLAKE2B ce1b42d316e1d55567384fc5374af1a177f9
 DIST poppler-23.10.0.tar.xz.sig 833 BLAKE2B 74bdf5548afae23cf17037f3810765afd82a8d7f2a908e49144733adaae5f2eff0adce97aaa0945a40a324b293cb5f7f88b996e783390b26f7c360886c6bb41c SHA512 3c02270febea589d72d60e3fd0ffff2cb0be84ffcf5c8c66fd4461e64827614e08d9351176a6880d64558247cd722adc42343a7a5774eb331e55141bfb8f661c
 DIST poppler-23.11.0.tar.xz 1894712 BLAKE2B a5083e30c6d0e5494541f5fb7282390647fedf738bccbc99c246649fdee13166638507f314fd7b069af6aca5829319840883bd8d8f50fd4685c54c7ac6fe3b6b SHA512 0312472ff80c10aaec0c06e6bfd3f74257672c2001301db4d44e28051387ad5ddd8126d45e82c75ff4585cfde8e34a68bcab2d979aa58c904c60dc3efb1b6f3d
 DIST poppler-23.11.0.tar.xz.sig 833 BLAKE2B 50b0de45f56370aa493ba2929d5aaf6355ea8fd1a4fc3dc10e1fe6e58ba688d03d9867736814f6d5c6d452df820e2fb081e250fcda00255f533661022e75d887 SHA512 f3f743ff614b839f270ee1113ed728b0f1d390e2c2e53828b0a42573040b6e6b4edbcec2c6b3b198088474a89a24e3af9ccb8717bf37734222436dd8049a8d6e
+DIST poppler-23.12.0.tar.xz 1895580 BLAKE2B c63699d4ba62fd739b49cd94fd9510abedf9accc2f07cf2cd361da5fb561ce4289c3537343341defe3fb4fb31587a39b3967324e1f357799dc8b140f8c9eedbf SHA512 f28962f6842091a68edfb18e5f76e29fdf65d2a7cca6cb4be4202a35bab3e80a2dbe10b86ab8bc4fff7e555a077a41314b9892e19d0d7d89724b9ebb3db93852
+DIST poppler-23.12.0.tar.xz.sig 833 BLAKE2B b8dbbde8d6324fd65e583ad5eda04ae531ab364e3afd925c082ac102e6a00368b5c966a890e1b84089845f866b4afb324383d6d47e3d509356e2a5a857f4cdf9 SHA512 817ac3210a191535b037ebac78ebf4d67d3ac055cc54be2a0614ddaf757f6fa4aa5de4f1aecfd1a26a2290c190e14830a925fd83d102aca7afdd6e8fb1e98281
 DIST poppler-test-e3cdc82782941a8d7b8112f83b4a81b3d334601a.tar.bz2 5199251 BLAKE2B 6431b2aa4c60dec6202c737b4cfbbd4bf03808772c0adc6568454a04e713a2e869702f5c318e7799e7b1374252b5a956471b7cf6c9e2d6c8da5236e31a110f35 SHA512 bf5442601f453e601e0b368cc576bf0d5ca5509e9eecd8c7f0476802346834e9a9d3e0f32130c18d21807cd69a55e8168bca1cdb0292ad0215590a881a923c04
 EBUILD poppler-23.09.0.ebuild 4300 BLAKE2B 50d638a1313f901f0e12df981d6334e8692ef43505ecf4aae6affe1592ab76969ae750b9402249747ff15de2b7c259eeac1a1e5f42f1d9fe7f8475574def88e0 SHA512 18cbdce77f8d29af5d576742253836c7038968cc9a7efcd0beaa80c76796f432e14e2ff1372f50d18a66037895030180348ec7532e74a0af45090383e726fd4c
 EBUILD poppler-23.10.0.ebuild 4282 BLAKE2B dee9abb21878f0aec2d64ba8d29ac277ffbe2a87d32c4188746405e2cb7f28033d1a2d98c80db32d30c53e1654fa0a74f22c24965e72574dbd05d3392bfbab8e SHA512 c27abdf3006a59db903c1c9ee259e02f5db8537993cf366fb747a2d06ddbcffb81d685b40cd0280ece1feb9e5d362ccf79f1f9c4da17694517d4f38b9a4e8022
 EBUILD poppler-23.11.0.ebuild 4288 BLAKE2B 6382ea8c8905007c77efdb5f1632bf7d360522d5b8674fd2a82a963a056198230cfb9182c79cf417a2ed629dc39ee6912f2d1f2d98ee31a6c7b7c7e692133748 SHA512 8b41a4376af6cc2a7e87c6a453c06f1d3aa6a8b544f7a0fe6ec69ad9f309d3b95865ffed21e4874ca1b12b58f4e338fe0fa3f67f394a8fae30c0b657b3f56df5
+EBUILD poppler-23.12.0.ebuild 4385 BLAKE2B 5fdfb90b4e7d15a2ef26ecc985885f677c02918eff1c9f84065f376002d1a71fd9323cc5952ca54709aac873608502dbc6221e85b34a0a6f96819042f5ade0d2 SHA512 aed416dc9dd2c13358aada3c4a7e85cf57120dc07de52910bc1bd34c8e026b4670d214d0f3432103804efd6f5fb27d711550f8ef55c75c0aff33bee859f270ea
 EBUILD poppler-9999.ebuild 4385 BLAKE2B 5fdfb90b4e7d15a2ef26ecc985885f677c02918eff1c9f84065f376002d1a71fd9323cc5952ca54709aac873608502dbc6221e85b34a0a6f96819042f5ade0d2 SHA512 aed416dc9dd2c13358aada3c4a7e85cf57120dc07de52910bc1bd34c8e026b4670d214d0f3432103804efd6f5fb27d711550f8ef55c75c0aff33bee859f270ea
 MISC metadata.xml 1230 BLAKE2B e537b88babbb0c4ef5355c57c226d1c27b8b058e85c437962afe3610cf7dcdd4fea4a7694e508314cc5111d7bf09dc67881f0268a5cc8c2ce1e569a6f8c7699d SHA512 92b0a2fb9bf788eab1187657485698322cec7623da7b861ed5134089d0f3fc05f42138f734aa78bb811679203af2c6bf0dad7e78a091d5a51ba16a2aac60a227
diff --git a/app-text/poppler/poppler-23.12.0.ebuild b/app-text/poppler/poppler-23.12.0.ebuild
new file mode 100644
index 000000000000..13bad1057cc7
--- /dev/null
+++ b/app-text/poppler/poppler-23.12.0.ebuild
@@ -0,0 +1,156 @@
+# Copyright 2005-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/aacid.asc
+	inherit verify-sig
+
+	TEST_COMMIT="e3cdc82782941a8d7b8112f83b4a81b3d334601a"
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	SRC_URI+=" test? ( https://gitlab.freedesktop.org/poppler/test/-/archive/${TEST_COMMIT}/test-${TEST_COMMIT}.tar.bz2 -> ${PN}-test-${TEST_COMMIT}.tar.bz2 )"
+	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+	SLOT="0/133"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="boost cairo cjk curl +cxx debug doc gpgme +introspection +jpeg +jpeg2k +lcms nss png qt5 qt6 test tiff +utils"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=media-libs/fontconfig-2.13
+	>=media-libs/freetype-2.10
+	sys-libs/zlib
+	cairo? (
+		>=dev-libs/glib-2.64:2
+		>=x11-libs/cairo-1.16
+		introspection? ( >=dev-libs/gobject-introspection-1.64:= )
+	)
+	curl? ( net-misc/curl )
+	gpgme? ( >=app-crypt/gpgme-1.19.0:=[cxx] )
+	jpeg? ( >=media-libs/libjpeg-turbo-1.1.0:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.49 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,xml] )
+	tiff? ( media-libs/tiff:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( app-text/poppler-data )
+"
+DEPEND="${COMMON_DEPEND}
+	boost? ( >=dev-libs/boost-1.71 )
+	test? (
+		qt5? (
+			dev-qt/qttest:5
+			dev-qt/qtwidgets:5
+		)
+		qt6? ( dev-qt/qtbase:6[test,widgets] )
+	)
+"
+BDEPEND="
+	>=dev-util/glib-utils-2.64
+	virtual/pkgconfig
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-aacid-20230907 )"
+fi
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-23.10.0-qt-deps.patch"
+	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]] ; then
+		git-r3_src_unpack
+	elif use verify-sig ; then
+		verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
+	fi
+
+	default
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if tc-is-clang ; then
+		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	append-lfs-flags # bug #898506
+
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=$(usex test $(usex qt5))
+		-DBUILD_CPP_TESTS=$(usex test)
+		-DBUILD_MANUAL_TESTS=$(usex test)
+		-DTESTDATADIR="${WORKDIR}"/test-${TEST_COMMIT}
+		-DRUN_GPERF_IF_PRESENT=OFF
+		-DENABLE_BOOST="$(usex boost)"
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DENABLE_GPGME=$(usex gpgme)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_LCMS=$(usex lcms)
+		-DENABLE_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		-DENABLE_QT5=$(usex qt5)
+		-DENABLE_QT6=$(usex qt6)
+		-DENABLE_LIBTIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+	)
+	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}