gentoo resync : 23.03.2018

2 files changed, 94 insertions, 0 deletions

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
index 83670e69331e..1ad98e7fa14b 100644
--- a/app-crypt/qca/Manifest
+++ b/app-crypt/qca/Manifest
@@ -2,4 +2,5 @@ AUX qca-2.1.3-c++11.patch 3555 BLAKE2B 68b9e4a9e13543b2f98c564f19deef32090be25bb
 AUX qca-disable-pgp-test.patch 446 BLAKE2B a98d5951d7b89c65787d7d586a5504949c51271ebe09c5e19b90a2e24f24fb6d03d6c1f76d7ad4234354bc2507cf7031c716b3b2bf8243b8c1d85065079dded4 SHA512 30bb6d31b9392166d6bbae39da2eeb1788ac9cccffb801b074468a3606a6e1a56d6a41ee276d3b8b8d39112bf6aea7025f07f4810bb835102bd00521ee9eb104
 DIST qca-2.1.3.tar.xz 686340 BLAKE2B 60ebf9add907632ed17426ee53c6c35a9aed279a4492012f1c174608cbe9579d366feb7ff7bff551d2e9e4ef2f271e8f340fcb4c9e1f67f209657d388567d44f SHA512 0aec277e0695da2e45298f0a9006213829fe4c449a79969e472947db54f45000ba6e22361b782465bdc03f269b7301d318c843f5a83db459a118e58a03f3116a
 EBUILD qca-2.1.3-r1.ebuild 2719 BLAKE2B cc8c3ed0071caf9c474c2ecaab4cdca0d1db9a53f0324ff2bf2741e26363a90f685a088cc7159853347387928ca466d6723f74513b486a4c543d92a0a85a6bd0 SHA512 395f82a689752d6248e64c94e535e60fe0ed78c1e5592fa78ff9ee2e52c6410520a7f37fef61fe7bcdf3a3d50797ab3edbd797923278d9c7761541c972e03f07
+EBUILD qca-2.1.3-r2.ebuild 2150 BLAKE2B 7f12cb90bcf417ec0652f2f5fd203b196aa39f86c036ac2fcbd82e90c3bad197636acb83cba7eb7236b198dbe12576915582ae2ceb961e72969a1c2babb8a9c0 SHA512 34e2dd86037f684defe4896455f233edaebfff306a07a47d377c251b61b351c8358e23c8cd6f7ecf70d3ebc238332328d5c8023d029453203cfdc9d16417d3e5
 MISC metadata.xml 842 BLAKE2B 1732f7a0efeba7de6c54bfb817a69f9be88eab8bb37a75f5ee685ba7893ad9be13a10ea8b2a404954846e1ea73dc617d0a89ac3b1f69a83928275b9e8d5fc7ab SHA512 900de0e8b914d1970b3e4fcfbdbeea48c1e56ab596e6c959e4dce29a0fd0cb0b6969ab6899784a80b6c233a656f3a4501513d8af6b4acc8519a5ecf1c9a1a622
diff --git a/app-crypt/qca/qca-2.1.3-r2.ebuild b/app-crypt/qca/qca-2.1.3-r2.ebuild
new file mode 100644
index 000000000000..396b23660490
--- /dev/null
+++ b/app-crypt/qca/qca-2.1.3-r2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="https://userbase.kde.org/QCA"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+
+IUSE="botan debug doc examples gcrypt gpg libressl logger nss pkcs11 sasl softstore +ssl test"
+
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	botan? ( dev-libs/botan:0 )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	pkcs11? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+		dev-libs/pkcs11-helper
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtnetwork:5
+	doc? ( app-doc/doxygen )
+	test? ( dev-qt/qttest:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!app-crypt/qca-cyrus-sasl
+	!app-crypt/qca-gnupg
+	!app-crypt/qca-logger
+	!app-crypt/qca-ossl
+	!app-crypt/qca-pkcs11
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-disable-pgp-test.patch"
+	"${FILESDIR}/${P}-c++11.patch"
+)
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(qt5_get_mkspecsdir)/features"
+		-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(qt5_get_plugindir)"
+		$(qca_plugin_use botan)
+		$(qca_plugin_use gcrypt)
+		$(qca_plugin_use gpg gnupg)
+		$(qca_plugin_use logger)
+		$(qca_plugin_use nss)
+		$(qca_plugin_use pkcs11)
+		$(qca_plugin_use sasl cyrus-sasl)
+		$(qca_plugin_use softstore)
+		$(qca_plugin_use ssl ossl)
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null || die
+		doxygen Doxyfile.in || die
+		dodoc -r apidocs/html
+		popd >/dev/null || die
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}