gentoo resync : 22.06.2019

5 files changed, 374 insertions, 0 deletions

diff --git a/app-misc/anki/anki-2.1.13.ebuild b/app-misc/anki/anki-2.1.13.ebuild
new file mode 100644
index 000000000000..bb38a02500c9
--- /dev/null
+++ b/app-misc/anki/anki-2.1.13.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_6 )
+PYTHON_REQ_USE="sqlite"
+
+inherit eutils python-single-r1 xdg
+
+DESCRIPTION="A spaced-repetition memory training program (flash cards)"
+HOMEPAGE="https://apps.ankiweb.net"
+SRC_URI="https://apps.ankiweb.net/downloads/current/${P}-source.tgz -> ${P}.tgz"
+
+S="${WORKDIR}/${P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="latex +recording +sound test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/PyQt5[gui,svg,webengine,widgets,${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.4[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	recording? ( media-sound/lame )
+	sound? ( media-video/mpv )
+	latex? (
+		app-text/texlive
+		app-text/dvipng
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/updates=True/updates=False/" \
+		aqt/profiles.py || die
+}
+
+src_compile() {
+	:;
+}
+
+src_test() {
+	sed -e "s:nose=nosetests$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests\":" \
+		-i tools/tests.sh || die
+	sed -e "s:nose=nosetests3$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests3\":" \
+		-i tools/tests.sh || die
+	sed -e "s:which nosetests3:which ${EROOT}usr/bin/nosetests3:" \
+		-i tools/tests.sh || die
+	./tools/tests.sh || die
+}
+
+src_install() {
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+	doman ${PN}.1
+
+	dodoc README.md README.development
+	python_domodule aqt anki
+	python_newscript runanki anki
+
+	# Localization files go into the anki directory:
+	python_moduleinto anki
+	python_domodule locale
+
+	# not sure if this is correct, but
+	# site-packages/aqt/mediasrv.py wants the directory
+	insinto /usr/share/anki
+	doins -r web
+}
diff --git a/app-misc/geoclue/files/geoclue-2.5.3-optional-vapi.patch b/app-misc/geoclue/files/geoclue-2.5.3-optional-vapi.patch
new file mode 100644
index 000000000000..874488decace
--- /dev/null
+++ b/app-misc/geoclue/files/geoclue-2.5.3-optional-vapi.patch
@@ -0,0 +1,47 @@
+From 56c7ca99dcadbf3e80ff2a9baf3e174f278b6a71 Mon Sep 17 00:00:00 2001
+From: Sobhan Mohammadpour <sobhan@gentoo.org>
+Date: Wed, 19 Jun 2019 01:16:16 -0400
+Subject: [PATCH] optinal vala
+
+---
+ libgeoclue/meson.build | 5 +++--
+ meson_options.txt      | 3 +++
+ 2 files changed, 6 insertions(+), 2 deletions(-)
+
+diff --git a/libgeoclue/meson.build b/libgeoclue/meson.build
+index e228ec3..e78a3e8 100644
+--- a/libgeoclue/meson.build
++++ b/libgeoclue/meson.build
+@@ -58,7 +58,8 @@ libgeoclue_dep = declare_dependency(link_with: libgeoclue,
+                                     sources: [ libgeoclue_sources, libgeoclue_headers ])
+ 
+ gir = find_program('g-ir-scanner', required: false)
+-vapigen = find_program('vapigen', required: false)
++vapigen_req = get_option('vapigen')
++vapigen = find_program('vapigen-ver', required: false)
+ enable_gir = get_option('introspection')
+ pkg_requirements = ['glib-2.0', 'gio-2.0', 'gio-unix-2.0']
+ gir_sources = [ libgeoclue_sources,
+@@ -78,7 +79,7 @@ if gir.found() and enable_gir
+                                install: true,
+                                header: 'geoclue.h',
+                                extra_args: [ '--quiet' ])
+-  if vapigen.found()
++  if vapigen.found() and vapigen_req
+     gnome.generate_vapi('libgeoclue-' + gclue_api_version,
+                         sources: geo_gir[0],
+                         packages: pkg_requirements,
+diff --git a/meson_options.txt b/meson_options.txt
+index 83bc60e..8611f6c 100644
+--- a/meson_options.txt
++++ b/meson_options.txt
+@@ -1,3 +1,6 @@
++option('vapigen',
++       type: 'boolean', value: false,
++       description: 'Enable vala?')
+ option('libgeoclue',
+         type: 'boolean', value: true,
+         description: 'Enable convenience library')
+-- 
+2.21.0
+
diff --git a/app-misc/geoclue/geoclue-2.5.3-r1.ebuild b/app-misc/geoclue/geoclue-2.5.3-r1.ebuild
new file mode 100644
index 000000000000..b4c7c3071852
--- /dev/null
+++ b/app-misc/geoclue/geoclue-2.5.3-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.32"
+
+inherit gnome.org meson systemd vala user xdg
+
+DESCRIPTION="A geoinformation D-Bus service"
+HOMEPAGE="https://gitlab.freedesktop.org/geoclue/geoclue/wikis/home"
+SRC_URI="https://gitlab.freedesktop.org/geoclue/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+#todo maybe add a use flat for libgeoclue
+IUSE="+introspection gtk-doc modemmanager vala zeroconf"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/json-glib-0.14
+	>=net-libs/libsoup-2.42:2.4
+	sys-apps/dbus
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	modemmanager? ( >=net-misc/modemmanager-1.6 )
+	zeroconf? ( >=net-dns/avahi-0.6.10[dbus] )
+	!<sci-geosciences/geocode-glib-3.10.0
+	x11-libs/libnotify
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-1
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? (  $(vala_depend) )
+"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-optional-vapi.patch
+
+	vala_src_prepare
+	sed -i -e "s:'vapigen-ver':'vapigen-$(vala_best_api_version)':" libgeoclue/meson.build || die
+	xdg_src_prepare
+}
+
+src_configure() {
+	# debug only affects CFLAGS
+	local emesonargs=(
+		$(meson_use gtk-doc)
+		$(meson_use vala vapigen)
+		-Ddbus-srv-user=geoclue \
+		-Denable-backend=true \
+		-Dlibgeoclue=true \
+		-Dsystemd-system-unit-dir="$(systemd_get_systemunitdir)" \
+		-Ddemo-agent=false \
+		$(meson_use introspection) \
+		$(meson_use modemmanager 3g-source) \
+		$(meson_use modemmanager cdma-source) \
+		$(meson_use modemmanager modem-gps-source) \
+		$(meson_use zeroconf nmea-source)
+	)
+	meson_src_configure
+}
+
+pkg_preinst() {
+	enewgroup geoclue
+	enewuser geoclue -1 -1 /var/lib/geoclue geoclue
+}
diff --git a/app-misc/getopt/getopt-1.1.6-r1.ebuild b/app-misc/getopt/getopt-1.1.6-r1.ebuild
new file mode 100644
index 000000000000..0acad8e55401
--- /dev/null
+++ b/app-misc/getopt/getopt-1.1.6-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs eutils
+
+DESCRIPTION="getopt(1) replacement supporting GNU-style long options"
+HOMEPAGE="http://frodo.looijaard.name/project/getopt/"
+SRC_URI="http://frodo.looijaard.name/system/files/software/getopt/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64-fbsd ~m68k-mint ~ppc-aix ~ppc-macos ~sparc-solaris ~sparc64-solaris ~x64-cygwin ~x64-macos ~x64-solaris ~x86-fbsd ~x86-macos ~x86-solaris"
+IUSE="nls"
+
+RDEPEND="nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1.5-libintl.patch
+	"${FILESDIR}"/${PN}-1.1.5-setlocale.patch
+	"${FILESDIR}"/${PN}-1.1.6-longrename.patch
+	"${FILESDIR}"/${PN}-1.1.4-irix.patch
+)
+
+src_compile() {
+	local nogettext="1"
+	local libintl=""
+	local libcgetopt=1
+
+	if use nls; then
+		nogettext=0
+		has_version sys-libs/glibc || libintl="-lintl"
+	fi
+
+	[[ ${CHOST} == *-aix* ]] && libcgetopt=0
+	[[ ${CHOST} == *-irix* ]] && libcgetopt=0
+	[[ ${CHOST} == *-interix* ]] && libcgetopt=0
+
+	emake CC="$(tc-getCC)" prefix="${EPREFIX}/usr" \
+		LIBCGETOPT=${libcgetopt} \
+		WITHOUT_GETTEXT=${nogettext} LIBINTL=${libintl} \
+		CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	use nls && emake prefix="${EPREFIX}/usr" DESTDIR="${D}" install_po
+
+	newbin getopt getopt-long
+
+	# at least on interix, the system getopt is ... broken...
+	# util-linux, which would provide the getopt binary, does not build &
+	# install on interix/prefix, so, this has to provide it.
+	[[ ${CHOST} == *-interix* || ${CHOST} == *-mint* ]] && \
+		dosym getopt-long /usr/bin/getopt
+
+	newman getopt.1 getopt-long.1
+
+	dodoc getopt-*sh
+}
diff --git a/app-misc/mosquitto/mosquitto-1.6.2.ebuild b/app-misc/mosquitto/mosquitto-1.6.2.ebuild
new file mode 100644
index 000000000000..0eb52c398c30
--- /dev/null
+++ b/app-misc/mosquitto/mosquitto-1.6.2.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_7 )
+
+inherit python-any-r1 systemd toolchain-funcs user
+
+DESCRIPTION="An Open Source MQTT v3 Broker"
+HOMEPAGE="https://mosquitto.org/"
+SRC_URI="https://mosquitto.org/files/source/${P}.tar.gz"
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="bridge examples +persistence +srv ssl tcpd test websockets"
+
+REQUIRED_USE="test? ( bridge )"
+
+RDEPEND="srv? ( net-dns/c-ares:= )
+	ssl? ( dev-libs/openssl:0= )
+	tcpd? ( sys-apps/tcp-wrappers )"
+
+DEPEND="${PYTHON_DEPS}
+	${RDEPEND}
+	test? ( dev-util/cunit )
+	websockets? ( net-libs/libwebsockets )"
+
+_emake() {
+	local LIBDIR=$(get_libdir)
+	emake \
+		CC="$(tc-getCC)" \
+		CLIENT_LDFLAGS="${LDFLAGS}" \
+		LIB_SUFFIX="${LIBDIR:3}" \
+		WITH_BRIDGE="$(usex bridge)" \
+		WITH_PERSISTENCE="$(usex persistence)" \
+		WITH_SRV="$(usex srv)" \
+		WITH_TLS="$(usex ssl)" \
+		WITH_WEBSOCKETS="$(usex websockets)" \
+		WITH_WRAP="$(usex tcpd)" \
+		"$@"
+}
+
+pkg_setup() {
+	enewgroup mosquitto
+	enewuser mosquitto -1 -1 -1 mosquitto
+}
+
+src_prepare() {
+	default
+	if use persistence; then
+		sed -i -e "/^#autosave_interval/s|^#||" \
+			-e "s|^#persistence false$|persistence true|" \
+			-e "/^#persistence_file/s|^#||" \
+			-e "s|#persistence_location|persistence_location /var/lib/mosquitto/|" \
+			mosquitto.conf || die
+	fi
+
+	# Remove prestripping
+	sed -i -e 's/-s --strip-program=${CROSS_COMPILE}${STRIP}//'\
+		client/Makefile lib/cpp/Makefile src/Makefile lib/Makefile || die
+
+	# Remove failing tests
+	sed -i -e '/02-subpub-qos1-bad-pubcomp.py/d' \
+		-e '/02-subpub-qos1-bad-pubrec.py/d' \
+		-e '/02-subpub-qos2-bad-puback-1.py/d' \
+		-e '/02-subpub-qos2-bad-puback-2.py/d' \
+		-e '/02-subpub-qos2-bad-pubcomp.py/d' \
+		-e '/11-message-expiry.py/d' test/broker/Makefile || die
+
+	python_setup
+	python_fix_shebang test
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${D}" prefix=/usr install
+	keepdir /var/lib/mosquitto
+	fowners mosquitto:mosquitto /var/lib/mosquitto
+	dodoc readme.md CONTRIBUTING.md ChangeLog.txt
+	doinitd "${FILESDIR}"/mosquitto
+	insinto /etc/mosquitto
+	doins mosquitto.conf
+	systemd_dounit "${FILESDIR}/mosquitto.service"
+
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "The Python module has been moved out of mosquitto."
+		elog "See https://mosquitto.org/documentation/python/"
+	else
+		elog "To start the mosquitto daemon at boot, add it to the default runlevel with:"
+		elog ""
+		elog "    rc-update add mosquitto default"
+		elog "or"
+		elog "    systemctl enable mosquitto"
+	fi
+}