gentoo auto-resync : 12:09:2023 - 04:40:07

3 files changed, 234 insertions, 0 deletions

diff --git a/app-i18n/Manifest.gz b/app-i18n/Manifest.gz
index 162dfb3d149a..93da7cde7c45 100644
--- a/app-i18n/Manifest.gz
+++ b/app-i18n/Manifest.gz
diff --git a/app-i18n/ibus/Manifest b/app-i18n/ibus/Manifest
index 96bad167ff38..cbd6a520713f 100644
--- a/app-i18n/ibus/Manifest
+++ b/app-i18n/ibus/Manifest
@@ -3,8 +3,10 @@ DIST ibus-1.5.26.tar.gz 3715263 BLAKE2B 80eb293b028d431b76c015c6d6d9fea92888554f
 DIST ibus-1.5.27.tar.gz 3779541 BLAKE2B e98f775cd62036ae02dafd984933343e99390a6a1e77b672feb4bc00dd1d423126227bded2d22b8bc9fa214e572ea906c407658de8ee20e036f8753836d68f46 SHA512 b5f3ae555d19eb780a416383e6351ed2cd8834fcc2bc4ebe4f4a194fc934dd055c5e782f9ec382fb21e1e2103c5409804174a79d192b5494a9018ce9081305e4
 DIST ibus-1.5.28-upstream-patches-0.tar.xz 23820 BLAKE2B 773736257e166170060458ad66b99889d2e54ef480504fe86ee65bc41364243ddcb5c7625aaa66a3e266c735d024c4f6c51d559484214d1f1c04a30479ccba62 SHA512 5555162bcb129f9e07c135c921c778de080aeaec81d56bedcf62d3b568cf39515e41662790c5a3d34241586d58785b887bbbaa7a75f486338968e3a496aa6433
 DIST ibus-1.5.28.tar.gz 3871246 BLAKE2B 7117c09e708df8a08e6684cc1096f38873503eb2c7937e0e3b02aeff678c96b3e2fc59fa4dfc7a11275b2e1b3349ae136041f8f4730aadc66339914b77c577d3 SHA512 5bfb9158a5810d38af900775ed30406823872c431ef4772b476afa7b58c120ef508a51b961620ea6003549f1f49cf05484992beee8677b138f1162afc73ab247
+DIST ibus-1.5.29-rc1.tar.gz 3989492 BLAKE2B c99f42fcd18bed240bf5e9f5b406bc879b05b12f3d0c14713e21b8c99fbcde32cd880dead1374731914289c022b1f160d9961bdbd9e9a0a3ced86949c5beb811 SHA512 776a01bcfd730be67e0f7d730f7b4b0a586d39744deb605359330a1786542acae52efbc085c39b8417b20164e45c259b40b29725f53fb1b69e2b340778ff28dc
 EBUILD ibus-1.5.26-r1.ebuild 5533 BLAKE2B 75716903dc3b6ad5034c22dcd2bdaf60ec07170d2f23cebcf5e9685ae5799ea5158ea041a37210d3d2b74c8338f501c9729af450c814f0cc2f20596620084564 SHA512 8431264247a824557e20dfce4e440edef9f34c694f27b0c6671e699ac32d124ee1119378e1e0004f4f05cfd9cf16284b281efc1fa4c1df31f5972230b961505e
 EBUILD ibus-1.5.27.ebuild 5700 BLAKE2B 58c61606ed583acd02ffcce71b9c92ff066307955de07e9939acf730f55d73b220d8913d3c9e5ea506b62c3f90b9cad09ac6e463e5aa129ad154a366c99fbc57 SHA512 58614dfd8df3b59b6962f76f44679eb1663d909538b8a6f4ca0e591b4a4c98ca83d8cc663e54232928d3e35d1899f80ffa081deb95a59f1e09f6cc361cf6b83b
 EBUILD ibus-1.5.28-r1.ebuild 6032 BLAKE2B 1be3511a08ecab5c8957161a69a78759967a1249d462d59879c8fbac9729165fd467ee86292cea0fc8738118a03601d3fb6f7fc879daeefdd73cab5ab2b3341a SHA512 95ecf15f596bf1d9ee8d0e3d86c33c6acd3cc3826b39d7a6967d356c4b89c5b60bebca5862878d55ee3610725ae3453a29f60defdb08fd8eab69e382d11b618d
 EBUILD ibus-1.5.28.ebuild 5707 BLAKE2B 91f9c3df682d60ebd42679e518ac1d2697c6a6c5f94a63ebde283d2c9e63dbc55181f28fcd03eb5324bb9a3c4ff6753f6bd1d4ff4262b0a8d7f0c018d0635f29 SHA512 164902af52536db045b4be5ab9b9b4404f3939d1861628797598773ad61d293d99a7cd823a37fe36553aac0eb35c79839944297a8262729c0cbf3ff0a1b119d2
