gentoo auto-resync : 14:07:2022 - 13:40:00

6 files changed, 475 insertions, 5 deletions

diff --git a/app-editors/Manifest.gz b/app-editors/Manifest.gz
index 6fbe11fb0dc5..ef8ed2186ccb 100644
--- a/app-editors/Manifest.gz
+++ b/app-editors/Manifest.gz
diff --git a/app-editors/emacs/Manifest b/app-editors/emacs/Manifest
index 7ab413503cb1..19fbb2ee08df 100644
--- a/app-editors/emacs/Manifest
+++ b/app-editors/emacs/Manifest
@@ -18,8 +18,9 @@ EBUILD emacs-24.5-r11.ebuild 10781 BLAKE2B 436f02959a1aa71165682f8e133dc0d7964cf
 EBUILD emacs-25.3-r11.ebuild 11091 BLAKE2B 02e66e0142e1fe4a5bd262548ee01bc399328d3b3cfeaf81bf67ad76dd10405bac1013de66d648f0e3cf5aa09b46ec69989130b514ad9989c5962a06d465bc68 SHA512 1ec9fdc1c130274277da7dd689640c48b9f3e439bf948dada9d4b79d6f2dee74e22d53e2854c1a2bd223da4b81916f2217efb9dd788e344004d50a28ba9f2b7d
 EBUILD emacs-26.3-r7.ebuild 11779 BLAKE2B 69ef04e1707478913d6d574cc9569e1b7eece4152f68c70112e9caf1e192b6b2d5f74fff7e0e89f4d730429861c1b4e1d70a0c1e6b9cb42565fefe740085f8d3 SHA512 6757269a4fdd86292b107d138d8ac39f44f055858d017e988ce005dcb4985ed3b49ce58b61335aa61fb031865f8a15bd1cbb46c402ae5466529adcee6280b552
 EBUILD emacs-27.2-r5.ebuild 14310 BLAKE2B 8875ffdd3002c88240d58891d67c840ea67bba108009e7fbf5963050a36b9e4f1cc4903e38c37a7456c3becf9a5c42c29bb910e8797940b9389b3fad8747948d SHA512 e47f5035c3d687b7a58ef3a05952ec301a00d17ae7633a9d5055c15f8fe9631d7d60927966eaf0b3e9fb1a3f0d892e3830269dc995efc2ff3400aad23815df1c
