gentoo resync : 22.10.2018

1 files changed, 40 insertions, 0 deletions

diff --git a/app-eselect/eselect-repository/eselect-repository-6.ebuild b/app-eselect/eselect-repository/eselect-repository-6.ebuild
new file mode 100644
index 000000000000..06ccc47c631d
--- /dev/null
+++ b/app-eselect/eselect-repository/eselect-repository-6.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{3_4,3_5,3_6,3_7} )
+inherit python-single-r1
+
+DESCRIPTION="Manage repos.conf via eselect"
+HOMEPAGE="https://github.com/mgorny/eselect-repository"
+SRC_URI="https://github.com/mgorny/eselect-repository/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="${PYTHON_DEPS}
+	app-admin/eselect
+	dev-python/lxml[${PYTHON_USEDEP}]
+	net-misc/wget"
+
+src_compile() {
+	MAKEARGS=(
+		PREFIX="${EPREFIX}/usr"
+		SYSCONFDIR="${EPREFIX}/etc"
+		SHAREDSTATEDIR="${EPREFIX}/var"
+		ESELECTDIR="${EPREFIX}/usr/share/eselect/modules"
+	)
+
+	emake "${MAKEARGS[@]}"
+	python_fix_shebang eselect-repo-helper
+}
+
+src_install() {
+	emake "${MAKEARGS[@]}" DESTDIR="${D}" install
+	keepdir /var/db/repos
+	einstalldocs
+}