gentoo resync : 14.07.2018

3 files changed, 0 insertions, 282 deletions

diff --git a/app-misc/tracker/Manifest b/app-misc/tracker/Manifest
deleted file mode 100644
index 0b81af2a95a1..000000000000
--- a/app-misc/tracker/Manifest
+++ /dev/null
@@ -1,3 +0,0 @@
-DIST tracker-1.12.4.tar.xz 5051884 BLAKE2B 99cc85fc4d49691eb0a73e4f1776d9971b5cbe5844478825e473137b4d7b13e2578065be497da57285abc2d3cf4c6d1ed1b077a01cd68dc093e18ddd7674c1f1 SHA512 e81af22733c7d80535c79e23a4b3edbbcf888eede1dff071d466518054e90d4c207af76bcb4d8c73dc20729ae2eab60444ca91ee7ae09e96c0da2fdab97752c1
-EBUILD tracker-1.12.4.ebuild 7607 BLAKE2B 81fad33e737d27d9c27f4f9817a5f38a96d51e8d56f03e04da8b5ad4a131bd73243a2046cf2401bfbdcadaa6058da9fcf3305a816cd975f4134db06245a9b121 SHA512 cf76e06d94b6d64930ffdf04e9aa9f660f294a2ed7360f8a99fdd220747e08d376eb44c4b46194dd599357f2ef3e0abf56d21dbfd69ad366ace1c0172447fca3
-MISC metadata.xml 1561 BLAKE2B ce0e9984983c7e0f249af4d375361f64236fb38d105b9ce2cee6c12519c70d4e8c7801a6000adfe777b2f9bb787c47779246b148dbbb5ec6fb6e94356413d8d3 SHA512 89deedce6c26547cdc8a2b3ff1880662125b73f490293156904a942acf632e1325dbc3657cdd6a1ca53cdb7556adbd96fea2705759a0a5503e80ae95d90045c4
diff --git a/app-misc/tracker/metadata.xml b/app-misc/tracker/metadata.xml
deleted file mode 100644
index 64efbfdb6eb6..000000000000
--- a/app-misc/tracker/metadata.xml
+++ /dev/null
@@ -1,30 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-  <maintainer type="project">
-    <email>gnome@gentoo.org</email>
-    <name>Gentoo GNOME Desktop</name>
-  </maintainer>
-  <use>
-    <flag name="cue">Enable cue sheet parsing</flag>
-    <!-- 'firefox-bookmarks' instead of 'firefox' to prevent most users from
-       enabling this by accident; it has some stability problems and
-       performance implications -->
-    <flag name="firefox-bookmarks">Install bookmark data miner plugin for
-    <pkg>www-client/firefox</pkg> and <pkg>www-client/firefox-bin</pkg></flag>
-    <flag name="gsf">Enable <pkg>gnome-extra/libgsf</pkg> based data extractor and
-  for ODT.</flag>
-    <flag name="iptc">Enable extraction of IPTC data from pictures</flag>
-    <flag name="iso">Enable extraction of metadata from ISO disk images</flag>
-    <flag name="miner-fs">Enable tracker-miner-fs (required for filesystem indexing)</flag>
-    <flag name="nautilus">Enable tracker to integrate with
-    <pkg>gnome-base/nautilus</pkg> by providing entries in its context menu
-  </flag>
-    <flag name="playlist">Add support for playlists</flag>
-    <flag name="stemmer">Add word stemming via <pkg>dev-libs/snowball-stemmer</pkg>.</flag>
-    <flag name="thunderbird">Install email data miner plugin for
-    <pkg>mail-client/thunderbird</pkg> and
-    <pkg>mail-client/thunderbird-bin</pkg></flag>
-    <flag name="xps">Add support for XPS file format through <pkg>app-text/libgxps</pkg>.</flag>
-  </use>
-</pkgmetadata>
diff --git a/app-misc/tracker/tracker-1.12.4.ebuild b/app-misc/tracker/tracker-1.12.4.ebuild
deleted file mode 100644
index 0cc6d681e2d8..000000000000
--- a/app-misc/tracker/tracker-1.12.4.ebuild
+++ /dev/null
@@ -1,249 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-GNOME2_LA_PUNT="yes"
-PYTHON_COMPAT=( python2_7 )
-
-inherit autotools bash-completion-r1 eutils gnome2 linux-info multilib python-any-r1 vala versionator virtualx
-
-DESCRIPTION="A tagging metadata database, search tool and indexer"
-HOMEPAGE="https://wiki.gnome.org/Projects/Tracker"
-
-LICENSE="GPL-2+ LGPL-2.1+"
-SLOT="0/100"
-IUSE="cue elibc_glibc exif ffmpeg firefox-bookmarks flac gif gsf gstreamer
-gtk iptc +iso +jpeg libav +miner-fs mp3 nautilus networkmanager pdf playlist
-rss seccomp stemmer test thunderbird +tiff upnp-av upower +vorbis +xml xmp xps"
-
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86"
-
-REQUIRED_USE="
-	?? ( gstreamer ffmpeg )
-	cue? ( gstreamer )
-	upnp-av? ( gstreamer )
-	!miner-fs? ( !cue !exif !flac !gif !gsf !iptc !iso !jpeg !mp3 !pdf !playlist !tiff !vorbis !xml !xmp !xps )
-"
-
-# According to NEWS, introspection is non-optional
-# glibc-2.12 needed for SCHED_IDLE (see bug #385003)
-# seccomp is automagic, though we want to use it whenever possible (linux)
-# >=media-libs/libmediaart-1.9:2.0 is suggested to be disabled for 1.10 for security;
-# It is disable in configure in 1.12; revisit for 1.14/2 (configure flag)
-RDEPEND="
-	>=app-i18n/enca-1.9
-	>=dev-db/sqlite-3.20:=
-	>=dev-libs/glib-2.44:2
-	>=dev-libs/gobject-introspection-0.9.5:=
-	>=dev-libs/icu-4.8.1.1:=
-	>=dev-libs/json-glib-1.0
-	>=media-libs/libpng-1.2:0=
-	>=net-libs/libsoup-2.40:2.4
-	>=x11-libs/pango-1:=
-	sys-apps/util-linux
-	virtual/imagemagick-tools[png,jpeg?]
-
-	cue? ( media-libs/libcue )
-	elibc_glibc? ( >=sys-libs/glibc-2.12 )
-	exif? ( >=media-libs/libexif-0.6 )
-	ffmpeg? (
-		libav? ( media-video/libav:= )
-		!libav? ( media-video/ffmpeg:0= )
-	)
-	firefox-bookmarks? ( || (
-		>=www-client/firefox-4.0
-		>=www-client/firefox-bin-4.0 ) )
-	flac? ( >=media-libs/flac-1.2.1 )
-	gif? ( media-libs/giflib:= )
-	gsf? ( >=gnome-extra/libgsf-1.14.24 )
-	gstreamer? (
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0 )
-	gtk? (
-		>=x11-libs/gtk+-3:3 )
-	iptc? ( media-libs/libiptcdata )
-	iso? ( >=sys-libs/libosinfo-0.2.9:= )
-	jpeg? ( virtual/jpeg:0 )
-	upower? ( || ( >=sys-power/upower-0.9 sys-power/upower-pm-utils ) )
-	mp3? ( >=media-libs/taglib-1.6 )
-	networkmanager? ( >=net-misc/networkmanager-0.8:= )
-	pdf? (
-		>=x11-libs/cairo-1:=
-		>=app-text/poppler-0.16[cairo,utils]
-		>=x11-libs/gtk+-2.12:2 )
-	playlist? ( >=dev-libs/totem-pl-parser-3 )
-	rss? ( >=net-libs/libgrss-0.7:0 )
-	stemmer? ( dev-libs/snowball-stemmer )
-	thunderbird? ( || (
-		>=mail-client/thunderbird-5.0
-		>=mail-client/thunderbird-bin-5.0 ) )
-	tiff? ( media-libs/tiff:0 )
-	upnp-av? ( >=media-libs/gupnp-dlna-0.9.4:2.0 )
-	vorbis? ( >=media-libs/libvorbis-0.22 )
-	xml? ( >=dev-libs/libxml2-2.6 )
-	xmp? ( >=media-libs/exempi-2.1 )
-	xps? ( app-text/libgxps )
-	!gstreamer? ( !ffmpeg? ( || ( media-video/totem media-video/mplayer ) ) )
-	seccomp? ( >=sys-libs/libseccomp-2.0 )
-"
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	$(vala_depend)
-	dev-util/gdbus-codegen
-	>=dev-util/gtk-doc-am-1.8
-	>=dev-util/intltool-0.40.0
-	>=sys-devel/gettext-0.17
-	virtual/pkgconfig
-	test? (
-		>=dev-libs/dbus-glib-0.82-r1
-		>=sys-apps/dbus-1.3.1[X] )
-"
-PDEPEND="nautilus? ( ~gnome-extra/nautilus-tracker-tags-${PV} )"
-
-function inotify_enabled() {
-	if linux_config_exists; then
-		if ! linux_chkconfig_present INOTIFY_USER; then
-			ewarn "You should enable the INOTIFY support in your kernel."
-			ewarn "Check the 'Inotify support for userland' under the 'File systems'"
-			ewarn "option. It is marked as CONFIG_INOTIFY_USER in the config"
-			die 'missing CONFIG_INOTIFY'
-		fi
-	else
-		einfo "Could not check for INOTIFY support in your kernel."
-	fi
-}
-
-pkg_setup() {
-	linux-info_pkg_setup
-	inotify_enabled
-
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	# Don't run 'firefox --version' or 'thunderbird --version'; it results in
-	# access violations on some setups (bug #385347, #385495).
-	create_version_script "www-client/firefox" "Mozilla Firefox" firefox-version.sh
-	create_version_script "mail-client/thunderbird" "Mozilla Thunderbird" thunderbird-version.sh
-
-	eautoreconf # See bug #367975
-	gnome2_src_prepare
-	vala_src_prepare
-}
-
-src_configure() {
-	local myconf=""
-
-	if use gstreamer ; then
-		myconf="${myconf} --enable-generic-media-extractor=gstreamer"
-		if use upnp-av; then
-			myconf="${myconf} --with-gstreamer-backend=gupnp-dlna"
-		else
-			myconf="${myconf} --with-gstreamer-backend=discoverer"
-		fi
-	elif use ffmpeg ; then
-		myconf="${myconf} --enable-generic-media-extractor=libav"
-	else
-		myconf="${myconf} --enable-generic-media-extractor=external"
-	fi
-
-	# unicode-support: libunistring, libicu or glib ?
-	# According to NEWS, introspection is required
-	# is not being generated
-	# nautilus extension is in a separate package, nautilus-tracker-tags
-	# miner-evolution disabled as it's incompatible with current eds
-	gnome2_src_configure \
-		--disable-hal \
-		--disable-miner-evolution \
-		--disable-nautilus-extension \
-		--disable-static \
-		--enable-abiword \
-		--enable-artwork \
-		--enable-dvi \
-		--enable-enca \
-		--enable-guarantee-metadata \
-		--enable-icon \
-		--enable-introspection \
-		--disable-libmediaart \
-		--enable-libpng \
-		--enable-miner-apps \
-		--enable-miner-user-guides \
-		--enable-ps \
-		--enable-text \
-		--enable-tracker-fts \
-		--enable-tracker-writeback \
-		--with-unicode-support=libicu \
-		--with-bash-completion-dir="$(get_bashcompdir)" \
-		$(use_enable cue libcue) \
-		$(use_enable exif libexif) \
-		$(use_enable firefox-bookmarks miner-firefox) \
-		$(use_with firefox-bookmarks firefox-plugin-dir "${EPREFIX}"/usr/$(get_libdir)/firefox/extensions) \
-		FIREFOX="${S}"/firefox-version.sh \
-		$(use_enable flac libflac) \
-		$(use_enable gif libgif) \
-		$(use_enable gsf libgsf) \
-		$(use_enable gtk tracker-needle) \
-		$(use_enable gtk tracker-preferences) \
-		$(use_enable iptc libiptcdata) \
-		$(use_enable iso libosinfo) \
-		$(use_enable jpeg libjpeg) \
-		$(use_enable upower upower) \
-		$(use_enable miner-fs) \
-		$(use_enable mp3 taglib) \
-		$(use_enable mp3) \
-		$(use_enable networkmanager network-manager) \
-		$(use_enable pdf poppler) \
-		$(use_enable playlist) \
-		$(use_enable rss miner-rss) \
-		$(use_enable stemmer libstemmer) \
-		$(use_enable test functional-tests) \
-		$(use_enable test unit-tests) \
-		$(use_enable thunderbird miner-thunderbird) \
-		$(use_with thunderbird thunderbird-plugin-dir "${EPREFIX}"/usr/$(get_libdir)/thunderbird/extensions) \
-		THUNDERBIRD="${S}"/thunderbird-version.sh \
-		$(use_enable tiff libtiff) \
-		$(use_enable vorbis libvorbis) \
-		$(use_enable xml libxml2) \
-		$(use_enable xmp exempi) \
-		$(use_enable xps libgxps) \
-		${myconf}
-}
-
-src_test() {
-	# G_MESSAGES_DEBUG, upstream bug #699401#c1
-	virtx emake check TESTS_ENVIRONMENT="dbus-run-session" G_MESSAGES_DEBUG="all"
-}
-
-src_install() {
-	gnome2_src_install
-
-	# Manually symlink extensions for {firefox,thunderbird}-bin
-	if use firefox-bookmarks; then
-		dosym ../../../share/xul-ext/trackerfox \
-			/usr/$(get_libdir)/firefox-bin/extensions/trackerfox@bustany.org
-	fi
-
-	if use thunderbird; then
-		dosym ../../../share/xul-ext/trackerbird \
-			/usr/$(get_libdir)/thunderbird-bin/extensions/trackerbird@bustany.org
-	fi
-}
-
-create_version_script() {
-	# Create script $3 that prints "$2 MAX(VERSION($1), VERSION($1-bin))"
-
-	local v=$(best_version ${1})
-	v=${v#${1}-}
-	local vbin=$(best_version ${1}-bin)
-	vbin=${vbin#${1}-bin-}
-
-	if [[ -z ${v} ]]; then
-		v=${vbin}
-	else
-		version_compare ${v} ${vbin}
-		[[ $? -eq 1 ]] && v=${vbin}
-	fi
-
-	echo -e "#!/bin/sh\necho $2 $v" > "$3" || die
-	chmod +x "$3" || die
-}