gentoo resync : 30.06.2019

2 files changed, 105 insertions, 0 deletions

diff --git a/app-emacs/emacs-common-gentoo/Manifest b/app-emacs/emacs-common-gentoo/Manifest
index f20001a8088c..56ad65f48e0f 100644
--- a/app-emacs/emacs-common-gentoo/Manifest
+++ b/app-emacs/emacs-common-gentoo/Manifest
@@ -1,3 +1,4 @@
 DIST emacs-common-gentoo-1.6.tar.xz 61224 BLAKE2B 70e4f30c26c9098fdb02a53cab5d60cb611143d8bac6947707f3c7596b5a81ceb513b5a0809ee90f351472824f1d4216720c02cadb51d25b3dfce5e436e02bdf SHA512 a7daed2241d778ab283482ecc016801e25084eed10fcbbc50e187d5f842df5a0d278a77f94ae950b086c8651e8ca1a18f89c11dffdde9cf9168755288aae926a
 EBUILD emacs-common-gentoo-1.6-r1.ebuild 2882 BLAKE2B ab454de8e5f8b8c555b60a2129865214337279c9082c3927c455c1bfbac8f4a1de3e2f56a9be3fd7f9a181cd7c9295ebe90a00a64d158991f3f6808a0e14c17c SHA512 f7e4f173fa3c84a7c91e38b6d94b8555483a5c91875a2d87277e4e11423fc162590d45376643ddea08806b4c76a849c09404da421fb693c72e0b6ffa13ee2d9d
+EBUILD emacs-common-gentoo-1.6-r2.ebuild 2891 BLAKE2B 82a73eebc027e56c308aa2532dd9e09072252635659c7d401dc937548db759cbac8e0c98b9eb69d5155aef4ad185328214723eda1100f316b6531a72a0a579db SHA512 bfe17dc4f7699d3032bcf3e34c309964ebefffc06eecd07d8cac111181a27396c49e7944d05468fc1a89c18ebc70002d03fa0cc6ffb292469329aada8af15ad4
 MISC metadata.xml 360 BLAKE2B e7e420afb7a8377bffcf2a23f3954bbf4cc80fcd19a8514733e2e0164f4235271e21dc860bf77cb9cfcd1a4026ef3dafe97a10dc397e2d8e6f001f02bf6e9bc7 SHA512 d57f8f097617229f774b06437aaa83595aab2a6d9321d51b97dac8bd56fa94db396c7bdca538570f0912390e25ae8643c5adc374908757f67f1422fa1f872605
diff --git a/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r2.ebuild b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r2.ebuild
new file mode 100644
index 000000000000..e7d0b6437284
--- /dev/null
+++ b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r2.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp-common desktop xdg-utils gnome2-utils readme.gentoo-r1
+
+DESCRIPTION="Common files needed by all GNU Emacs versions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="games X"
+
+RDEPEND="games? ( acct-group/gamestat )"
+DEPEND="${RDEPEND}"
+PDEPEND="virtual/emacs"
+
+src_install() {
+	insinto "${SITELISP}"
+	doins subdirs.el
+	newins site-gentoo.el{,.orig}
+
+	keepdir /etc/emacs
+	insinto /etc/emacs
+	doins site-start.el
+
+	if use games; then
+		keepdir /var/games/emacs
+		fowners 0:gamestat /var/games/emacs
+		fperms g+w /var/games/emacs
+	fi
+
+	if use X; then
+		local i
+		domenu emacs.desktop emacsclient.desktop || die
+
+		pushd icons || die
+		newicon sink.png emacs-sink.png
+		newicon emacs25_48.png emacs.png
+		for i in 16 24 32 48 128; do
+			[[ ${i} -le 48 ]] && newicon -s ${i} emacs22_${i}.png emacs22.png
+			newicon -s ${i} emacs23_${i}.png emacs23.png
+			newicon -s ${i} emacs25_${i}.png emacs.png
+		done
+		doicon -s scalable emacs23.svg
+		newicon -s scalable emacs25.svg emacs.svg
+		popd
+
+		gnome2_icon_savelist
+	fi
+
+	DOC_CONTENTS="All site initialisation for Gentoo-installed packages is
+		added to ${SITELISP}/site-gentoo.el. In order for this site
+		initialisation to be loaded for all users automatically, a default
+		site startup file /etc/emacs/site-start.el is installed. You are
+		responsible for maintenance of this file.
+		\n\nAlternatively, individual users can add the following command:
+		\n\n(require 'site-gentoo)
+		\n\nto their ~/.emacs initialisation files, or, for greater
+		flexibility, users may load single package-specific initialisation
+		files from the ${SITELISP}/site-gentoo.d/ directory."
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	# make sure that site-gentoo.el exists since site-start.el requires it
+	if [[ ! -f ${ED}${SITELISP}/site-gentoo.el ]]; then		#554518
+		mv "${ED}${SITELISP}"/site-gentoo.el{.orig,} || die
+	fi
+	if [[ -d ${EROOT}${SITELISP} ]]; then
+		elisp-site-regen
+		cp "${EROOT}${SITELISP}/site-gentoo.el" "${ED}${SITELISP}/" || die
+	fi
+
+	if use games; then
+		local f
+		for f in /var/games/emacs/{snake,tetris}-scores; do
+			if [[ -e ${EROOT}${f} ]]; then
+				cp "${EROOT}${f}" "${ED}${f}" || die
+			fi
+			touch "${ED}${f}" || die
+			chgrp gamestat "${ED}${f}" || die
+			chmod g+w "${ED}${f}" || die
+		done
+	fi
+}
+
+pkg_postinst() {
+	if use X; then
+		xdg_desktop_database_update
+		gnome2_icon_cache_update
+	fi
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	if use X; then
+		xdg_desktop_database_update
+		gnome2_icon_cache_update
+	fi
+}