gentoo resync : 16.09.2020

1 files changed, 49 insertions, 0 deletions

diff --git a/app-i18n/ibus-hangul/ibus-hangul-1.5.4.ebuild b/app-i18n/ibus-hangul/ibus-hangul-1.5.4.ebuild
new file mode 100644
index 000000000000..1c7692b697c0
--- /dev/null
+++ b/app-i18n/ibus-hangul/ibus-hangul-1.5.4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Korean Hangul engine for IBus"
+HOMEPAGE="https://github.com/libhangul/ibus-hangul/wiki"
+SRC_URI="https://github.com/libhangul/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+	')
+	>=app-i18n/libhangul-0.1
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--with-python=${EPYTHON}
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}