gentoo resync : 02.09.2020

1 files changed, 43 insertions, 0 deletions

diff --git a/app-text/editorconfig-core-c/editorconfig-core-c-0.12.4.ebuild b/app-text/editorconfig-core-c/editorconfig-core-c-0.12.4.ebuild
new file mode 100644
index 000000000000..c79152307cf3
--- /dev/null
+++ b/app-text/editorconfig-core-c/editorconfig-core-c-0.12.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="EditorConfig core library written in C"
+HOMEPAGE="https://github.com/editorconfig/editorconfig-core-c/"
+SRC_URI="https://github.com/editorconfig/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="cli doc"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+DEPEND="dev-libs/libpcre2:="
+RDEPEND="${DEPEND}
+	cli? ( !dev-python/editorconfig-core-py[cli] )"
+
+src_prepare() {
+	# Don't install the static library.
+	sed -e '/install(TARGETS editorconfig_static/,+5d' -i src/lib/CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc 'ON' 'OFF')
+		-DBUILD_STATICALLY_LINKED_EXE=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+	cmake_src_install
+
+	if ! use cli; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}