gentoo resync : 20.10.2021

1 files changed, 51 insertions, 0 deletions

diff --git a/app-i18n/libskk/libskk-1.0.5_p20210830.ebuild b/app-i18n/libskk/libskk-1.0.5_p20210830.ebuild
new file mode 100644
index 000000000000..b0caa5c5a713
--- /dev/null
+++ b/app-i18n/libskk/libskk-1.0.5_p20210830.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit autotools vala vcs-snapshot virtualx
+
+EGIT_COMMIT="5f5e5c2d3facfec9f577fb66032e6f1994ed5d44"
+
+DESCRIPTION="GObject-based library to deal with Japanese kana-to-kanji conversion method"
+HOMEPAGE="https://github.com/ueno/libskk"
+SRC_URI="https://github.com/ueno/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection nls static-libs"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libgee:0.8
+	x11-libs/libxkbcommon
+	introspection? ( dev-libs/gobject-introspection )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	vala_src_prepare
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable static-libs static)
+}
+
+src_test() {
+	export GSETTINGS_BACKEND="memory"
+	virtx emake check
+}
+
+src_install() {
+	default
+	use static-libs || find "${ED}" -name '*.la' -delete || die
+}