gentoo resync : 13.11.2021

3 files changed, 322 insertions, 1 deletions

diff --git a/app-text/calibre/Manifest b/app-text/calibre/Manifest
index a937edec2778..841c1170f097 100644
--- a/app-text/calibre/Manifest
+++ b/app-text/calibre/Manifest
@@ -11,9 +11,11 @@ DIST calibre-5.25.0.tar.xz 36849112 BLAKE2B f9cb423317ea1f5b22e7f3540708fd4fa6e7
 DIST calibre-5.30.0.tar.xz 37002224 BLAKE2B dc034c54a6ebee838652fe10b467bf8408f8dabd759108d617e2c9f64109e92afe0f2994c5df480ec4346c596361ccb63d0aaab2796edc4993ae0eef4222ba6d SHA512 c2d435ec9a8cfd5f76439f229cd9a7a7f4e829e44d9f2ff37003faf8a925df40cd77471d72d05a8d145bfc104bf92dbdd67ddacabc84e6e3cad055887530d8bd
 DIST calibre-5.31.0.tar.xz 36937976 BLAKE2B 55995aa8fc75ebee5506145ab7995ebcfd04dfa080eae48229a167e404cc4f091c27f9d9401656c52b1620b6d407904a6e454b0b693c6e194a871bc6fda30d4b SHA512 4a2926f86d4bb4e9b66312c9f988bdf9cbcf12096c76578259f9473f69f7e8c16f763934fbd2664ba8e3bd24fbe6a878c1e2a9df43152ea0fe0ba3d447dfed42
 DIST calibre-5.31.1.tar.xz 36943652 BLAKE2B 13fa46d4426f705f7af2de07a38ca2266148291ca054a1de65b11013907fa51eb7ebefb774988a0b471af31d62ba8eb890cd3fe687505976d9d70738fb64f538 SHA512 c9f8e7fef430961f51699eeda009a799b702b740c9999744b982dbd14d971557f76b31897853435f8947199ca3d65622bf974b2d2afadc813d292b64bc048121
+DIST calibre-5.32.0.tar.xz 37115596 BLAKE2B c26340a87f77f373de619a1120f572b21530ebb69ba47975c5fd27e00dc5e72bd23c7265065e25d82f8e964fbeac8a05cc6a08c2d361c4f0105702993230ebd4 SHA512 4ad46e169a0ce23b354d2443b615f2fa80ef69aa763a5f26431968c49af433becf736659daaeb8d8d07e4a2326698c920cafa9a74ac5a8b7bb2f82f0fee2f532
 EBUILD calibre-5.16.1-r1.ebuild 8515 BLAKE2B c9dc7b66d93d6020cde09a360b0aa92894eafab75e7ca4f18a1a9a9286c6eb4f2af17fb162583fcc05088775abd0fa28ff849888775d964a396ab09cfcc02eea SHA512 cd76c560e8acfeb4e41de7ae8cce3fd4294b54ac7bee585ed562a596791054a7ad2918f09105b86587271002f7690b681ac9bc3e53bf1e5657b80f94aa37cbe9
 EBUILD calibre-5.25.0-r2.ebuild 8521 BLAKE2B e8aadd09100a88f08a2555faf10b399ca14b9cc1a514c37e548db7a659ff76d24a25085a6549b9aa07a7c9f106f6198940390c9eb1362afd28745055e461f347 SHA512 600ddb23b1a0360fbb04cc1b84cdcfcbaae4f40b6b52f8385364a8bd5e1aa13678eb97a43600a08ca50c13aef58564a3398f0919232e395a7d4c3cd96556da7c
 EBUILD calibre-5.30.0.ebuild 8535 BLAKE2B 6fa6447889c1ec42b79a78a85997b6edd10f938ccc0aa319f9f9e0cff43590ffc8520844cea70526b6e67cd31a2dd4ff62bce9340b6bb6b86c38eb190c244e8f SHA512 a0758ea6888c9def11b0835301e5f6b32b8315c07b66d718125f9cc8c2d3d8e66e270b9382d825c8e40e5330bc5599c163182f180419b02130db369167482fb8
 EBUILD calibre-5.31.0.ebuild 8535 BLAKE2B 6fa6447889c1ec42b79a78a85997b6edd10f938ccc0aa319f9f9e0cff43590ffc8520844cea70526b6e67cd31a2dd4ff62bce9340b6bb6b86c38eb190c244e8f SHA512 a0758ea6888c9def11b0835301e5f6b32b8315c07b66d718125f9cc8c2d3d8e66e270b9382d825c8e40e5330bc5599c163182f180419b02130db369167482fb8
