gentoo resync : 28.04.2019

1 files changed, 39 insertions, 0 deletions

diff --git a/app-admin/terraform/terraform-0.11.13.ebuild b/app-admin/terraform/terraform-0.11.13.ebuild
new file mode 100644
index 000000000000..ae68474b0f4d
--- /dev/null
+++ b/app-admin/terraform/terraform-0.11.13.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-vcs-snapshot
+
+DESCRIPTION="A tool for building, changing, and combining infrastructure safely"
+HOMEPAGE="https://www.terraform.io/"
+
+EGO_PN="github.com/hashicorp/${PN}"
+SRC_URI="https://github.com/hashicorp/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+DEPEND=">=dev-lang/go-1.11.0"
+
+DOCS=( README.md CHANGELOG.md )
+
+src_compile() {
+	cd "src/${EGO_PN}" || die
+	GOPATH="${S}" GOCACHE="${T}/go-cache" go build \
+		-v -work -o "${S}/${PN}" ./ || die
+}
+
+src_install() {
+	dobin terraform
+
+	pushd "src/${EGO_PN}" >/dev/null || die
+	einstalldocs
+	popd >/dev/null || die
+}
+
+pkg_postinst() {
+	elog "If you would like to install shell completions please run:"
+	elog "    terraform -install-autocomplete"
+}