gentoo resync : 22.10.2018

3 files changed, 116 insertions, 0 deletions

diff --git a/app-pda/Manifest.gz b/app-pda/Manifest.gz
index fb710d8ef5f9..db7b0aa5b0cb 100644
--- a/app-pda/Manifest.gz
+++ b/app-pda/Manifest.gz
diff --git a/app-pda/pilot-link/Manifest b/app-pda/pilot-link/Manifest
index d0372b0140f9..6da594c14e7e 100644
--- a/app-pda/pilot-link/Manifest
+++ b/app-pda/pilot-link/Manifest
@@ -1,4 +1,5 @@
 DIST pilot-link-0.12.5-gentoo-patchset.tar.bz2 8182 BLAKE2B db6e053bebc2876308d5bf5c29b86b9f22aecd0e75ed6d16e9214d63d73cb5e2dc7080bcd03a9d4dc21d4f2ef84d9632bac6cd36673d93915db9fd095ae12dfd SHA512 141900ef42d8a6716d7e0a219e1b75609f392c393376fb60f645561cfe1cf67ad9cec03321a31dcf1e8a70c75591df6eac4f727c957487496ab46ae6aa2dc90d
 DIST pilot-link-0.12.5.tar.bz2 1578735 BLAKE2B acc8748448d90928ac393e3d716f9d12c7962e18564a738b5f01e19bb225d610e179bb0694aded57979c7240df2652cac72845e5b8cdcddf6a4a800bbac4424b SHA512 a12972fb7a43f2dfccb82a046ca372c9fce5333f632a77880439c4f4705af6a7f16b76f04c9f3ed0d6a12aad55a3a55f8781a4e92931bc6907cd1ec4f1209868
 EBUILD pilot-link-0.12.5-r1.ebuild 2915 BLAKE2B c2f046807b4e573861361f522d59c318e800114095addac35d7f08355e7152ca35f5d4ba3450ed23ab42df1e3aeb671a6cc667567a8111a3053e42ef344c5dc8 SHA512 9376978300128ba5b930a36a497c4f8ce36640ad6cac9b0ca1412fd285f9202cfba1254f95d2157068cf42f66f44a16b73fc5bd0d59896a3b9bc88fef12acf57
+EBUILD pilot-link-0.12.5-r2.ebuild 3064 BLAKE2B 8dbad643c3855415b7e673458f7c624a90ba12f6b8609afd54b8a87bca58bca951163305f08fc5e2eb4eb0f208e5ff3c0c653f68f68aacc36becf37ca7d49d62 SHA512 f221e381a64fb2307081fde04a416c43f914e1486382a016696a1335caeb493bb908fc2852fb6a0f4944a9e2467fbce360ef8fa0fc78511caad37e59c75ff90c
 MISC metadata.xml 166 BLAKE2B c254f1fb642881aba57637be14fb0a89b10384f91a128feaec3a8c870d76efc2cbacb92caccc0dee2dd19a5ac5eaf8643080dafa05c4e2ac96a68568927e5afd SHA512 a56648c974a1d14dd4c18237532773c72057a13ab90c58b5da04f185e3c12a8bd8d5c21fb06053507f31766291a82dc7d87b34cd65fd94cfe2af7295c813ef84
diff --git a/app-pda/pilot-link/pilot-link-0.12.5-r2.ebuild b/app-pda/pilot-link/pilot-link-0.12.5-r2.ebuild
new file mode 100644
index 000000000000..0c758b2a6338
--- /dev/null
+++ b/app-pda/pilot-link/pilot-link-0.12.5-r2.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools distutils-r1 perl-module java-pkg-opt-2
+
+DESCRIPTION="Suite of tools for moving data between a Palm device and a desktop"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://gentoo/${P}.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/${P}-gentoo-patchset.tar.bz2"
+
+LICENSE="|| ( GPL-2 LGPL-2 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="bluetooth debug java perl png python static-libs threads usb"
+
+COMMON_DEPEND="
+	dev-libs/popt
+	>=sys-libs/ncurses-5.7-r7:0=
+	>=sys-libs/readline-6:0=
+	virtual/libiconv
+	bluetooth? ( net-wireless/bluez )
+	perl? ( >=dev-lang/perl-5.12 )
+	png? ( media-libs/libpng:0= )
+	usb? ( virtual/libusb:0 )
+"
+DEPEND="${COMMON_DEPEND}
+	java? ( >=virtual/jdk-1.4 )
+"
+RDEPEND="${COMMON_DEPEND}
+	java? ( >=virtual/jre-1.4 )
+"
+
+src_prepare() {
+	default
+
+	eapply -p0 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.3-java-install.patch
+	eapply -p0 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.3-respect-javacflags.patch
+	eapply -p0 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.2-werror_194921.patch
+	eapply -p1 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.2-threads.patch
+	eapply -p0 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.3-libpng14.patch
+	eapply -p1 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.3-png.patch
+	eapply -p0 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.3-distutils.patch
+	eapply -p1 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.3-libusb-compat-usb_open.patch
+	eapply -p1 "${WORKDIR}/${P}-gentoo-patchset"/${PN}-0.12.5-perl514.patch
+
+	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #467600
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_configure() {
+	# tcl/tk support is disabled as per upstream request.
+	# readline is not really optional, bug #626504
+	econf \
+		--includedir="${EPREFIX}"/usr/include/libpisock \
+		$(use_enable static-libs static) \
+		--enable-conduits \
+		--with-readline \
+		$(use_enable threads) \
+		$(use_enable usb libusb) \
+		$(use_enable debug) \
+		$(use_with png libpng) \
+		$(use_with bluetooth bluez) \
+		$(use_with perl) \
+		$(use_with java) \
+		--without-tcl \
+		$(use_with python)
+}
+
+src_compile() {
+	emake
+
+	if use perl; then
+		cd "${S}"/bindings/Perl
+		perl-module_src_configure
+		local mymake=( OTHERLDFLAGS="${LDFLAGS} -L../../libpisock/.libs -lpisock" ) #308629
+		perl-module_src_compile
+	fi
+
+	if use python; then
+		cd "${S}"/bindings/Python
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc ChangeLog NEWS README doc/{README*,TODO}
+
+	if use java; then
+		cd "${S}"/bindings/Java
+		java-pkg_newjar ${PN}.jar
+		java-pkg_doso libjpisock.so
+	fi
+
+	if use perl; then
+		cd "${S}"/bindings/Perl
+		perl-module_src_install
+	fi
+
+	if use python; then
+		cd "${S}"/bindings/Python
+		distutils-r1_src_install
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	perl_set_version
+	java-pkg-opt-2_pkg_preinst
+}