gentoo Easter resync : 12.04.2020

1 files changed, 52 insertions, 0 deletions

diff --git a/app-arch/gcab/gcab-1.4.ebuild b/app-arch/gcab/gcab-1.4.ebuild
new file mode 100644
index 000000000000..fc5fcda22bdd
--- /dev/null
+++ b/app-arch/gcab/gcab-1.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="Library and tool for working with Microsoft Cabinet (CAB) files"
+HOMEPAGE="https://wiki.gnome.org/msitools"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.62.0:2
+	sys-libs/zlib
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-util/meson-0.50.0
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		$(meson_use introspection)
+		-Dnls=true
+		$(meson_use vala vapi)
+		$(meson_use test tests)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}