+EBUILD ibus-1.5.29_rc1.ebuild 5714 BLAKE2B 215a97916fb65f78803939cce1cb55ea9207e7c7a5e334083927f8dccf6ddba63e1a7f4a749013d3e75b066d84c17eb205a5578fca70dcbb488d2adaf55c9e72 SHA512 1df4b581c9b04d614cdaa4a29bbc2ddad679caa2e2e5114213dc3f403e9abd3d94235f4ef7f9a1ec87117361c30c691d0d085892953adb2d9db5e98267ba3274
 MISC metadata.xml 989 BLAKE2B 9103c61af6f3766fa483864877a674455d0a47a2e7fc1e7ef0f62d835e1f57d6c71816737c64938babd5f29a7228d67f64c1d7aaaae0e9b10cc793ed373a698c SHA512 1552ed06ec527f6c9868b2b006b1d5d7bdc7101d34d4c4438eba6de74f398744a2720e31f73dc203f034631aa900db0a2ad8d429a67e577b69005cda1440f1ef
diff --git a/app-i18n/ibus/ibus-1.5.29_rc1.ebuild b/app-i18n/ibus/ibus-1.5.29_rc1.ebuild
new file mode 100644
index 000000000000..10fdab116676
--- /dev/null
+++ b/app-i18n/ibus/ibus-1.5.29_rc1.ebuild
@@ -0,0 +1,232 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit autotools bash-completion-r1 gnome2-utils python-r1 toolchain-funcs vala virtualx
+
+DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+
+MY_PV=$(ver_rs 3 '-')
+GENTOO_VER=
+[[ -n ${GENTOO_VER} ]] && \
+	GENTOO_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${P}-gentoo-patches-${GENTOO_VER}.tar.xz"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${MY_PV}/${PN}-${MY_PV}.tar.gz
+	${GENTOO_PATCHSET_URI}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="X appindicator +emoji gtk2 +gtk3 +gtk4 +gui +introspection libnotify nls +python systemd test +unicode vala wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	appindicator? ( gtk3 )
+	python? (
+		${PYTHON_REQUIRED_USE}
+		introspection
+	)
+	test? ( gtk3 )
+	vala? ( introspection )
+	X? ( gtk3 )
+"
+DEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.65.0:2
+	gnome-base/dconf
+	gnome-base/librsvg:2
+	sys-apps/dbus[X?]
+	X? (
+		x11-libs/libX11
+		>=x11-libs/libXfixes-6.0.0
+	)
+	appindicator? ( dev-libs/libdbusmenu[gtk3?] )
+	gtk2? ( x11-libs/gtk+:2 )
+	gtk3? ( x11-libs/gtk+:3 )
+	gtk4? ( gui-libs/gtk:4 )
+	gui? (
+		x11-libs/libX11
+		x11-libs/libXi
+	)
+	introspection? ( dev-libs/gobject-introspection )
+	libnotify? ( x11-libs/libnotify )
+	nls? ( virtual/libintl )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)"
+RDEPEND="${DEPEND}
+	python? (
+		gui? (
+			x11-libs/gtk+:3[introspection]
+		)
+	)"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/glib:2
+	dev-util/glib-utils
+	virtual/pkgconfig
+	x11-misc/xkeyboard-config
+	emoji? (
+		app-i18n/unicode-cldr
+		app-i18n/unicode-emoji
+	)
+	nls? ( sys-devel/gettext )
+	test? ( x11-apps/setxkbmap )
+	unicode? ( app-i18n/unicode-data )"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_prepare() {
+	vala_setup --ignore-use
+	if ! has_version 'x11-libs/gtk+:3[wayland]'; then
+		touch ui/gtk3/panelbinding.vala \
+			ui/gtk3/panel.vala \
+			ui/gtk3/emojierapp.vala || die
+	fi
+	if ! use emoji; then
+		touch \
+			tools/main.vala \
+			ui/gtk3/panel.vala || die
+	fi
+	if ! use appindicator; then
+		touch ui/gtk3/panel.vala || die
+	fi
+	if [[ -n ${GENTOO_VER} ]]; then
+		einfo "Try to apply Gentoo specific patch set"
+		eapply "${WORKDIR}"/patches-gentoo/*.patch
+	fi
+
+	# for multiple Python implementations
+	sed -i "s/^\(PYGOBJECT_DIR =\).*/\1/" bindings/Makefile.am || die
+	# fix for parallel install
+	sed -i "/^if ENABLE_PYTHON2/,/^endif/d" bindings/pygobject/Makefile.am || die
+	# require user interaction
+	sed -i "/^TESTS_C += ibus-\(compose\|keypress\)/d" src/tests/Makefile.am || die
+
+	sed -i "/^bash_completion/d" tools/Makefile.am || die
+
+	default
+	eautoreconf
+	xdg_environment_reset
+}
+
+src_configure() {
+	local unicodedir="${EPREFIX}"/usr/share/unicode
+	local python_conf=()
+	if use python; then
+		python_setup
+		python_conf+=(
+			$(use_enable gui setup)
+			--with-python=${EPYTHON}
+		)
+	else
+		python_conf+=( --disable-setup )
+	fi
+
+	if tc-is-cross-compiler && { use emoji || use unicode; }; then
+		mkdir -p "${S}-build"
+		pushd "${S}-build" >/dev/null 2>&1 || die
+		ECONF_SOURCE=${S} econf_build --enable-static \
+			--disable-{dconf,gtk{2,3},python-library,shared,xim} \
+			ISOCODES_{CFLAG,LIB}S=-DSKIP \
+			$(use_enable emoji emoji-dict) \
+			$(use_enable unicode unicode-dict) \
+			$(use_with unicode ucd-dir "${EPREFIX}/usr/share/unicode-data")
+		popd >/dev/null 2>&1 || die
+	fi
+
+	local myconf=(
+		$(use_enable X xim)
+		$(use_enable appindicator)
+		$(use_enable emoji emoji-dict)
+		$(use_with emoji unicode-emoji-dir "${unicodedir}"/emoji)
+		$(use_with emoji emoji-annotation-dir "${unicodedir}"/cldr/common/annotations)
+		$(use_enable gtk2)
+		$(use_enable gtk3)
+		$(use_enable gtk4)
+		$(use_enable gui ui)
+		$(use_enable introspection)
+		$(use_enable libnotify)
+		$(use_enable nls)
+		$(use_enable systemd systemd-services)
+		$(use_enable test tests)
+		$(use_enable unicode unicode-dict)
+		$(use_with unicode ucd-dir "${EPREFIX}/usr/share/unicode-data")
+		$(use_enable vala)
+		$(use_enable wayland)
+		"${python_conf[@]}"
+	)
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	if tc-is-cross-compiler && { use emoji || use unicode; }; then
+		emake -C "${S}-build/src" \
+			$(usex emoji emoji-parser '') \
+			$(usex unicode unicode-parser '')
+		emake -C src \
+			$(usex emoji emoji-parser '') \
+			$(usex unicode unicode-parser '')
+		cp \
+			$(usex emoji "${S}-build/src/emoji-parser" '') \
+			$(usex unicode "${S}-build/src/unicode-parser" '') \
+			src || die
+	fi
+	emake
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	virtx dbus-run-session emake check
+}
+
+src_install() {
+	default
+	# Remove la files
+	find "${ED}" -name '*.la' -delete || die
+
+	# Remove stray python files generated by the build system
+	find "${ED}" -name '*.pyc' -exec rm -f {} \; || die
+	find "${ED}" -name '*.pyo' -exec rm -f {} \; || die
+
+	if use python; then
+		python_install() {
+			emake -C bindings/pygobject \
+				pyoverridesdir="$(${EPYTHON} -c 'import gi; print(gi._overridesdir)')" \
+				DESTDIR="${D}" \
+				install
+
+			python_optimize
+		}
+		python_foreach_impl python_install
+	fi
+
+	keepdir /usr/share/ibus/engine
+
+	newbashcomp tools/${PN}.bash ${PN}
+
+	insinto /etc/X11/xinit/xinput.d
+	newins xinput-${PN} ${PN}.conf
+}
+
+pkg_postinst() {
+	use gtk2 && gnome2_query_immodules_gtk2
+	use gtk3 && gnome2_query_immodules_gtk3
+	xdg_icon_cache_update
+	gnome2_schemas_update
+	dconf update
+}
+
+pkg_postrm() {
+	use gtk2 && gnome2_query_immodules_gtk2
+	use gtk3 && gnome2_query_immodules_gtk3
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}