gentoo auto-resync : 06:07:2023 - 22:15:01

2 files changed, 152 insertions, 0 deletions

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index eb73e2df6451..15f75a870aad 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -6,8 +6,11 @@ DIST poppler-23.05.0.tar.xz 1856488 BLAKE2B 837d532855da3816c3d83ff3401e9a545451
 DIST poppler-23.05.0.tar.xz.sig 833 BLAKE2B c372ded3a5ea3fcf46cccd3d1417d95b449f0b2abfbc114f4bae0d3574040140a8081c23da3c048b3eecca484ed75baee700d2484a12a86d4a5ae82337530f8c SHA512 c9b359dfe67d901578ba6708f1224d1d45b3307a97f3e14e6bac0da748dd2c4457d6e8ff8949b2def5e84acd770198c653e0c5ef8b91088168c38bebf4f3be50
 DIST poppler-23.06.0.tar.xz 1867384 BLAKE2B 36ad02481b4c0eb312d2822165eeb7505d17c91da9c6dfab9a7ebc033b18d60fc4e612e5163351da0dbe36ad8b23c9cf7b778fd24b5c34b939adc4415ce0b104 SHA512 4f7ac99431b4c4fccbb94080e3964fad2abde67d6c7895090cd72488c00066faf7e5d34c660ab46a63a1009bbc948660cc5db1a4cfa1bbfe78f3bf18e95415f6
 DIST poppler-23.06.0.tar.xz.sig 833 BLAKE2B e161b1fb68a2b8977c4f36a264bc43e8e53bacdc63749978178952843d1cf2310df439289e39c2f414e402f477e36177b073b962cae0c643d0ac48e6fa7afb95 SHA512 c20634400d586aea475e86eab50f50f7341dd31d1ccb1c64750a6d6f81d91e623f4dc365fb5db1d4543ef8950488a7258fb4e8ddfe733d6101a5487350d063f2
+DIST poppler-23.07.0.tar.xz 1882144 BLAKE2B 5c29060ae0ade048eb8fc7d7e462b1dc9877921e94e23be64f382a36b56bc469e1dbf64d3110b00ecd6d3da3c97593a7b75a7bfe4bdd33507e4ef1f64276d939 SHA512 8d39a2ca9505f1c12f1dde6f8b57a93dea6fbcf4cf47f8aa3f53a5db900a79ab8630afab96b24439e90d1dfc7b801c3468f705b308b6fcf0c88eafaf9c50dcd4
+DIST poppler-23.07.0.tar.xz.sig 833 BLAKE2B 41b68cb9e8a725f3b86bdcbea82cf5f173b7f87030f17e177a9968af12e1aad0426f6e00bf8db5317c42bc99a6534c36cb2f4ccf6e59766a410ec94cf522c5a0 SHA512 dea7fdcf0a37de838fc2c8020cb75498994a04cf2c74002021d0081c2d2414d0c96c52cc8cdf4f06f76e5f80337338e4ff5f05a8ec9f192ad227ff42c9bc032c
 DIST poppler-test-eea2a4a355eb49ca70d944afd5245b24578af287.tar.bz2 5196899 BLAKE2B 926e148953a703249fa6369254f3aaacd945e0d08effdecec826a0b9c207c9b91d4af8dbeefb0a1a52decb5e941ff6b0f654fbaf15d5ed4d280ae1a7a3542534 SHA512 0c861f95a318f8a966851c7f12524d9311fba1914750527492bb4e5196d5d0be0deae7e3265fff78a5536617130b708285fed5b1edcb85c34ba83ca77226a7cd
 EBUILD poppler-23.05.0.ebuild 4224 BLAKE2B 5601b63a80f51d47cc645d4b5ee9447d3f897045e462941125e6319d8a42c8c2e4222546d0cb767a7142a467a21d1b57a181940943ffad5f3abcc67f812bb10c SHA512 2e4f40d744b86f57d0339df5103449cc6fab31e43d7bb1a4dc689596fd334914b886acc2e21339d8371bacad4a2b0d5f488ff3f12390048c5ba2b4e1288901ab
 EBUILD poppler-23.06.0.ebuild 4371 BLAKE2B cb9e76c627a93d27ae67f032106b4e9a3201011b9aa32b100ecf355356c6c579a2adda67c44b825e27f85047e96da68ba8937c895a42e396908256e078658649 SHA512 da28890ee6917a83a874f3095cddb03946e7643426ebabcdbfd36622ec192842e633cb55523e0d75266bf1563efd5f5c3c23018f9549cda44ff4d688082a7e16
