gentoo auto-resync : 24:06:2023 - 01:25:35

2 files changed, 192 insertions, 0 deletions

diff --git a/app-text/ghostscript-gpl/Manifest b/app-text/ghostscript-gpl/Manifest
index 8f81e69005b7..a7a23d0803e6 100644
--- a/app-text/ghostscript-gpl/Manifest
+++ b/app-text/ghostscript-gpl/Manifest
@@ -1,8 +1,10 @@
 DIST ghostscript-10.0.0.tar.xz 62749144 BLAKE2B 10b962d358994506b69aba34827ea9d6a86c61e5093d7371b8350ff29a74b1db4816d0a62ff64f5d0e5a652fcd0304224c6236d33e717299789dfb2c9f350e24 SHA512 660252841e9b24c411bc92d0eb104de464686131e70051f60108db1a6ecfe2ada2ccacbeed8f2ac84bf69338ad75c850e814c9ac4e0351943f9989d66b3b082d
 DIST ghostscript-10.01.0.tar.xz 67564800 BLAKE2B 6b4b724158e7878f879e56154eaa399be0a53c97292e8df5b2a324ef329d83c31e85850d10b463e3e5373d5b47b7ac4a8b0d92769c76162b5e445292882ca831 SHA512 b679b35bcdcf211d6aa41a571225a50449e7e36def75cf37fee8f06889df3a5a9726a7aef2fd5ae819c2071cb6fcf8712741cd2c131c9341b60936e684bd8d98
 DIST ghostscript-10.01.1.tar.xz 67567268 BLAKE2B 26f14f11362c7cd6e129044b8e094ad421fc607a702e1f5d10ae03b8ebfb1e76fc094281df739d6ebfa815c6080f1b2223036268474c41d795e2a1e5fc66bab2 SHA512 d944be9e8aef68d1176d64c40db6fa86d55d0c9e30047f2147c02806ab61cfe9ac2cb00d4e5b218ff3c51cc6ed47ceffe1bac4dd9d4cc1760b7974f30c6c2735
+DIST ghostscript-10.01.2.tar.xz 67571808 BLAKE2B d5bedfe058a9b982da3a5a9935617add8d963291f135e047369439eeb0b1587e697511fe4a2a9633cfb49594d3a36467d1df7904125f53c70d8161dc9825ff32 SHA512 ee20f0e12f553a3d04578e71a0d45defebc71117ce4dc2c14043985bfe7348ad7f8b2fe98fc9b4f5b935ecb32e50dc340be67d6ef58190542ec6d0f9da1de380
 DIST ghostscript-gpl-10.0-patches.tar.xz 2980 BLAKE2B e2c20195b153bf45f374e84d91a4df1885a3696f4061340a0a2ac5f586b9723b45eade343ad0e5760e66616624b5f7dad82d62747040493d7ca40c13329b2df2 SHA512 dac26d7f75bbdc2a56891db7d607c2120717fdf8b1cd55c53ed3be09de3e0a62338585f4dac74496d634ce03ecb2212f386187e72b5e6b59debf8d07694e0c83
 EBUILD ghostscript-gpl-10.0.0-r5.ebuild 5512 BLAKE2B 9eb094ba10e9971558e30d66c26904d7c09ec501739140d697b11b2a119ea25aad4fbc946bfc9f1ce0e5dca32efd506b947dfe0e6454d7c3ad4bc379b86eff33 SHA512 cfc70d3f53e92d41450029963c47c4b807c727c19673d1975b6c717a09fdb6ce1454553ade21d74ab3ccb1b76eb2f22ff2e3f99564d3ba96250df6b1e5bef01e
 EBUILD ghostscript-gpl-10.01.0.ebuild 5451 BLAKE2B 43fca62dc201a45d172ee88d3d51c58c751a4056e83bd15b1c414479c5982d5a227264ce4ec3cf72cd9c374b42a9f8e37e08aaf8636bff8f1024e6224b5d1385 SHA512 a1fef86a3c5f90711a596ca57c60d18a60af3bca8ed85cd57ad8033920164edeb13570f37847dad81bca0b4c674b9ece513cd542e4b9ae6684854512844f27f3
 EBUILD ghostscript-gpl-10.01.1.ebuild 5456 BLAKE2B bfd0846903bf34d6f7c9eae3a0717e00184534f9c0d55546eebc3fcd09c215a891269190b14c06af3d6e278d63005e894cc82a4b522dc026aec089e4861b8012 SHA512 af602edb537d8063bc731ade835c3917096040a399e9926637be853b59a79ded5f1e8342d0f5c1ce7739683ae832681bcacbede7263982f279f38a1181bf244a