-EBUILD calibre-5.31.1.ebuild 10215 BLAKE2B 210207e389214ff9889512db52cfd7fa2ac1966b6114733e3767b91e2b6a549ae20d131ac6842307317ed60fb0114b08f9ff71d355999f931810cd4916ce436e SHA512 bbb8e5774f520d1981a85db901362dae5fba080e2b2d7812369d8cdae64716ccbb5dd63119fb41c0785df661af7eb058823f534597068afc9d5478063b3d8998
+EBUILD calibre-5.31.1.ebuild 10375 BLAKE2B 6e8e273664d2e2f926cfc2a01aba692c9b671267de9008517242b3c3f61a51ff0d184417ae9b69a32fbfa7e172c26fbb553f927cd0dffe573df8288d780e1318 SHA512 0075d57a1b2f9e734a90e2427aa8e11548af33d925b4b646a6bee54b104c02af66bd82a009c79d5c429b8d2c42f69ab00d55a7f247cd4f644df6a2a76f67b3b2
+EBUILD calibre-5.32.0-r1.ebuild 10358 BLAKE2B 5a45a111ce35949075dd77b7f3113456f22613fb4957f031cce2878eb5706c47393b09cdc75846ab89047f87a4f644df6f723b577663a0f8b0c06043590b4009 SHA512 95f4c46743d61ce1deef6f32e4eb7bc703da29e35064703e1a9d7b5990b3147bfa7c6f3a445746a2eff1712f77ec9940bc278b7d0a409ec3953149384a657337
 MISC metadata.xml 304 BLAKE2B 0d93b1c7606c37cb8b7308b507a1d2988a05f780a93ae80c98e021f5af75128954d57b102afc1d96728872c81bf0adc40e32b31197dfa825cd040af3a8739fb7 SHA512 e193c0b78ed4140b695c44d273310207c9f2f745bf31589c69e81230a9eed68fa1c361c1e3f68a60e135ef0628aa480002229871f4a50f4000aea6df7e5f067d
diff --git a/app-text/calibre/calibre-5.31.1.ebuild b/app-text/calibre/calibre-5.31.1.ebuild
index 283305d4191a..4c142f046ab5 100644
--- a/app-text/calibre/calibre-5.31.1.ebuild
+++ b/app-text/calibre/calibre-5.31.1.ebuild
@@ -191,6 +191,10 @@ src_compile() {
 	# TODO: get qmake called by setup.py to respect CC and CXX too
 	tc-export CC CXX
 
+	# bug 821871
+	local MY_LIBDIR="${ESYSROOT}/usr/$(get_libdir)"
+	export FT_LIB_DIR="${MY_LIBDIR}" HUNSPELL_LIB_DIR="${MY_LIBDIR}" PODOFO_LIB_DIR="${MY_LIBDIR}"
+
 	PATH="${T}/bin:${PATH}" ${EPYTHON} setup.py build || die
 }
 
