blob: 174015d488f4cc29de55013eb59535a263f5d5a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MY_P="${PN}-${PV/_pre20200309/-alpha4}" # present as upgrade over previous snapshot
SRC_URI="https://github.com/annulen/webkit/releases/download/${MY_P}/${MY_P}.tar.xz"
KEYWORDS="amd64 arm arm64 ~ppc ppc64 x86"
S="${WORKDIR}/${MY_P}"
PYTHON_COMPAT=( python3_{6,7,8} )
inherit check-reqs cmake flag-o-matic python-any-r1 qmake-utils toolchain-funcs
DESCRIPTION="WebKit rendering library for the Qt5 framework (deprecated)"
HOMEPAGE="https://www.qt.io/"
LICENSE="BSD LGPL-2+"
SLOT="5/5.212"
IUSE="geolocation gles2-only +gstreamer +hyphen +jit multimedia nsplugin opengl orientation +printsupport qml webp X"
REQUIRED_USE="
nsplugin? ( X )
qml? ( opengl )
?? ( gstreamer multimedia )
"
# Dependencies found at Source/cmake/OptionsQt.cmake
QT_MIN_VER="5.12.3:5"
BDEPEND="
${PYTHON_DEPS}
dev-lang/ruby:2.5
dev-lang/perl
dev-util/gperf
>=sys-devel/bison-2.4.3
sys-devel/flex
virtual/pkgconfig
virtual/rubygems
"
DEPEND="
dev-db/sqlite:3
dev-libs/icu:=
dev-libs/libxml2
dev-libs/libxslt
>=dev-qt/qtcore-${QT_MIN_VER}
>=dev-qt/qtgui-${QT_MIN_VER}
>=dev-qt/qtnetwork-${QT_MIN_VER}
>=dev-qt/qtwidgets-${QT_MIN_VER}=
media-libs/libpng:0=
media-libs/woff2
virtual/jpeg:0
geolocation? ( >=dev-qt/qtpositioning-${QT_MIN_VER} )
gstreamer? (
dev-libs/glib:2
media-libs/gstreamer:1.0
media-libs/gst-plugins-bad:1.0
media-libs/gst-plugins-base:1.0
)
hyphen? ( dev-libs/hyphen )
multimedia? ( >=dev-qt/qtmultimedia-${QT_MIN_VER}[widgets] )
opengl? (
>=dev-qt/qtgui-${QT_MIN_VER}[gles2-only=]
>=dev-qt/qtopengl-${QT_MIN_VER}[gles2-only=]
)
orientation? ( >=dev-qt/qtsensors-${QT_MIN_VER} )
printsupport? ( >=dev-qt/qtprintsupport-${QT_MIN_VER} )
qml? (
>=dev-qt/qtdeclarative-${QT_MIN_VER}
>=dev-qt/qtwebchannel-${QT_MIN_VER}[qml]
)
webp? ( media-libs/libwebp:= )
X? (
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXrender
)
"
RDEPEND="${DEPEND}"
CHECKREQS_DISK_BUILD="16G" # bug 417307
_check_reqs() {
if [[ ${MERGE_TYPE} != binary ]] && is-flagq "-g*" && ! is-flagq "-g*0"; then
einfo "Checking for sufficient disk space to build ${PN} with debugging flags"
check-reqs_$1
fi
}
pkg_pretend() {
_check_reqs pkg_pretend
}
pkg_setup() {
_check_reqs pkg_setup
python-any-r1_pkg_setup
}
src_configure() {
# Respect CC, otherwise fails on prefix, bug #395875
tc-export CC
# Multiple rendering bugs on youtube, github, etc without this, bug #547224
append-flags $(test-flags -fno-strict-aliasing)
local mycmakeargs=(
-DPORT=Qt
-DENABLE_API_TESTS=OFF
-DENABLE_TOOLS=OFF
-DENABLE_GEOLOCATION=$(usex geolocation)
-DUSE_GSTREAMER=$(usex gstreamer)
-DUSE_LIBHYPHEN=$(usex hyphen)
-DENABLE_JIT=$(usex jit)
-DUSE_QT_MULTIMEDIA=$(usex multimedia)
-DENABLE_NETSCAPE_PLUGIN_API=$(usex nsplugin)
-DENABLE_OPENGL=$(usex opengl)
-DENABLE_PRINT_SUPPORT=$(usex printsupport)
-DENABLE_DEVICE_ORIENTATION=$(usex orientation)
-DENABLE_WEBKIT2=$(usex qml)
$(cmake_use_find_package webp WebP)
-DENABLE_X11_TARGET=$(usex X)
-DRUBY_EXECUTABLE=$(type -P ruby25)
)
cmake_src_configure
}
src_install() {
cmake_src_install
# bug 572056
if [[ ! -f ${ED}$(qt5_get_libdir)/libQt5WebKit.so ]]; then
eerror "${CATEGORY}/${PF} could not build due to a broken ruby environment."
die 'Check "eselect ruby" and ensure you have a working ruby in your $PATH'
fi
}
|
