gentoo resync : 31.03.2018

1 files changed, 54 insertions, 0 deletions

diff --git a/app-metrics/uwsgi_exporter/uwsgi_exporter-0.7.0.ebuild b/app-metrics/uwsgi_exporter/uwsgi_exporter-0.7.0.ebuild
new file mode 100644
index 000000000000..7c5dd6280d85
--- /dev/null
+++ b/app-metrics/uwsgi_exporter/uwsgi_exporter-0.7.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit user golang-build golang-vcs-snapshot systemd
+
+EGO_PN="github.com/timonwong/uwsgi_exporter"
+EGIT_COMMIT="v${PV/_rc/-rc.}"
+UWSGI_EXPORTER_COMMIT="20e35a9"
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="uWSGI metrics exporter for prometheus.io"
+HOMEPAGE="https://github.com/timonwong/uwsgi_exporter"
+SRC_URI="${ARCHIVE_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-util/promu"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/{{.Revision}}/${UWSGI_EXPORTER_COMMIT}/" src/${EGO_PN}/.promu.yml || die
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	mkdir -p bin || die
+	GOPATH="${S}" promu build -v --prefix bin || die
+	popd || die
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin bin/uwsgi_exporter
+	dodoc README.md
+	popd || die
+	local dir
+	for dir in /var/{lib,log}/${PN}; do
+		keepdir "${dir}"
+		fowners ${PN}:${PN} "${dir}"
+	done
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+}