net-misc/meganz-sdk : new package

2 files changed, 72 insertions, 0 deletions

diff --git a/net-misc/meganz-sdk/Manifest b/net-misc/meganz-sdk/Manifest
new file mode 100644
index 00000000..9b541fae
--- /dev/null
+++ b/net-misc/meganz-sdk/Manifest
@@ -0,0 +1 @@
+DIST meganz-sdk-3.3.3.tar.gz 2736357 BLAKE2B ab5c9d2f10e7faf03d0d48ee177c2a5a6ab1605690134343fe457a1f29e2309d5a3a2c70b901ff11051a43179bbcee52b8bd22aca2f0d878bb329d6faf2baf49 SHA512 e33b9a0351e644eae1a34a5371595d0bd5ff8a94310abeeae081e4745d5c3c04aff0a67fb16131a13ccba5f419d613da43c9ae13f5ed870a897f2c2361d07179
diff --git a/net-misc/meganz-sdk/meganz-sdk-3.3.3.ebuild b/net-misc/meganz-sdk/meganz-sdk-3.3.3.ebuild
new file mode 100644
index 00000000..9bb73de7
--- /dev/null
+++ b/net-misc/meganz-sdk/meganz-sdk-3.3.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic qmake-utils autotools db-use
+DESCRIPTION="MEGA C++ SDK"
+HOMEPAGE="https://github.com/meganz/sdk"
+SRC_URI="https://github.com/meganz/sdk/archive/v3.3.3.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="freeimage fuse hardened inotify libuv mediainfo +qt +sqlite"
+
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-libs/crypto++
+	sys-libs/zlib
+	dev-libs/libpcre:3[cxx]
+	dev-libs/openssl:0
+	net-dns/c-ares
+	net-misc/curl
+	sqlite? ( dev-db/sqlite:3 )
+	!sqlite? ( sys-libs/db:*[cxx] )
+	freeimage? ( media-libs/freeimage )
+	libuv? ( dev-libs/libuv )
+	dev-libs/libsodium
+	mediainfo? ( media-libs/libmediainfo )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/sdk-"${PV}"
+
+pkg_setup() {
+	use sqlite || append-cppflags "-I$(db_includedir)"
+}
+
+src_prepare() {
+	default
+	use qt && sed \
+		-e '/SOURCES += src\// s:+:-:' \
+		-e '/!exists.*config.h/ s:!::' \
+		-e 's:-lsqlite3 -lrt:-lmega &:' \
+		-i bindings/qt/sdk.pri
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-chat
+		--disable-examples
+		$(use_enable inotify)
+		$(use_enable hardened gcc-hardening)
+		$(use_with libuv)
+		$(use_with !sqlite db)
+		$(use_with sqlite)
+		$(use_with freeimage)
+		$(use_with fuse)
+		$(use_with mediainfo libmediainfo)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	doheader -r include/mega
+
+	use qt || return
+	insinto /usr/share/${PN}/bindings/qt
+	doins bindings/qt/*.{h,cpp,pri}
+}