x11-misc/pcmanfm-qt : version && EAPI bump

1 files changed, 62 insertions, 0 deletions

diff --git a/x11-misc/pcmanfm-qt/pcmanfm-qt-0.14.1.ebuild b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.14.1.ebuild
new file mode 100644
index 00000000..df0694d8
--- /dev/null
+++ b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.14.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Fast lightweight tabbed filemanager (Qt port)"
+HOMEPAGE="https://lxqt.org/"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+IUSE="samba"
+
+PATCHES=( "${FILESDIR}/${P}-use_view_action_icons_from_theme.patch" )
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=lxqt-base/lxqt-build-tools-0.6.0
+"
+DEPEND="
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	=x11-libs/libfm-qt-$(ver_cut 1-2)*
+	x11-libs/libxcb:=
+	x11-misc/xdg-utils
+	virtual/eject
+	virtual/freedesktop-icon-theme
+"
+RDEPEND="${DEPEND}
+	samba? ( net-fs/samba
+		x11-misc/pcmanfm-qt-share
+	)
+	!lxqt-base/lxqt-l10n
+"
+
+pkg_postinst() {
+	xdg_desktop_database_update
+
+	if ! has_version lxqt-base/lxqt-meta && ! has_version gnome-base/gvfs; then
+		elog
+		elog "To make use of the 'trash' functionality, please install"
+		elog "the 'gnome-base/gvfs' package."
+		elog
+	fi
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}