gentoo auto-resync : 13:12:2023 - 23:41:49

2 files changed, 249 insertions, 0 deletions

diff --git a/app-admin/salt/Manifest b/app-admin/salt/Manifest
index 55c7034c54e8..0fe24c567066 100644
--- a/app-admin/salt/Manifest
+++ b/app-admin/salt/Manifest
@@ -29,10 +29,12 @@ DIST salt-3005.4.tar.gz 17936876 BLAKE2B e06ec0e357fac18fe0ad823cf80e6261d80dbf2
 DIST salt-3006.2.tar.gz 20411634 BLAKE2B dff474017918ef3ee0031856a2739282077205d8c2589809a91e5f1c3741cb26d2bd2458734ea4d3533118c881851dfd853f4ba4f1c631e7db28e95bc1b6f7f8 SHA512 2626cb5beb1b30fc63f554f5804f0d9b7e36b7c569c5f9049e5f5ac5a413e9d99a98b3d91089683338e3d3890ec973dff80782b4e41acb291872e45084fd2546
 DIST salt-3006.3.tar.gz 20461738 BLAKE2B dfa4698dbc611c9c4954b4631d11b685e1efc978915918ce6d8f1890bb4a230d234b6a191166ffff9243058d44530bfc14b43386c8bc295c035c6609d6bf3fa0 SHA512 9cced766db2144de445ed53b52c1551c986ba43774c40512fd07973862d6d3a361e25f55fcfeeb0e03ba44eec1051909834e5d0a352ead5ec6f418b15c909628
 DIST salt-3006.4.tar.gz 20465324 BLAKE2B 8cf9acf8850e9eefbff32f3e347d8773ed7e28f58a0a441af9ec0a4c87a0bba49ff2b82e6f5816511de7303e16d79246df8c0024464a5c267f3ef7e370c8be98 SHA512 c48c69730ba81d3e279cbb01cb26c743dd8b4945c2fc16a7c959472ab4050316fcdaee935e009b7f472bd3b08172ac69defe64774a2d93e143a050cd559997ef
+DIST salt-3006.5.tar.gz 20536455 BLAKE2B cf475dc5e919f6ab180578db2aae5f3655623b39b134d67609da4f607be909340c6e55c940cfb66f129cc75d40b5cdda094e866db116d8a45aa5eef26d8fa1eb SHA512 8aaf5c5d36d8aa17b3fe867cee470f7b3c5dd1f6abaf5bdb49a3df76d3498d0dc1fa305a069bc95ad057489db229454b38b0ea9c1ade1e46b5d9b57aeef10c23
 EBUILD salt-3005.1-r1.ebuild 7234 BLAKE2B af8c85ad4abcd00244b52a73cc67fc31505395dc11282841bec155a4ae5c24694214f9e3a173f8ae09c25de2ae06f5eefdc3fd0aa27608908a78f664e18cf408 SHA512 1d790f172358abbac38351e1b5be50fa1e646fc7cb51179af428249e8dccd6452f51f25710ab73c91e0942df8098a9b97d6f579b8934a1f0e4d194cd7ec6961d
 EBUILD salt-3005.3.ebuild 9382 BLAKE2B 068d7d5a8e15ebb387b9534616693c74dd89d2b8839c21a57c50bcbdf83427b44a49796805b84b45be823007c0c6ea3828a17ac47a20576286e340c4ccaf0775 SHA512 da78be3da31b32b079129bc05547890e17bb3c67d8e4ba33f84be796c83fbaf31aae838df0f8c51153bca51960dfdfa41ca6af92dc77ef32760b5dba3f901e81
 EBUILD salt-3005.4.ebuild 9382 BLAKE2B 068d7d5a8e15ebb387b9534616693c74dd89d2b8839c21a57c50bcbdf83427b44a49796805b84b45be823007c0c6ea3828a17ac47a20576286e340c4ccaf0775 SHA512 da78be3da31b32b079129bc05547890e17bb3c67d8e4ba33f84be796c83fbaf31aae838df0f8c51153bca51960dfdfa41ca6af92dc77ef32760b5dba3f901e81
 EBUILD salt-3006.2.ebuild 8539 BLAKE2B 335093f353da0d42abedf7b836c1516239390ec64fe4acf0f58d23f1d4b467446304aec086587fd9901b3007d50d86743aaf26157d7706b0b4b511f814d3e7ab SHA512 d8690757e65594d3bef93e852d61efb4c771fc3d2d441ef79dae0cd585cb93854a77ed641f9ba65bce13eaba7f46475c90dd03c591d2e0f580ef4a53bf7b1532
 EBUILD salt-3006.3.ebuild 8903 BLAKE2B cbf034e5dec44f2b46cecf74dbc4d7b8df9782905024ff86ed3e5320172a1693027859036e79609e23aae00c50994a62aee8806928c46dd907411efcaaa2a0c7 SHA512 867092ef5873126ceee767ebf12df66acaade553df2d7d351441a7aff19fc90346c6805882b77be602e79e407ddf9f90e0885a746336b64e4ce3bb6422426f57
 EBUILD salt-3006.4.ebuild 8825 BLAKE2B 6789758984b1d9bc4e1e6fd61b6516a8bec88df9a3de73a5570f0717e52ed2f5796e03d6a1b2eb31ca67635b51b72f963b406ebd03e97f8be6a0dab7ec29836e SHA512 999951e1a35552ffc86ecccda556274f108d082df37163a8570879aa6029751dedec3ea76ce42f39ce5b3ff46ebdaedca46a2ddc5b6639952aba257830c0e522