-EBUILD emacs-28.1.90.ebuild 14797 BLAKE2B 1e781ab85ddfd1ac3e699c89ebf5ca08f127437a0a1fdb254ce85fa0a550abc2e650d2e81829b61d96dcc2567228e5bc0a083651af4a5a0dda8e4454da77a458 SHA512 d286a760d36d98ea0b445384e28049d519959b716fc85a5bbf6ff2b1d07fbf793b7238cc7fbed58463992ad0cd47dc89d47f5d750a58d71cf0a621eb2a40a210
-EBUILD emacs-28.1.9999.ebuild 14795 BLAKE2B 9c3e4056feb08a72443cae30db1a1bbe555b7b454964bd5e6ba7663e0b92a4276641c19018f117f7fdf6548d18872a32956aeb727bf25e9530aa7179b1d91581 SHA512 447012b92de8f4ae909e2a8233e8ff02353095960300a9a31d2edc6ccb536f1a2b69f65d09b30f6d26ca19bf990081181f68ea82b785da754d4565f54cb6c049
+EBUILD emacs-28.1-r2.ebuild 15037 BLAKE2B 985440b0c7b7f30e52127e8938da63af03d69a172a32490ba87f15e0d4b3baeeb9086a0d2121c1d61efd423f6b8935657c820e3790fdbd4964894aa3140bee54 SHA512 a43637d2d466a5a687874646b6b897e0fb00c24e5ea09e6d051cdc9029df0aa810d2b9e8a17699b93dae32f5402e5980dde23cdd486341df0e61cd38e71437c6
+EBUILD emacs-28.1.90-r2.ebuild 15037 BLAKE2B 61cbff92ed83808be6868a4451f6e7f4064474da368f7e93295a3b23ff8a9f3a6ceb6c78ebc3955a3aa506ccf01e096b6a906b0ae4225c532b649b7492c865dd SHA512 37e7756db860b4564557b7f93c6a46e3b390dd899568802296ea2416cf9b23c408843192e5f9793a2968eff9bf622138c09858210efb85f16da0f006a912693d
+EBUILD emacs-28.1.9999.ebuild 15037 BLAKE2B 61cbff92ed83808be6868a4451f6e7f4064474da368f7e93295a3b23ff8a9f3a6ceb6c78ebc3955a3aa506ccf01e096b6a906b0ae4225c532b649b7492c865dd SHA512 37e7756db860b4564557b7f93c6a46e3b390dd899568802296ea2416cf9b23c408843192e5f9793a2968eff9bf622138c09858210efb85f16da0f006a912693d
 EBUILD emacs-28.1.ebuild 14790 BLAKE2B 9555b8b3d692fd33b9575e5666a63345369070187799e1a33556565c15a4f1c07b91197223e9db311911ca9ee4e797e9840b525fe8a2e8a9255f153c1bb541a5 SHA512 22757ca82108d2a47ee187119e82460a33c1df1d7b6cfd543a7bedd87e22aaff63083b2dffe47bcbb795430fa40e0a43477d0ef415a0de6e8b6bc5aaae425670
-EBUILD emacs-29.0.9999.ebuild 16277 BLAKE2B 1c2ac9eca96417bd14d115d060411fb3d0999f9b0c9cd77afaa65163b7eab525e4ff816d2c90253bbd9304955ddd600f965df97c4d6520c12dfae1ff46e12443 SHA512 e9794123c564caf3bec05ac041e5ebb73622c073fa1f2c8a04f9a900aa259d65a33d5f4260bc4004282e9477535c3b9b02eb171e163b02a40dd8f5bf18f02ff4
+EBUILD emacs-29.0.9999.ebuild 16519 BLAKE2B ad8023a343f5b3809ac1a1b361c6213921931c2afa9eeca1d57d77b925f56c319ca10880ab7d70a33488e44c35969475b14442989c50147b7722e3d9cf44ee03 SHA512 50c3e8308f7627dd0da511104fcf3dc93e6095ad8334fa425de17b597e44e6feba58e0851cf15a8e1deb280b4957fce2ae173688f519b5e27bd4be25c42ffcb7
 MISC metadata.xml 3130 BLAKE2B 162f49aa253a87b89e80dcbc961cacf659220c16c5b9d83e96b1eb90c40f828b87830173a80fb24cbfae50efb2ddfe51aed3e334c8c0f8e5cd30b63569e991cb SHA512 71a1b4b298ae915a33c7876a20892799c3c7b39f913b7b2606c18e6c14a4169b60f17c41742cdaab870cb60bceee14c0d10ea6f345739b1e9c3d07a14d9d60ee
