gentoo resync : 15.12.2019

1 files changed, 44 insertions, 0 deletions

diff --git a/app-misc/binwalk/binwalk-2.2.0.ebuild b/app-misc/binwalk/binwalk-2.2.0.ebuild
new file mode 100644
index 000000000000..cd3986d63469
--- /dev/null
+++ b/app-misc/binwalk/binwalk-2.2.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7,3_8} )
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/ReFirmLabs/binwalk.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ReFirmLabs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="A tool for identifying files embedded inside firmware images"
+HOMEPAGE="https://github.com/ReFirmLabs/binwalk"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="$(python_gen_cond_dep 'dev-python/backports-lzma[${PYTHON_USEDEP}]' python2_7)"
+BDEPEND="test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.2.0-disable-test-coverage.patch )
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOCS=( API.md INSTALL.md README.md )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "binwalk has many optional dependencies to automatically"
+		elog "extract/decompress data, see INSTALL.md for more details."
+	fi
+}