blob: ab97b7051d80002e4a4f4e4cb91c8a42e18a0bbc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="forceoptional"
KFMIN=6.6.0
PVCUT=$(ver_cut 1-3)
QTMIN=6.7.2
inherit ecm plasma.kde.org optfeature
DESCRIPTION="Utility providing information about the computer hardware"
HOMEPAGE="https://userbase.kde.org/KInfoCenter"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
IUSE="gles2-only usb"
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus,gles2-only=,gui,widgets]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=kde-frameworks/kauth-${KFMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
gles2-only? ( || (
>=media-libs/mesa-24.1.0_rc1[opengl]
<media-libs/mesa-24.1.0_rc1[gles2]
) )
usb? ( virtual/libusb:1 )
"
RDEPEND="${DEPEND}
|| (
>=dev-qt/qttools-${QTMIN}:6[qdbus]
dev-qt/qdbus:*
)
>=kde-frameworks/kirigami-${KFMIN}:6
>=kde-plasma/systemsettings-${PVCUT}:6
"
BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
CMAKE_SKIP_TESTS=(
# bug 816591
smbmountmodeltest
)
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package usb USB1)
-DCMAKE_DISABLE_FIND_PACKAGE_SeleniumWebDriverATSPI=ON # missing
)
ecm_src_configure
}
src_install() {
ecm_src_install
# TODO: Make this fully obsolete by /etc/os-release
insinto /etc/xdg
doins "${FILESDIR}"/kcm-about-distrorc
insinto /usr/share/${PN}
doins "${FILESDIR}"/glogo-small.png
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature_header "Query network filesystem info:"
optfeature "NFS information module" net-fs/nfs-utils
optfeature "Samba status information module" net-fs/samba
optfeature_header "Query firmware/hardware info:"
fi
optfeature "System DMI table readout" sys-apps/dmidecode
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "Firmware security module" "app-text/aha sys-apps/fwupd"
optfeature "PCI devices information module" sys-apps/pciutils
optfeature "advanced CPU information module" sys-apps/util-linux
optfeature_header "Query GPU/graphics support info:"
fi
optfeature "OpenCL information module" dev-util/clinfo
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "OpenGL information module" x11-apps/mesa-progs
optfeature "Vulkan graphics API information module" dev-util/vulkan-tools
optfeature "Wayland information module" app-misc/wayland-utils
optfeature "X Server information module" x11-apps/xdpyinfo
fi
ecm_pkg_postinst
}
|