diff --git a/app-editors/emacs/emacs-28.1-r2.ebuild b/app-editors/emacs/emacs-28.1-r2.ebuild
new file mode 100644
index 000000000000..29813e2a063f
--- /dev/null
+++ b/app-editors/emacs/emacs-28.1-r2.ebuild
@@ -0,0 +1,454 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools elisp-common readme.gentoo-r1 toolchain-funcs
+
+if [[ ${PV##*.} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs.git"
+	EGIT_BRANCH="emacs-28"
+	EGIT_CHECKOUT_DIR="${WORKDIR}/emacs"
+	S="${EGIT_CHECKOUT_DIR}"
+	SLOT="${PV%%.*}-vcs"
+else
+	# FULL_VERSION keeps the full version number, which is needed in
+	# order to determine some path information correctly for copy/move
+	# operations later on
+	FULL_VERSION="${PV%%_*}"
+	SRC_URI="mirror://gnu/emacs/${P}.tar.xz"
+	S="${WORKDIR}/emacs-${FULL_VERSION}"
+	# PV can be in any of the following formats:
+	# 27.1                 released version (slot 27)
+	# 27.1_rc1             upstream release candidate (27)
+	# 27.0.9999            live ebuild (slot 27-vcs)
+	# 27.0.90              upstream prerelease snapshot (27-vcs)
+	# 27.0.50_pre20191223  snapshot by Gentoo developer (27-vcs)
+	if [[ ${PV} == *_pre* ]]; then
+		SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+		S="${WORKDIR}/emacs"
+	elif [[ ${PV//[0-9]} != "." ]]; then
+		SRC_URI="https://alpha.gnu.org/gnu/emacs/pretest/${PN}-${PV/_/-}.tar.xz"
+	fi
+	SLOT="${PV%%.*}"
+	[[ ${PV} == *.*.* ]] && SLOT+="-vcs"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+fi
+
+DESCRIPTION="The extensible, customizable, self-documenting real-time display editor"
+HOMEPAGE="https://www.gnu.org/software/emacs/"
+
+LICENSE="GPL-3+ FDL-1.3+ BSD HPND MIT W3C unicode PSF-2"
+IUSE="acl alsa aqua athena cairo dbus dynamic-loading games gfile gif +gmp gpm gsettings gtk gui gzip-el harfbuzz imagemagick +inotify jit jpeg json kerberos lcms libxml2 livecd m17n-lib mailutils motif png selinux sound source ssl svg systemd +threads tiff toolkit-scroll-bars wide-int Xaw3d xft +xpm xwidgets zlib"
+RESTRICT="test"
+
+RDEPEND="app-emacs/emacs-common[games?,gui(-)?]
+	sys-libs/ncurses:0=
+	acl? ( virtual/acl )
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( sys-apps/dbus )
+	games? ( acct-group/gamestat )
+	gmp? ( dev-libs/gmp:0= )
+	gpm? ( sys-libs/gpm )
+	!inotify? ( gfile? ( >=dev-libs/glib-2.28.6 ) )
+	jit? ( sys-devel/gcc:=[jit(-)] )
+	json? ( dev-libs/jansson:= )
+	kerberos? ( virtual/krb5 )
+	lcms? ( media-libs/lcms:2 )
+	libxml2? ( >=dev-libs/libxml2-2.2.0 )
+	mailutils? ( net-mail/mailutils[clients] )
+	!mailutils? ( acct-group/mail net-libs/liblockfile )
+	selinux? ( sys-libs/libselinux )
+	ssl? ( net-libs/gnutls:0= )
+	systemd? ( sys-apps/systemd )
+	zlib? ( sys-libs/zlib )
+	gui? ( !aqua? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXfixes
+		x11-libs/libXinerama
+		x11-libs/libXrandr
+		x11-libs/libxcb
+		x11-misc/xbitmaps
+		gsettings? ( >=dev-libs/glib-2.28.6 )
+		gif? ( media-libs/giflib:0= )
+		jpeg? ( media-libs/libjpeg-turbo:0= )
+		png? ( >=media-libs/libpng-1.4:0= )
+		svg? ( >=gnome-base/librsvg-2.0 )
+		tiff? ( media-libs/tiff:0 )
+		xpm? ( x11-libs/libXpm )
+		imagemagick? ( >=media-gfx/imagemagick-6.6.2:0= )
+		xft? (
+			media-libs/fontconfig
+			media-libs/freetype
+			x11-libs/libXft
+			x11-libs/libXrender
+			cairo? ( >=x11-libs/cairo-1.12.18 )
+			harfbuzz? ( media-libs/harfbuzz:0= )
+			m17n-lib? (
+				>=dev-libs/libotf-0.9.4
+				>=dev-libs/m17n-lib-1.5.1
+			)
+		)
+		gtk? (
+			x11-libs/gtk+:3
+			xwidgets? (
+				net-libs/webkit-gtk:4=
+				x11-libs/libXcomposite
+			)
+		)
+		!gtk? (
+			motif? (
+				>=x11-libs/motif-2.3:0
+				x11-libs/libXpm
+				x11-libs/libXmu
+				x11-libs/libXt
+			)
+			!motif? (
+				Xaw3d? (
+					x11-libs/libXaw3d
+					x11-libs/libXmu
+					x11-libs/libXt
+				)
+				!Xaw3d? ( athena? (
+					x11-libs/libXaw
+					x11-libs/libXmu
+					x11-libs/libXt
+				) )
+			)
+		)
+	) )"
+
+DEPEND="${RDEPEND}
+	gui? ( !aqua? ( x11-base/xorg-proto ) )"
+
+BDEPEND="sys-apps/texinfo
+	virtual/pkgconfig
+	gzip-el? ( app-arch/gzip )"
+
+IDEPEND="app-eselect/eselect-emacs"
+
+RDEPEND+=" ${IDEPEND}"
+
+EMACS_SUFFIX="emacs-${SLOT}"
+SITEFILE="20${EMACS_SUFFIX}-gentoo.el"
+
+src_prepare() {
+	if [[ ${PV##*.} = 9999 ]]; then
+		FULL_VERSION=$(sed -n 's/^AC_INIT([^,]*,[ \t]*\([^ \t,)]*\).*/\1/p' \
+			configure.ac)
+		[[ ${FULL_VERSION} ]] || die "Cannot determine current Emacs version"
+		einfo "Emacs branch: ${EGIT_BRANCH}"
+		einfo "Commit: ${EGIT_VERSION}"
+		einfo "Emacs version number: ${FULL_VERSION}"
+		[[ ${FULL_VERSION} =~ ^${PV%.*}(\..*)?$ ]] \
+			|| die "Upstream version number changed to ${FULL_VERSION}"
+	fi
+
+	if use jit; then
+		# These files ignore LDFLAGS. We assign the variable here, because
+		# for live ebuilds FULL_VERSION doesn't exist in global scope
+		QA_FLAGS_IGNORED="usr/$(get_libdir)/emacs/${FULL_VERSION}/native-lisp/.*"
+
+		# gccjit doesn't play well with ccache or distcc #801580
+		# For now, work around the problem with an explicit LIBRARY_PATH
+		has ccache ${FEATURES} || has distcc ${FEATURES} && tc-is-gcc \
+			&& export LIBRARY_PATH=$("$(tc-getCC)" -print-search-dirs \
+				| sed -n '/^libraries:/{s:^[^/]*::;p}')
+	fi
+
+	default
+
+	# Fix filename reference in redirected man page
+	sed -i -e "/^\\.so/s/etags/&-${EMACS_SUFFIX}/" doc/man/ctags.1 || die
+
+	# libseccomp is detected by configure but doesn't appear to have any
+	# effect on the installed image. Suppress it by supplying pkg-config
+	# with a wrong library name.
+	sed -i -e "/CHECK_MODULES/s/libseccomp/DiSaBlE&/" configure.ac || die
+
+	AT_M4DIR=m4 eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if use alsa; then
+		use sound || ewarn \
+			"USE flag \"alsa\" overrides \"-sound\"; enabling sound support."
+		myconf+=" --with-sound=alsa"
+	else
+		myconf+=" --with-sound=$(usex sound oss)"
+	fi
+
+	if ! use gui; then
+		einfo "Configuring to build without window system support"
+		myconf+=" --without-x --without-ns"
+	elif use aqua; then
+		einfo "Configuring to build with Nextstep (Macintosh Cocoa) support"
+		myconf+=" --with-ns --disable-ns-self-contained"
+		myconf+=" --without-x"
+	else
+		myconf+=" --with-x --without-ns"
+		myconf+=" --without-gconf"
+		myconf+=" $(use_with gsettings)"
+		myconf+=" $(use_with toolkit-scroll-bars)"
+		myconf+=" $(use_with gif)"
+		myconf+=" $(use_with jpeg)"
+		myconf+=" $(use_with png)"
+		myconf+=" $(use_with svg rsvg)"
+		myconf+=" $(use_with tiff)"
+		myconf+=" $(use_with xpm)"
+		myconf+=" $(use_with imagemagick)"
+
+		if use xft; then
+			myconf+=" --with-xft"
+			myconf+=" $(use_with cairo)"
+			myconf+=" $(use_with harfbuzz)"
+			myconf+=" $(use_with m17n-lib libotf)"
+			myconf+=" $(use_with m17n-lib m17n-flt)"
+		else
+			myconf+=" --without-xft"
+			myconf+=" --without-cairo"
+			myconf+=" --without-libotf --without-m17n-flt"
+			use cairo && ewarn \
+				"USE flag \"cairo\" has no effect if \"xft\" is not set."
+			use m17n-lib && ewarn \
+				"USE flag \"m17n-lib\" has no effect if \"xft\" is not set."
+		fi
+
+		local f line
+		if use gtk; then
+			einfo "Configuring to build with GIMP Toolkit (GTK+)"
+			while read line; do ewarn "${line}"; done <<-EOF
+				Your version of GTK+ will have problems with closing open
+				displays. This is no problem if you just use one display, but
+				if you use more than one and close one of them Emacs may crash.
+				See <https://gitlab.gnome.org/GNOME/gtk/-/issues/221> and
+				<https://gitlab.gnome.org/GNOME/gtk/-/issues/2315>.
+				If you intend to use more than one display, then it is strongly
+				recommended that you compile Emacs with the Athena/Lucid or the
+				Motif toolkit instead.
+			EOF
+			myconf+=" --with-x-toolkit=gtk3 $(use_with xwidgets)"
+			for f in motif Xaw3d athena; do
+				use ${f} && ewarn \
+					"USE flag \"${f}\" has no effect if \"gtk\" is set."
+			done
+		elif use motif; then
+			einfo "Configuring to build with Motif toolkit"
+			myconf+=" --with-x-toolkit=motif"
+			for f in Xaw3d athena; do
+				use ${f} && ewarn \
+					"USE flag \"${f}\" has no effect if \"motif\" is set."
+			done
+		elif use athena || use Xaw3d; then
+			einfo "Configuring to build with Athena/Lucid toolkit"
+			myconf+=" --with-x-toolkit=lucid $(use_with Xaw3d xaw3d)"
+		else
+			einfo "Configuring to build with no toolkit"
+			myconf+=" --with-x-toolkit=no"
+		fi
+		! use gtk && use xwidgets && ewarn \
+			"USE flag \"xwidgets\" has no effect if \"gtk\" is not set."
+	fi
+
+	if tc-is-cross-compiler; then
+		# Configure a CBUILD directory when cross-compiling to make tools
+		mkdir "${S}-build" && pushd "${S}-build" >/dev/null || die
+		ECONF_SOURCE="${S}" econf_build --without-all --without-x-toolkit
+		popd >/dev/null || die
+		# Don't try to execute the binary for dumping during the build
+		myconf+=" --with-dumping=none"
+	elif use m68k; then
+		# Workaround for https://debbugs.gnu.org/44531
+		myconf+=" --with-dumping=unexec"
+	else
+		myconf+=" --with-dumping=pdumper"
+	fi
+
+	econf \
+		--program-suffix="-${EMACS_SUFFIX}" \
+		--includedir="${EPREFIX}"/usr/include/${EMACS_SUFFIX} \
+		--infodir="${EPREFIX}"/usr/share/info/${EMACS_SUFFIX} \
+		--localstatedir="${EPREFIX}"/var \
+		--enable-locallisppath="${EPREFIX}/etc/emacs:${EPREFIX}${SITELISP}" \
+		--without-compress-install \
+		--without-hesiod \
+		--without-pop \
+		--with-file-notification=$(usev inotify || usev gfile || echo no) \
+		--with-pdumper \
+		$(use_enable acl) \
+		$(use_with dbus) \
+		$(use_with dynamic-loading modules) \
+		$(use_with games gameuser ":gamestat") \
+		$(use_with gmp libgmp) \
+		$(use_with gpm) \
+		$(use_with jit native-compilation) \
+		$(use_with json) \
+		$(use_with kerberos) $(use_with kerberos kerberos5) \
+		$(use_with lcms lcms2) \
+		$(use_with libxml2 xml2) \
+		$(use_with mailutils) \
+		$(use_with selinux) \
+		$(use_with ssl gnutls) \
+		$(use_with systemd libsystemd) \
+		$(use_with threads) \
+		$(use_with wide-int) \
+		$(use_with zlib) \
+		${myconf}
+}
+
+src_compile() {
+	if tc-is-cross-compiler; then
+		# Build native tools for compiling lisp etc.
+		emake -C "${S}-build" src
+		emake lib	   # Cross-compile dependencies first for timestamps
+		# Save native build tools in the cross-directory
+		cp "${S}-build"/lib-src/make-{docfile,fingerprint} lib-src || die
+		# Specify the native Emacs to compile lisp
+		emake -C lisp all EMACS="${S}-build/src/emacs"
+	fi
+
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" NO_BIN_LINK=t BLESSMAIL_TARGET= install
+
+	mv "${ED}"/usr/bin/{emacs-${FULL_VERSION}-,}${EMACS_SUFFIX} || die
+	mv "${ED}"/usr/share/man/man1/{emacs-,}${EMACS_SUFFIX}.1 || die
+	mv "${ED}"/usr/share/metainfo/{emacs-,}${EMACS_SUFFIX}.metainfo.xml || die
+
+	# move info dir to avoid collisions with the dir file generated by portage
+	mv "${ED}"/usr/share/info/${EMACS_SUFFIX}/dir{,.orig} || die
+	touch "${ED}"/usr/share/info/${EMACS_SUFFIX}/.keepinfodir
+	docompress -x /usr/share/info/${EMACS_SUFFIX}/dir.orig
+
+	# movemail must be setgid mail
+	if ! use mailutils; then
+		fowners root:mail /usr/libexec/emacs/${FULL_VERSION}/${CHOST}/movemail
+		fperms 2751 /usr/libexec/emacs/${FULL_VERSION}/${CHOST}/movemail
+	fi
+
+	# avoid collision between slots, see bug #169033 e.g.
+	rm "${ED}"/usr/share/emacs/site-lisp/subdirs.el || die
+	rm -rf "${ED}"/usr/share/{applications,icons} || die
+	rm -rf "${ED}/usr/$(get_libdir)/systemd" || die
+	rm -rf "${ED}"/var || die
+
+	# remove unused <version>/site-lisp dir
+	rm -rf "${ED}"/usr/share/emacs/${FULL_VERSION}/site-lisp || die
+
+	# remove COPYING file (except for etc/COPYING used by describe-copying)
+	rm "${ED}"/usr/share/emacs/${FULL_VERSION}/lisp/COPYING || die
+
+	if use systemd; then
+		insinto /usr/lib/systemd/user
+		sed -e "/^##/d" \
+			-e "/^ExecStart/s,emacs,${EPREFIX}/usr/bin/${EMACS_SUFFIX}," \
+			-e "/^ExecStop/s,emacsclient,${EPREFIX}/usr/bin/&-${EMACS_SUFFIX}," \
+			etc/emacs.service | newins - ${EMACS_SUFFIX}.service
+		assert
+	fi
+
+	if use gzip-el; then
+		# compress .el files when a corresponding .elc exists
+		find "${ED}"/usr/share/emacs/${FULL_VERSION}/lisp -type f \
+			-name "*.elc" -print | sed 's/\.elc$/.el/' | xargs gzip -9n
+		assert "gzip .el failed"
+	fi
+
+	local cdir
+	if use source; then
+		cdir="/usr/share/emacs/${FULL_VERSION}/src"
+		insinto "${cdir}"
+		# This is not meant to install all the source -- just the
+		# C source you might find via find-function
+		doins src/*.{c,h,m}
+	elif has installsources ${FEATURES}; then
+		cdir="/usr/src/debug/${CATEGORY}/${PF}/${S#"${WORKDIR}/"}/src"
+	fi
+
+	sed -e "${cdir:+#}/^Y/d" -e "s/^[XY]//" >"${T}/${SITEFILE}" <<-EOF || die
+	X
+	;;; ${EMACS_SUFFIX} site-lisp configuration
+	X
+	(when (string-match "\\\\\`${FULL_VERSION//./\\\\.}\\\\>" emacs-version)
+	Y  (setq find-function-C-source-directory
+	Y	"${EPREFIX}${cdir}")
+	X  (let ((path (getenv "INFOPATH"))
+	X	(dir "${EPREFIX}/usr/share/info/${EMACS_SUFFIX}")
+	X	(re "\\\\\`${EPREFIX}/usr/share\\\\>"))
+	X    (and path
+	X	 ;; move Emacs Info dir before anything else in /usr/share
+	X	 (let* ((p (cons nil (split-string path ":" t))) (q p))
+	X	   (while (and (cdr q) (not (string-match re (cadr q))))
+	X	     (setq q (cdr q)))
+	X	   (setcdr q (cons dir (delete dir (cdr q))))
+	X	   (setq Info-directory-list (prune-directory-list (cdr p)))))))
+	EOF
+	elisp-site-file-install "${T}/${SITEFILE}" || die
+
+	dodoc README BUGS CONTRIBUTE
+
+	if use gui && use aqua; then
+		dodir /Applications/Gentoo
+		rm -rf "${ED}"/Applications/Gentoo/${EMACS_SUFFIX^}.app || die
+		mv nextstep/Emacs.app \
+			"${ED}"/Applications/Gentoo/${EMACS_SUFFIX^}.app || die
+	fi
+
+	local DOC_CONTENTS="You can set the version to be started by
+		/usr/bin/emacs through the Emacs eselect module, which also
+		redirects man and info pages. Therefore, several Emacs versions can
+		be installed at the same time. \"man emacs.eselect\" for details.
+		\\n\\nIf you upgrade from a previous major version of Emacs, then
+		it is strongly recommended that you use app-admin/emacs-updater
+		to rebuild all byte-compiled elisp files of the installed Emacs
+		packages."
+	if use gui; then
+		DOC_CONTENTS+="\\n\\nYou need to install some fonts for Emacs.
+			Installing media-fonts/font-adobe-{75,100}dpi on the X server's
+			machine would satisfy basic Emacs requirements under X11.
+			See also https://wiki.gentoo.org/wiki/Xft_support_for_GNU_Emacs
+			for how to enable anti-aliased fonts."
+		use aqua && DOC_CONTENTS+="\\n\\n${EMACS_SUFFIX^}.app is in
+			\"${EPREFIX}/Applications/Gentoo\". You may want to copy or
+			symlink it into /Applications by yourself."
+	fi
+	tc-is-cross-compiler && DOC_CONTENTS+="\\n\\nEmacs did not write
+		a portable dump file due to being cross-compiled.
+		To create this file at run time, execute the following command:
+		\\n${EMACS_SUFFIX} --batch -Q --eval='(dump-emacs-portable
+		\"/usr/libexec/emacs/${FULL_VERSION}/${CHOST}/emacs.pdmp\")'"
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	# move Info dir file to correct name
+	if [[ -d ${ED}/usr/share/info ]]; then
+		mv "${ED}"/usr/share/info/${EMACS_SUFFIX}/dir{.orig,} || die
+	fi
+}
+
+pkg_postinst() {
+	elisp-site-regen
+	readme.gentoo_print_elog
+
+	if use livecd; then
+		# force an update of the emacs symlink for the livecd/dvd,
+		# because some microemacs packages set it with USE=livecd
+		eselect emacs update
+	else
+		eselect emacs update ifunset
+	fi
+}
+
+pkg_postrm() {
+	elisp-site-regen
+	eselect emacs update ifunset
+}
diff --git a/app-editors/emacs/emacs-28.1.90.ebuild b/app-editors/emacs/emacs-28.1.90-r2.ebuild
index 7875c15c2dcd..ce9357f531fc 100644
--- a/app-editors/emacs/emacs-28.1.90.ebuild
+++ b/app-editors/emacs/emacs-28.1.90-r2.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-inherit elisp-common readme.gentoo-r1 toolchain-funcs #autotools
+inherit autotools elisp-common readme.gentoo-r1 toolchain-funcs
 
 if [[ ${PV##*.} = 9999 ]]; then
 	inherit git-r3
@@ -165,7 +165,12 @@ src_prepare() {
 	# Fix filename reference in redirected man page
 	sed -i -e "/^\\.so/s/etags/&-${EMACS_SUFFIX}/" doc/man/ctags.1 || die
 
-	#AT_M4DIR=m4 eautoreconf
+	# libseccomp is detected by configure but doesn't appear to have any
+	# effect on the installed image. Suppress it by supplying pkg-config
+	# with a wrong library name.
+	sed -i -e "/CHECK_MODULES/s/libseccomp/DiSaBlE&/" configure.ac || die
+
+	AT_M4DIR=m4 eautoreconf
 }
 
 src_configure() {
diff --git a/app-editors/emacs/emacs-28.1.9999.ebuild b/app-editors/emacs/emacs-28.1.9999.ebuild
index a3ba699d12bc..ce9357f531fc 100644
--- a/app-editors/emacs/emacs-28.1.9999.ebuild
+++ b/app-editors/emacs/emacs-28.1.9999.ebuild
@@ -165,6 +165,11 @@ src_prepare() {
 	# Fix filename reference in redirected man page
 	sed -i -e "/^\\.so/s/etags/&-${EMACS_SUFFIX}/" doc/man/ctags.1 || die
 
+	# libseccomp is detected by configure but doesn't appear to have any
+	# effect on the installed image. Suppress it by supplying pkg-config
+	# with a wrong library name.
+	sed -i -e "/CHECK_MODULES/s/libseccomp/DiSaBlE&/" configure.ac || die
+
 	AT_M4DIR=m4 eautoreconf
 }
 
diff --git a/app-editors/emacs/emacs-29.0.9999.ebuild b/app-editors/emacs/emacs-29.0.9999.ebuild
index 571ff6e3636c..0fde98bc4137 100644
--- a/app-editors/emacs/emacs-29.0.9999.ebuild
+++ b/app-editors/emacs/emacs-29.0.9999.ebuild
@@ -187,6 +187,11 @@ src_prepare() {
 	# Fix filename reference in redirected man page
 	sed -i -e "/^\\.so/s/etags/&-${EMACS_SUFFIX}/" doc/man/ctags.1 || die
 
+	# libseccomp is detected by configure but doesn't appear to have any
+	# effect on the installed image. Suppress it by supplying pkg-config
+	# with a wrong library name.
+	sed -i -e "/CHECK_MODULES/s/libseccomp/DiSaBlE&/" configure.ac || die
+
 	AT_M4DIR=m4 eautoreconf
 }