+EBUILD ghostscript-gpl-10.01.2.ebuild 5464 BLAKE2B e73bf57acfeab59e0c537758427e4bf78df4b7b446706acfdab1a37c5d40e87b6fc5e37877bd0a68f3b5a097b35db8cd1f1b4d834030bb78db74fc2c0e9506c1 SHA512 e9885bbbb4fbb8cfb323f0d22478576b286485a5e4268eea217510543f394c5fd8c0aa6e8ca127f0f349d3387d6200f59cad68710b401dbe974bf99a4cac5135
 MISC metadata.xml 831 BLAKE2B e594fcc7ef78d3eb9f157a46c63f33fd35887fa82cdc304bc4b2db4e772473e8ba695b0ef932a69df0c8a5ac5269955ae600b436444782820475f44c6fc1d9f1 SHA512 2b067dfde63ffd8da3afb27c889884e51a3e1158cef153bc30ffb10a69cb0f7d409bc38a335651010d4e1dddad3bf09a9873445d77416da2bbd2ac7af5ab1598
diff --git a/app-text/ghostscript-gpl/ghostscript-gpl-10.01.2.ebuild b/app-text/ghostscript-gpl/ghostscript-gpl-10.01.2.ebuild
new file mode 100644
index 000000000000..f6e25cf2e1c5
--- /dev/null
+++ b/app-text/ghostscript-gpl/ghostscript-gpl-10.01.2.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_PN=${PN/-gpl}
+MY_P="${MY_PN}-${PV/_}"
+PVM=$(ver_cut 1-2)
+PVM_S=$(ver_rs 1-2 "")
+
+# Use https://gitweb.gentoo.org/proj/codec/ghostscript-gpl-patches.git/ for patches
+# See 'index' branch for README
+MY_PATCHSET="ghostscript-gpl-10.0-patches.tar.xz"
+
+DESCRIPTION="Interpreter for the PostScript language and PDF"
+HOMEPAGE="https://ghostscript.com/ https://git.ghostscript.com/?p=ghostpdl.git;a=summary"
+SRC_URI="https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs${PVM_S}/${MY_P}.tar.xz"
+if [[ -n "${MY_PATCHSET}" ]] ; then
+	SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${MY_PATCHSET}"
+fi
+
+LICENSE="AGPL-3 CPL-1.0"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="cups dbus gtk l10n_de static-libs unicode X"
+
+LANGS="ja ko zh-CN zh-TW"
+for X in ${LANGS} ; do
+	IUSE="${IUSE} l10n_${X}"
+done
+
+DEPEND="app-text/libpaper:=
+	media-libs/fontconfig
+	>=media-libs/freetype-2.4.9:2=
+	>=media-libs/jbig2dec-0.19:=
+	>=media-libs/lcms-2.6:2
+	>=media-libs/libpng-1.6.2:=
+	media-libs/libjpeg-turbo:=
+	>=media-libs/openjpeg-2.1.0:2=
+	>=media-libs/tiff-4.0.1:=
+	>=sys-libs/zlib-1.2.7
+	cups? ( >=net-print/cups-1.3.8 )
+	dbus? ( sys-apps/dbus )
+	gtk? ( x11-libs/gtk+:3 )
+	unicode? ( net-dns/libidn:= )
+	X? ( x11-libs/libXt x11-libs/libXext )"
+BDEPEND="virtual/pkgconfig"
+# bug #844115 for newer poppler-data dep
+RDEPEND="${DEPEND}
+	>=app-text/poppler-data-0.4.11-r2
+	>=media-fonts/urw-fonts-2.4.9
+	l10n_ja? ( media-fonts/kochi-substitute )
+	l10n_ko? ( media-fonts/baekmuk-fonts )
+	l10n_zh-CN? ( media-fonts/arphicfonts )
+	l10n_zh-TW? ( media-fonts/arphicfonts )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	if [[ -n ${MY_PATCHSET} ]] ; then
+		# apply various patches, many borrowed from Fedora
+		# https://src.fedoraproject.org/rpms/ghostscript
+		# and Debian
+		# https://salsa.debian.org/printing-team/ghostscript/-/tree/debian/latest/debian/patches
+		eapply "${WORKDIR}"/${MY_PATCHSET%%.tar*}
+	fi
+
+	default
+
+	# Remove internal copies of various libraries
+	rm -r cups/libs || die
+	rm -r freetype || die
+	rm -r jbig2dec || die
+	rm -r jpeg || die
+	rm -r lcms2mt || die
+	rm -r libpng || die
+	rm -r tiff || die
+	rm -r zlib || die
+	rm -r openjpeg || die
+	# Remove internal CMaps (CMaps from poppler-data are used instead)
+	rm -r Resource/CMap || die
+
+	if ! use gtk ; then
+		sed -e "s:\$(GSSOX)::" \
+			-e "s:.*\$(GSSOX_XENAME)$::" \
+			-i base/unix-dll.mak || die "sed failed"
+	fi
+
+	# Force the include dirs to a neutral location.
+	sed -e "/^ZLIBDIR=/s:=.*:=${T}:" \
+		-i configure.ac || die
+	# Some files depend on zlib.h directly.  Redirect them. #573248
+	# Also make sure to not define OPJ_STATIC to avoid linker errors due to
+	# hidden symbols (https://bugs.freebsd.org/bugzilla/show_bug.cgi?id=203327#c1)
+	sed -e '/^zlib_h/s:=.*:=:' \
+		-e 's|-DOPJ_STATIC ||' \
+		-i base/lib.mak || die
+
+	# Search path fix
+	# put LDFLAGS after BINDIR, bug #383447
+	sed -e "s:\$\(gsdatadir\)/lib:@datarootdir@/ghostscript/${PV}/$(get_libdir):" \
+		-e "s:exdir=.*:exdir=@datarootdir@/doc/${PF}/examples:" \
+		-e "s:docdir=.*:docdir=@datarootdir@/doc/${PF}/html:" \
+		-e "s:GS_DOCDIR=.*:GS_DOCDIR=@datarootdir@/doc/${PF}/html:" \
+		-e 's:-L$(BINDIR):& $(LDFLAGS):g' \
+		-i Makefile.in base/*.mak || die "sed failed"
+
+	# Remove incorrect symlink, bug 590384
+	rm ijs/ltmain.sh || die
+	eautoreconf
+
+	cd ijs || die
+	eautoreconf
+}
+
+src_configure() {
+	# Unsupported upstream, bug #884841
+	filter-lto
+
+	local FONTPATH
+	for path in \
+		"${EPREFIX}"/usr/share/fonts/urw-fonts \
+		"${EPREFIX}"/usr/share/fonts/Type1 \
+		"${EPREFIX}"/usr/share/fonts
+	do
+		FONTPATH="${FONTPATH}${FONTPATH:+:}${EPREFIX}${path}"
+	done
+
+	# Do not add --enable-dynamic here, it's not supported fully upstream
+	# https://bugs.ghostscript.com/show_bug.cgi?id=705895
+	# bug #884707
+	#
+	# leptonica and tesseract are bundled but modified upstream, like in
+	# mujs/mupdf.
+	PKGCONFIG=$(type -P $(tc-getPKG_CONFIG)) econf \
+		--enable-freetype \
+		--enable-fontconfig \
+		--enable-openjpeg \
+		--disable-compile-inits \
+		--with-drivers=ALL \
+		--with-fontpath="${FONTPATH}" \
+		--with-ijs \
+		--with-jbig2dec \
+		--with-libpaper \
+		--with-system-libtiff \
+		$(use_enable cups) \
+		$(use_enable dbus) \
+		$(use_enable gtk) \
+		$(use_with cups pdftoraster) \
+		$(use_with unicode libidn) \
+		$(use_with X x) \
+		DARWIN_LDFLAGS_SO_PREFIX="${EPREFIX}/usr/lib/"
+
+	cd "${S}/ijs" || die
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	emake so all
+
+	cd ijs || die
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" install-so install
+
+	# move gsc to gs, bug #343447
+	# gsc collides with gambit, bug #253064
+	mv -f "${ED}"/usr/bin/{gsc,gs} || die
+
+	cd "${S}/ijs" || die
+	emake DESTDIR="${D}" install
+
+	# Sometimes the upstream versioning deviates from the tarball(!)
+	# bug #844115#c32
+	local my_gs_version=$(find "${ED}"/usr/share/ghostscript/ -maxdepth 1 -mindepth 1 -type d || die)
+	my_gs_version=${my_gs_version##*/}
+
+	# Install the CMaps from poppler-data properly, bug #409361
+	dosym -r /usr/share/poppler/cMaps /usr/share/ghostscript/${my_gs_version}/Resource/CMap
+
+	if ! use static-libs; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+}