gentoo auto-resync : 26:01:2024 - 18:57:55

2 files changed, 119 insertions, 0 deletions

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 621da0e70d11..886ef1bc1129 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,7 +1,9 @@
 DIST fastfetch-2.2.3.tar.gz 901203 BLAKE2B d6d097b72ce2f252e42b3e59cbd26b43a4f17ae974382f986270fbf91b457cf3c49e78a3c775e713d9302d536fb5a363e809005b9174d1a27622e6b6ed666709 SHA512 81e051b7555d56415c723606c0b6dfc3ad7ed91fb2c7b36c07465f4dfbdb91da5c8d216e46df36863888448de0a7bd63e28c6aa701995bf1165e0d7c33c4f724
 DIST fastfetch-2.6.3.tar.gz 996379 BLAKE2B f449abfe4b2cb75a04d7259957ae9c9da951123ad3a3e6b2178cb4dd04c4a42462ab77413446c7b23657e7c5a2da95f01e84dfd8299280e53e4bd563036bf7a7 SHA512 d32a9a2e80f8138af3ec5467d44ab89a8f34adfccf97480f28d947eb21a05178c8f3719c8a78d6f63027cd2b783a3f04ab9c3534f791f069000f726d7eca4e7d
+DIST fastfetch-2.7.0.tar.gz 1000300 BLAKE2B 5c6390e9581515bf20a01d6aebd9158845c5bb7665b7c36260e3922b4327198d31ed2439006292a5982ee820ffb36e8c1dfa380eb845117f5ed10ba329b420e1 SHA512 e20e2c6dfa6a8805460eece02afd9ced29e894b6b944537e95e3a2cbcbcfcb1ef356bfc0ccdbcb8eee1f09725a1f7eb71dcecfbbca39713880b428956f37696f
 EBUILD fastfetch-0.1.9999.ebuild 3286 BLAKE2B 1053ae09434fc4607b709b00d07d46327e098985021925956e84ed69378925859afc0d84a970dba5a11bbbf2ebe76b0db89ba08ab155d2633583fdc8bbfc8216 SHA512 1072af3c2abd7241af57471b3e9df0add0029df2e3f43c26fbb31d05e71a3d2c221db3d65f160fb4aa934d74385c0b65d83d4ac7c1a0f690fccf32567c901d90
 EBUILD fastfetch-0.2.9999.ebuild 3343 BLAKE2B 1b3c20d502d08eac2f2e63df6f755878b94a103e6d54a03171b8f8482c77dac3fd28d4eea9dd0b01e1d25c6259e2a3eb1ae6edfa33e8537f8598e8f7dc2934a3 SHA512 593e23e2363cc8a5cde69108e711b55f45a8541b1317ca5b12bf9b55fd8faea1c7d69902aef04eaf0030aacf3abd16391aabb0a07b1c9066581301d72b783d83
 EBUILD fastfetch-2.2.3-r1.ebuild 3190 BLAKE2B f98df2430184abc34138f6fdb0be1efc43ab2805bc8cb78ced628cb52d33ca24c726312a4e5ce8e9439cd98b188028feab88850f58aa1e37cfca0bdf09740b50 SHA512 646f925ff00be6c2a248663d2c2a5cd758568f3e5c622a7553d1c94bd6c5fea471dccba24b9ebbfa98ef5826c50335cb13cbc775c5c8771dff230031a3e0880d
 EBUILD fastfetch-2.6.3.ebuild 3343 BLAKE2B 1b3c20d502d08eac2f2e63df6f755878b94a103e6d54a03171b8f8482c77dac3fd28d4eea9dd0b01e1d25c6259e2a3eb1ae6edfa33e8537f8598e8f7dc2934a3 SHA512 593e23e2363cc8a5cde69108e711b55f45a8541b1317ca5b12bf9b55fd8faea1c7d69902aef04eaf0030aacf3abd16391aabb0a07b1c9066581301d72b783d83
+EBUILD fastfetch-2.7.0.ebuild 3343 BLAKE2B 1b3c20d502d08eac2f2e63df6f755878b94a103e6d54a03171b8f8482c77dac3fd28d4eea9dd0b01e1d25c6259e2a3eb1ae6edfa33e8537f8598e8f7dc2934a3 SHA512 593e23e2363cc8a5cde69108e711b55f45a8541b1317ca5b12bf9b55fd8faea1c7d69902aef04eaf0030aacf3abd16391aabb0a07b1c9066581301d72b783d83
 MISC metadata.xml 1257 BLAKE2B 521e87300ee660b7285c28ed7987a4cc52565e1c6fec3a10e37509822f829f808d468bd119ace4bea96d441b82d2cdce598d9d3cd25bacda5fae05920818a4bb SHA512 461c8f2f48789fe2635bb419f7655389a190b5684b9e1367dfb8faa7b6650984b001c8ac76051c39040526d51c71ac2faf566f0fd5a2f2e75c0702885eefa32a
diff --git a/app-misc/fastfetch/fastfetch-2.7.0.ebuild b/app-misc/fastfetch/fastfetch-2.7.0.ebuild
new file mode 100644
index 000000000000..ff81f55971fe
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.7.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pci pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.8.0:=
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}