+EBUILD poppler-23.07.0.ebuild 4294 BLAKE2B c54df5e3bf929e1985bcb7551ac8318471c1b1dcb3da70288d6a6bba06d68e2873506f4f34e289bf03b3d4f3abb5f8a887251b6794a1d750b93ebc0e4b4ae34d SHA512 c5953f7fa989c12318a530651b9531d07f8e029a98d0344a8c0412cfced331768988f794d51eb6d4c8d47bbb1be768a5d2395e4062a7e70d5d169e624b01c882
 EBUILD poppler-9999.ebuild 4294 BLAKE2B c54df5e3bf929e1985bcb7551ac8318471c1b1dcb3da70288d6a6bba06d68e2873506f4f34e289bf03b3d4f3abb5f8a887251b6794a1d750b93ebc0e4b4ae34d SHA512 c5953f7fa989c12318a530651b9531d07f8e029a98d0344a8c0412cfced331768988f794d51eb6d4c8d47bbb1be768a5d2395e4062a7e70d5d169e624b01c882
 MISC metadata.xml 1230 BLAKE2B e537b88babbb0c4ef5355c57c226d1c27b8b058e85c437962afe3610cf7dcdd4fea4a7694e508314cc5111d7bf09dc67881f0268a5cc8c2ce1e569a6f8c7699d SHA512 92b0a2fb9bf788eab1187657485698322cec7623da7b861ed5134089d0f3fc05f42138f734aa78bb811679203af2c6bf0dad7e78a091d5a51ba16a2aac60a227
diff --git a/app-text/poppler/poppler-23.07.0.ebuild b/app-text/poppler/poppler-23.07.0.ebuild
new file mode 100644
index 000000000000..961fa2f86c19
--- /dev/null
+++ b/app-text/poppler/poppler-23.07.0.ebuild
@@ -0,0 +1,149 @@
+# Copyright 2005-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/aacid.asc
+	inherit verify-sig
+
+	TEST_COMMIT="eea2a4a355eb49ca70d944afd5245b24578af287"
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	SRC_URI+=" test? ( https://gitlab.freedesktop.org/poppler/test/-/archive/${TEST_COMMIT}/test-${TEST_COMMIT}.tar.bz2 -> ${PN}-test-${TEST_COMMIT}.tar.bz2 )"
+	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+	SLOT="0/130"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="boost cairo cjk curl +cxx debug doc gpgme +introspection +jpeg +jpeg2k +lcms nss png qt5 test tiff +utils"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=media-libs/fontconfig-2.13
+	>=media-libs/freetype-2.10
+	sys-libs/zlib
+	cairo? (
+		>=dev-libs/glib-2.64:2
+		>=x11-libs/cairo-1.16
+		introspection? ( >=dev-libs/gobject-introspection-1.64:= )
+	)
+	curl? ( net-misc/curl )
+	gpgme? ( >=app-crypt/gpgme-1.19.0:=[cxx] )
+	jpeg? ( >=media-libs/libjpeg-turbo-1.1.0:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.49 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( app-text/poppler-data )
+"
+DEPEND="${COMMON_DEPEND}
+	boost? ( >=dev-libs/boost-1.71 )
+	test? ( qt5? ( dev-qt/qttest:5 ) )
+"
+BDEPEND="
+	>=dev-util/glib-utils-2.64
+	virtual/pkgconfig
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-aacid-20230313 )"
+fi
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-20.12.1-qt5-deps.patch"
+	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]] ; then
+		git-r3_src_unpack
+	elif use verify-sig ; then
+		verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
+	fi
+
+	default
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if tc-is-clang ; then
+		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	append-lfs-flags # bug #898506
+
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=$(usex test $(usex qt5))
+		-DBUILD_CPP_TESTS=$(usex test)
+		-DBUILD_MANUAL_TESTS=$(usex test)
+		-DTESTDATADIR="${WORKDIR}"/test-${TEST_COMMIT}
+		-DRUN_GPERF_IF_PRESENT=OFF
+		-DENABLE_BOOST="$(usex boost)"
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DWITH_Gpgmepp=$(usex gpgme)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_CMS=$(usex lcms lcms2 none)
+		-DWITH_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		$(cmake_use_find_package qt5 Qt5Core)
+		-DWITH_TIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+		-DENABLE_QT6=OFF
+	)
+	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}