+EBUILD salt-3006.5.ebuild 9589 BLAKE2B c90270c444f99da82b8a85e813c652f7cf4f6f5767160183de5162434bc4be3feb0060a2579c7191b189d8401625fc3acf003adea24d0c0aad9e027c3ffa20ef SHA512 1c67d2cc61e8594ee335f5da8c7ba53ea629fe389cd30fdb3f93d5b14b04592bff759fbe7b2ac7ce03d5524d9e9fb935e572119adc2c00861cf45422897d39fc
 MISC metadata.xml 2304 BLAKE2B 8fac51fe1b0c0dae5fe71d88f1bf84df1de8cc8b3d836b59c3b2e82bfa085f57352e3aafd999766ae69104a8bd9798f2fffdb64e1df1e0a1ca8561dba1ef7d5e SHA512 7d3706c40c27dd67509bd638cd0550bb4822f0895fef929ecad21c218cdaa0512da443c901cc2b3a8d4afd9f5e9bc461622ac3bab2a332ccd9c64c4cbf99bf74
diff --git a/app-admin/salt/salt-3006.5.ebuild b/app-admin/salt/salt-3006.5.ebuild
new file mode 100644
index 000000000000..f6b28047c843
--- /dev/null
+++ b/app-admin/salt/salt-3006.5.ebuild
@@ -0,0 +1,247 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_10 )
+
+DISTUTILS_USE_PEP517=setuptools
+inherit systemd distutils-r1
+
+DESCRIPTION="Salt is a remote execution and configuration manager"
+HOMEPAGE="https://www.saltstack.com/resources/community/
+	https://github.com/saltstack"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}stack/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	inherit pypi
+	KEYWORDS="~amd64 ~riscv ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="
+	cheetah cherrypy ldap libcloud libvirt genshi gnupg keyring mako
+	mongodb neutron	nova openssl portage profile redis selinux test raet
+	+zeromq vim-syntax
+"
+
+RDEPEND="
+	sys-apps/pciutils
+	>=dev-python/cryptography-41.0.3[${PYTHON_USEDEP}]
+	>=dev-python/distro-1.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.1.2[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/libnacl[${PYTHON_USEDEP}]
+	dev-python/looseversion[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pycryptodome-3.9.8[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-2.1.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.31.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	dev-python/watchdog[${PYTHON_USEDEP}]
+	libcloud? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/aiosignal[${PYTHON_USEDEP}]
+		>=dev-python/apache-libcloud-2.5.0[${PYTHON_USEDEP}]
+		dev-python/async-timeout[${PYTHON_USEDEP}]
+	)
+	mako? ( dev-python/mako[${PYTHON_USEDEP}] )
+	ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
+	libvirt? (
+		dev-python/libvirt-python[${PYTHON_USEDEP}]
+	)
+	openssl? (
+		dev-libs/openssl:0=[-bindist(-)]
+		>=dev-python/pyopenssl-23.2.0[${PYTHON_USEDEP}]
+	)
+	raet? (
+		>=dev-python/libnacl-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/ioflo-1.1.7[${PYTHON_USEDEP}]
+		>=dev-python/raet-0.6.0[${PYTHON_USEDEP}]
+	)
+	cherrypy? ( >=dev-python/cherrypy-3.2.2[${PYTHON_USEDEP}] )
+	cheetah? ( >=dev-python/cheetah3-3.2.2[${PYTHON_USEDEP}] )
+	genshi? ( dev-python/genshi[${PYTHON_USEDEP}] )
+	mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
+	portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
+	redis? ( dev-python/redis[${PYTHON_USEDEP}] )
+	selinux? ( sec-policy/selinux-salt )
+	nova? (
+		>=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}]
+	)
+	neutron? (
+		>=dev-python/python-neutronclient-2.3.6[${PYTHON_USEDEP}]
+	)
+	gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	profile? ( dev-python/yappi[${PYTHON_USEDEP}] )
+	vim-syntax? ( app-vim/salt-vim )
+	zeromq? ( >=dev-python/pyzmq-19.0.0[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	dev-python/build[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/apache-libcloud[${PYTHON_USEDEP}]
+		>=dev-python/boto-2.32.1[${PYTHON_USEDEP}]
+		>=dev-python/certifi-2023.07.22[${PYTHON_USEDEP}]
+		dev-python/cherrypy[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+		dev-python/mako[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/moto-2.0.0[${PYTHON_USEDEP}]
+		dev-python/passlib[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-23.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-7.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-salt-factories-1.0.0_rc28[${PYTHON_USEDEP}]
+		dev-python/pytest-tempdir[${PYTHON_USEDEP}]
+		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+		dev-python/pytest-shell-utilities[${PYTHON_USEDEP}]
+		dev-python/pytest-skip-markers[${PYTHON_USEDEP}]
+		dev-python/pytest-system-statistics[${PYTHON_USEDEP}]
+		dev-python/pytest-custom-exit-code[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		net-dns/bind-tools
+		>=dev-python/virtualenv-20.3.0[${PYTHON_USEDEP}]
+		dev-util/yamllint[${PYTHON_USEDEP}]
+		!x86? ( >=dev-python/boto3-1.21.46[${PYTHON_USEDEP}] )
+	)
+"
+
+DOCS=( README.rst AUTHORS )
+
+REQUIRED_USE="|| ( raet zeromq )
+	test? ( cheetah genshi )"
+RESTRICT="!test? ( test ) x86? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/salt-3003-gentoolkit-revdep.patch"
+	"${FILESDIR}/salt-3005.1-no-entry-points.patch"
+	"${FILESDIR}/salt-3006-skip-tests-that-oom-machine.patch"
+)
+
+python_prepare_all() {
+	# remove tests with external dependencies that may not be available, and
+	# tests that don't work in sandbox
+	rm tests/unit/{test_{zypp_plugins,module_names},utils/test_extend}.py || die
+	rm tests/unit/modules/test_boto_{vpc,secgroup,elb}.py || die
+	rm tests/unit/states/test_boto_vpc.py || die
+
+	#rm tests/support/gitfs.py || die
+	rm tests/pytests/functional/transport/server/test_req_channel.py || die
+	rm tests/pytests/functional/utils/test_async_event_publisher.py || die
+	rm tests/pytests/functional/runners/test_winrepo.py || die
+	rm tests/unit/netapi/rest_tornado/test_saltnado.py || die
+
+	# tests that require network access
+	rm tests/unit/{states,modules}/test_zcbuildout.py || die
+	rm -r tests/integration/cloud || die
+	rm -r tests/kitchen/tests/wordpress/tests || die
+	rm tests/kitchen/test_kitchen.py || die
+	rm tests/unit/modules/test_network.py || die
+	rm tests/pytests/functional/modules/test_pip.py || die
+	rm tests/pytests/unit/client/ssh/test_ssh.py || die
+	rm -r tests/pytests/{integration,functional}/netapi tests/integration/netapi || die
+
+	# tests require root access
+	rm tests/integration/pillar/test_git_pillar.py || die
+	rm tests/integration/states/test_supervisord.py || die
+	rm tests/pytests/scenarios/performance/test_performance.py || die
+
+	# removes contextvars, see bug: https://bugs.gentoo.org/799431
+	sed -i '/^contextvars/d' requirements/base.txt || die
+
+	# make sure pkg_resources doesn't bomb because pycrypto isn't installed
+	find "${S}" -name '*.txt' -print0 | xargs -0 sed -e '/pycrypto>/ d ; /pycryptodomex/ d' -i || die
+	# pycryptodome rather than pycryptodomex
+	find "${S}" -name '*.py' -print0 | xargs -0 -- sed -i -e 's:Cryptodome:Crypto:g' -- || die
+	# called_once should be assert_called_once_with
+	find "${S}/tests" -name '*.py' -print0 | xargs -0 -- sed -i -e 's:[.]called_once:.assert_called_once:g' -- || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	local svc
+	USE_SETUPTOOLS=1 distutils-r1_python_install_all
+
+	for svc in minion master syndic api; do
+		newinitd "${FILESDIR}"/${svc}-initd-5 salt-${svc}
+		newconfd "${FILESDIR}"/${svc}-confd-1 salt-${svc}
+		systemd_dounit "${FILESDIR}"/salt-${svc}.service
+	done
+
+	insinto /etc/${PN}
+	doins -r conf/*
+}
+
+python_test() {
+	local -a EPYTEST_DESELECT=(
+		# doesn't like the distutils warning
+		tests/pytests/integration/cli/test_batch.py::test_batch_retcode
+		tests/pytests/integration/cli/test_batch.py::test_multiple_modules_in_batch
+		# hangs indefinitely
+		tests/pytests/unit/test_minion.py::test_master_type_disable
+		# needs root
+		tests/pytests/unit/modules/test_cmdmod.py::test_runas_env_sudo_group
+		# don't like sandbox
+		tests/pytests/functional/cli/test_salt.py::test_help_log
+		tests/pytests/functional/cli/test_salt.py::test_versions_report
+		tests/pytests/integration/ssh/test_pillar_compilation.py::test_gpg_pillar
+		tests/pytests/integration/ssh/test_pillar_compilation.py::test_saltutil_runner
+		tests/unit/utils/test_vt.py::test_split_multibyte_characters_unicode
+		tests/unit/utils/test_vt.py::test_split_multibyte_characters_shiftjis
+		tests/pytests/unit/utils/test_vt.py::test_log_sanitize
+		tests/pytests/unit/client/ssh/test_single.py::test_run_with_pre_flight_args
+		tests/pytests/unit/modules/test_aptpkg.py::test_call_apt_dpkg_lock
+		tests/pytests/unit/modules/test_yumpkg.py::test_get_yum_config
+		tests/pytests/unit/test_master.py::test_fileserver_duration
+		tests/pytests/unit/test_template.py::test_compile_template_str_mkstemp_cleanup
+		tests/pytests/unit/_logging/handlers/test_deferred_stream_handler.py::test_deferred_write_on_flush
+		tests/pytests/unit/_logging/handlers/test_deferred_stream_handler.py::test_sync_with_handlers
+		tests/pytests/unit/modules/test_portage_config.py::test_enforce_nice_config
+		tests/pytests/unit/modules/test_msteams.py::test_post_card
+		tests/pytests/unit/renderers/test_yamlex.py::test_basic
+		tests/pytests/unit/renderers/test_yamlex.py::test_complex
+		tests/pytests/unit/states/test_file.py::test_file_recurse_directory_test
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_anyof_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_dict_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_hostname_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_not_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_oneof_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_optional_requirements_config_validation
+		# tests that need network access
+		tests/pytests/unit/utils/test_http.py::test_query_proxy
+		tests/pytests/unit/utils/test_http.py::test_backends_decode_body_false
+		tests/pytests/unit/utils/test_http.py::test_backends_decode_body_true
+		tests/pytests/unit/utils/test_network.py::test_isportopen
+	)
+
+	# testsuite likes lots of files
+	ulimit -n 4096 || die
+
+	# ${T} is too long a path for the tests to work
+	local TMPDIR
+	TMPDIR="$(mktemp --directory --tmpdir=/tmp ${PN}-XXXX)" || die
+	(
+		export TMPDIR
+		cleanup() { rm -rf "${TMPDIR}" || die; }
+
+		trap cleanup EXIT
+
+		addwrite "${TMPDIR}"
+
+		USE_SETUPTOOLS=1 NO_INTERNET=1 SHELL="/bin/bash" \
+			epytest
+	)
+}