diff --git a/app-text/calibre/calibre-5.32.0-r1.ebuild b/app-text/calibre/calibre-5.32.0-r1.ebuild
new file mode 100644
index 000000000000..7b6a8c3a07b4
--- /dev/null
+++ b/app-text/calibre/calibre-5.32.0-r1.ebuild
@@ -0,0 +1,315 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_REQ_USE="ipv6(+),sqlite,ssl"
+
+inherit toolchain-funcs python-single-r1 xdg-utils
+
+DESCRIPTION="Ebook management application"
+HOMEPAGE="https://calibre-ebook.com/"
+SRC_URI="https://download.calibre-ebook.com/${PV}/${P}.tar.xz"
+
+LICENSE="
+	GPL-3+
+	GPL-3
+	GPL-2+
+	GPL-2
+	GPL-1+
+	LGPL-3+
+	LGPL-2.1+
+	LGPL-2.1
+	BSD
+	MIT
+	Old-MIT
+	Apache-2.0
+	public-domain
+	|| ( Artistic GPL-1+ )
+	CC-BY-3.0
+	OFL-1.1
+	PSF-2
+"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0"
+IUSE="ios +udisks"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/hunspell-1.7:=
+	>=app-text/podofo-0.9.6_pre20171027:=
+	>=app-text/poppler-0.26.5[qt5]
+	dev-libs/glib:2=
+	dev-libs/hyphen:=
+	>=dev-libs/icu-57.1:=
+	dev-libs/libinput:=
+	>=dev-libs/dbus-glib-0.106
+	dev-libs/snowball-stemmer:=
+	>=sys-apps/dbus-1.10.8
+	$(python_gen_cond_dep '
+		app-accessibility/speech-dispatcher[python,${PYTHON_USEDEP}]
+		>=dev-python/apsw-3.25.2_p1[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/cchardet[${PYTHON_USEDEP}]
+		>=dev-python/chardet-3.0.3[${PYTHON_USEDEP}]
+		>=dev-python/cssselect-0.7.1[${PYTHON_USEDEP}]
+		>=dev-python/css-parser-1.0.4[${PYTHON_USEDEP}]
+		>=dev-python/dbus-python-1.2.4[${PYTHON_USEDEP}]
+		dev-python/dnspython[${PYTHON_USEDEP}]
+		>=dev-python/feedparser-5.2.1[${PYTHON_USEDEP}]
+		>=dev-python/html2text-2019.8.11[${PYTHON_USEDEP}]
+		>=dev-python/html5-parser-0.4.9[${PYTHON_USEDEP}]
+		dev-python/jeepney[${PYTHON_USEDEP}]
+		>=dev-python/lxml-3.8.0[${PYTHON_USEDEP}]
+		>=dev-python/markdown-3.0.1[${PYTHON_USEDEP}]
+		>=dev-python/mechanize-0.3.5[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.6.2[${PYTHON_USEDEP}]
+		>=dev-python/netifaces-0.10.5[${PYTHON_USEDEP}]
+		>=dev-python/pillow-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/psutil-4.3.0[${PYTHON_USEDEP}]
+		>=dev-python/pychm-0.8.6[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		>=dev-python/pygments-2.3.1[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.5.3[${PYTHON_USEDEP}]
+		>=dev-python/PyQt5-5.15.5_pre2107091435[gui,svg,widgets,network,printsupport,${PYTHON_USEDEP}]
+		>=dev-python/PyQt-builder-1.10.3[${PYTHON_USEDEP}]
+		>=dev-python/PyQtWebEngine-5.15.5_pre2108100905[${PYTHON_USEDEP}]
+		dev-python/regex[${PYTHON_USEDEP}]
+		dev-python/zeroconf[${PYTHON_USEDEP}]
+	')
+	dev-qt/qtcore:5=
+	dev-qt/qtdbus:5=
+	dev-qt/qtgui:5=[jpeg]
+	>=dev-qt/qtwebengine-5.12
+	dev-qt/qtwidgets:5=
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+	media-fonts/liberation-fonts
+	media-libs/fontconfig:=
+	>=media-libs/freetype-2:=
+	>=media-libs/libmtp-1.1.11:=
+	>=media-libs/libwmf-0.2.8
+	>=media-gfx/optipng-0.7.6
+	>=sys-libs/zlib-1.2.11:=
+	virtual/libusb:1=
+	x11-libs/libxkbcommon:=
+	x11-libs/libX11:=
+	x11-libs/libXext:=
+	x11-libs/libXrender:=
+	x11-misc/shared-mime-info
+	>=x11-misc/xdg-utils-1.0.2-r2
+	ios? (
+		>=app-pda/usbmuxd-1.0.8
+		>=app-pda/libimobiledevice-1.2.0
+	)
+	udisks? ( virtual/libudev )"
+RDEPEND="${COMMON_DEPEND}
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="$(python_gen_cond_dep '
+		>=dev-python/setuptools-23.1.0[${PYTHON_USEDEP}]
+		>=dev-python/sip-5[${PYTHON_USEDEP}]
+	')
+	>=virtual/podofo-build-0.9.6_pre20171027
+	virtual/pkgconfig"
+
+PATCHES=(
+	# Don't prompt the user for updates - they've installed via
+	# an ebuild.
+	"${FILESDIR}/${PN}-2.9.0-no_updates_dialog.patch"
+
+	# Skip calling a binary (JxrDecApp) from libjxr which is used for tests
+	# We don't (yet?) package libjxr and it seems to be dead upstream
+	# (last commit in 2017)
+	"${FILESDIR}/${PN}-5.31.0-jxr-test.patch"
+
+	# TODO:
+	# test_qt tries to load a bunch of images using Qt and it currently fails
+	# due to some presumably missing dependencies. This is important and
+	# we need to look into it, but at time of writing, none of the tests
+	# are even bring run, so I'd like to return to this later.
+	# We don't want to skip test_qt entirely, so just skip this particular
+	# assert for now.
+	"${FILESDIR}/${PN}-5.31.0-qt-image-test.patch"
+)
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && tc-is-gcc && [[ $(gcc-major-version) -lt 6 ]]; then
+		eerror "Calibre cannot be built with this version of gcc."
+		eerror "You need at least gcc-6.0"
+		die "Your C compiler is too old for this package."
+	fi
+}
+
+src_prepare() {
+	default
+
+	# Warning:
+	#
+	# While it might be rather tempting to add yet another sed here,
+	# please don't. There have been several bugs in Gentoo's packaging
+	# of calibre from seds-which-become-stale. Please consider
+	# creating a patch instead, but in any case, run the test suite
+	# and ensure it passes.
+	#
+	# If in doubt about a problem, checking Fedora or Arch Linux's packaging
+	# is recommended, as Arch Linux's PKGBUILD is maintained by a Calibre
+	# contributor. Or just ask them.
+
+	# Fix outdated version constant.
+	#sed -e "s#\\(^numeric_version =\\).*#\\1 (${PV//./, })#" \
+	#	-i src/calibre/constants.py || \
+	#	die "sed failed to patch constants.py"
+
+	# Avoid sandbox violation in /usr/share/gnome/apps when linux.py
+	# calls xdg-* (bug #258938).
+	sed -e "s|'xdg-desktop-menu', 'install'|\\0, '--mode', 'user'|" \
+		-e "s|check_call(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
+		-e "s|\\(CurrentDir(tdir)\\), \\\\\$|\\1:|" \
+		-e "s|, PreserveMIMEDefaults():|:|" \
+		-e "s|'xdg-icon-resource', 'install'|\\0, '--mode', 'user'|" \
+		-e "s|cmd\[2\]|cmd[4]|" \
+		-e "s|cc(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
+		-e "s|'xdg-mime', 'install'|\\0, '--mode', 'user'|" \
+		-i src/calibre/linux.py || die "sed failed to patch linux.py"
+
+	# Disable unnecessary privilege dropping for bug #287067.
+	sed -e "s:if os.geteuid() == 0:if False and os.geteuid() == 0:" \
+		-i setup/install.py || die "sed failed to patch install.py"
+	sed -e "/^            os.chdir(os.path.join(src_dir, 'build'))$/a\
+\\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ self.check_call(['sed', \
+'-e', 's|^CFLAGS .*|\\\\\\\\0 ${CFLAGS}|', \
+'-e', 's|^CXXFLAGS .*|\\\\\\\\0 ${CXXFLAGS}|', \
+'-e', 's|^LFLAGS .*|\\\\\\\\0 ${LDFLAGS}|', \
+'-i', os.path.join(os.path.basename(src_dir), 'Makefile')])" \
+		-e "s|open(self.j(bdir, '.qmake.conf'), 'wb').close()|open(self.j(bdir, '.qmake.conf'), 'wb').write(b'QMAKE_LFLAGS += ${LDFLAGS}')|" \
+		-i setup/build.py || die "sed failed to patch build.py"
+}
+
+src_compile() {
+	# TODO: get qmake called by setup.py to respect CC and CXX too
+	tc-export CC CXX
+
+	# bug 821871
+	local MY_LIBDIR="${ESYSROOT}/usr/$(get_libdir)"
+	export FT_LIB_DIR="${MY_LIBDIR}" HUNSPELL_LIB_DIR="${MY_LIBDIR}" PODOFO_LIB_DIR="${MY_LIBDIR}"
+
+	PATH="${T}/bin:${PATH}" ${EPYTHON} setup.py build || die
+}
+
+src_test() {
+	# Skipped tests:
+	# - 7z (unpackaged Python dependency: py7zr)
+	# - test_unrar (unpackaged Python dependency: unrardll)
+	#
+	# Note that we currently have a hack to skip one part of test_qt!
+	# See PATCHES for more.
+	CALIBRE_PY3_PORT=1 ${PYTHON} setup.py test \
+			--exclude-test-name 7z \
+			--exclude-test-name test_searching \
+			--exclude-test-name test_unrar || die
+}
+
+src_install() {
+	# calibre works with python 3, so remove the python 2 constraint
+	export CALIBRE_PY3_PORT=1
+
+	# Bypass kbuildsycoca and update-mime-database in order to
+	# avoid sandbox violations if xdg-mime tries to call them.
+	mkdir "${T}/bin" || die
+	cat - > "${T}/bin/kbuildsycoca" <<-EOF
+	#!${BASH}
+	echo $0 : $@
+	exit 0
+	EOF
+
+	cp "${T}"/bin/{kbuildsycoca,update-mime-database} || die
+	chmod +x "${T}"/bin/{kbuildsycoca,update-mime-database} || die
+
+	export QMAKE="${EPREFIX}/usr/$(get_libdir)/qt5/bin/qmake"
+
+	# Unset DISPLAY in order to prevent xdg-mime from triggering a sandbox
+	# violation with kbuildsycoca as in bug #287067, comment #13.
+	export -n DISPLAY
+
+	# Bug #352625 - Some LANGUAGE values can trigger the following ValueError:
+	#   File "/usr/lib/python2.6/locale.py", line 486, in getdefaultlocale
+	#    return _parse_localename(localename)
+	#  File "/usr/lib/python2.6/locale.py", line 418, in _parse_localename
+	#    raise ValueError, 'unknown locale: %s' % localename
+	#ValueError: unknown locale: 46
+	export -n LANG LANGUAGE ${!LC_*}
+	export LC_ALL=C.utf8 #709682
+
+	# Bug #295672 - Avoid sandbox violation in ~/.config by forcing
+	# variables to point to our fake temporary $HOME.
+	export HOME="${T}/fake_homedir"
+	export XDG_CONFIG_HOME="${HOME}/.config"
+	export XDG_DATA_HOME="${HOME}/.local/share"
+	export CALIBRE_CONFIG_DIRECTORY="${XDG_CONFIG_HOME}/calibre"
+	mkdir -p "${XDG_DATA_HOME}" "${CALIBRE_CONFIG_DIRECTORY}" || die
+
+	tc-export CC CXX
+	# Bug #334243 - respect LDFLAGS when building extensions
+	export OVERRIDE_CFLAGS="$CFLAGS" OVERRIDE_LDFLAGS="$LDFLAGS"
+	local libdir=$(get_libdir)
+	[[ -n $libdir ]] || die "get_libdir returned an empty string"
+
+	addpredict /dev/dri #665310
+
+	PATH=${T}/bin:${PATH} PYTHONPATH=${S}/src${PYTHONPATH:+:}${PYTHONPATH} \
+		"${PYTHON}" setup.py install \
+		--root="${D}" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/${libdir}" \
+		--staging-root="${ED}/usr" \
+		--staging-libdir="${ED}/usr/${libdir}" || die
+
+	find "${ED}"/usr/share -type d -empty -delete
+
+	cd "${ED}"/usr/share/calibre/fonts/liberation || die
+	local x
+	for x in * ; do
+		[[ -f ${EPREFIX}/usr/share/fonts/liberation-fonts/${x} ]] || continue
+		ln -sf "../../../fonts/liberation-fonts/${x}" "${x}" || die
+	done
+
+	einfo "Converting python shebangs"
+	python_fix_shebang --force "${ED}"
+
+	einfo "Compiling python modules"
+	python_optimize "${ED}"/usr/$(get_libdir)/calibre "${D}/$(python_get_sitedir)"
+
+	newinitd "${FILESDIR}"/calibre-server-3.init calibre-server
+	newconfd "${FILESDIR}"/calibre-server-3.conf calibre-server
+}
+
+pkg_preinst() {
+	# Indentify stray directories from upstream's "Binary install"
+	# method (see bug 622728).
+	CALIBRE_LIB_DIR=/usr/$(get_libdir)/calibre
+	CALIBRE_LIB_CONTENT=$(for x in "${ED}${CALIBRE_LIB_DIR}"/*; do
+		printf -- "${x##*/} "; done) || die "Failed to list ${ED}${CALIBRE_LIB_DIR}"
+}
+
+pkg_postinst() {
+	[[ -n ${CALIBRE_LIB_DIR} ]] || die "CALIBRE_LIB_DIR is unset"
+	local x
+	for x in "${EROOT}${CALIBRE_LIB_DIR}"/*; do
+		if [[ " ${CALIBRE_LIB_CONTENT} " != *" ${x##*/} "* ]]; then
+			elog "Purging '${x}'"
+			rm -rf "${x}"
+		fi
+	done
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}