gentoo auto-resync : 24:09:2022 - 11:31:39

1 files changed, 53 insertions, 0 deletions

diff --git a/app-emulation/q4wine/q4wine-1.3.13.ebuild b/app-emulation/q4wine/q4wine-1.3.13.ebuild
new file mode 100644
index 000000000000..eef0589c6f36
--- /dev/null
+++ b/app-emulation/q4wine/q4wine-1.3.13.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Upstream names the package PV-rX. We change that to
+# PV_pX so we can use portage revisions.
+MY_P=${PN}-${PV/_p/-r}
+inherit cmake xdg
+
+DESCRIPTION="Qt GUI configuration tool for Wine"
+HOMEPAGE="https://q4wine.brezblock.org.ua/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dbus debug +ico +iso +wineappdb"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsingleapplication[qt5(+),X]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dbus? ( dev-qt/qtdbus:5 )
+	ico? ( >=media-gfx/icoutils-0.26.0 )
+"
+RDEPEND="${DEPEND}
+	app-admin/sudo
+	>=sys-apps/which-2.19
+	iso? ( sys-fs/fuseiso )
+"
+BDEPEND="dev-qt/linguist-tools:5"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug ON OFF)
+		-DWITH_ICOUTILS=$(usex ico ON OFF)
+		-DWITH_SYSTEM_SINGLEAPP=ON
+		-DWITH_WINEAPPDB=$(usex wineappdb ON OFF)
+		-DUSE_BZIP2=OFF
+		-DUSE_GZIP=OFF
+		-DWITH_DBUS=$(usex dbus ON OFF)
+	)
+	cmake_src_configure
+}