media-sound/mpd : use gentoo ebuild

5 files changed, 0 insertions, 349 deletions

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
deleted file mode 100644
index aeb3d6d2..00000000
--- a/media-sound/mpd/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST mpd-0.23.13.tar.xz 776668 BLAKE2B 02907f08cc504d0fbf703179b333b301c7ad8fc8535d85305faa7962dd7faa164f4492286902cb48eaf3db2a1445b541b1261c18a89ca8a73e80016af9581e26 SHA512 1ef2b3a2089aa6078a455e43a2fb9097dc0d5b27b170e6d64e416d5e82349a794eb0acf8db72a975ad024083e872e4a1bd0e0fd51302d327d373b61f01bb819d
diff --git a/media-sound/mpd/files/mpd-0.21.1.logrotate b/media-sound/mpd/files/mpd-0.21.1.logrotate
deleted file mode 100644
index 597c4fb2..00000000
--- a/media-sound/mpd/files/mpd-0.21.1.logrotate
+++ /dev/null
@@ -1,9 +0,0 @@
-/var/lib/mpd/log {
-	missingok
-	weekly
-	delaycompress
-	compress
-	postrotate
-	/etc/init.d/mpd --quiet reload
-	endscript
-}
diff --git a/media-sound/mpd/files/mpd-0.21.4.init b/media-sound/mpd/files/mpd-0.21.4.init
deleted file mode 100644
index 72fede85..00000000
--- a/media-sound/mpd/files/mpd-0.21.4.init
+++ /dev/null
@@ -1,34 +0,0 @@
-#!/sbin/openrc-run
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-: CFGFILE=${CFGFILE:=/etc/mpd.conf}
-
-depend() {
-	need localmount
-	use net netmount nfsmount alsasound esound pulseaudio
-	config ${CFGFILE}
-}
-
-get_config() {
-	x=$1
-	test -e ${CFGFILE} || return 1
-	sed -n \
-	  -e '/^[ \t]*'${x}'/{s:^[ \t]*'${x}'[ \t]\+"\?\([^#"]\+\)[^"]*"\?$:\1: ; p }' \
-	  ${CFGFILE}
-}
-
-extra_started_commands='reload'
-# Required by io_uring
-rc_ulimit="-l 65535"
-command=/usr/bin/mpd
-command_args=${CFGFILE}
-required_files=${CFGFILE}
-pidfile=$(get_config pid_file)
-description="Music Player Daemon"
-
-reload() {
-      ebegin "Reloading ${RC_SVCNAME}"
-      start-stop-daemon --pidfile ${pidfile} --signal HUP
-      eend $?
-  }
diff --git a/media-sound/mpd/files/mpd-0.23.13-ffmpeg61.patch b/media-sound/mpd/files/mpd-0.23.13-ffmpeg61.patch
deleted file mode 100644
index 1f6cb51b..00000000
--- a/media-sound/mpd/files/mpd-0.23.13-ffmpeg61.patch
+++ /dev/null
@@ -1,11 +0,0 @@
-diff -Nur a/src/decoder/plugins/FfmpegIo.cxx b/src/decoder/plugins/FfmpegIo.cxx
---- a/src/decoder/plugins/FfmpegIo.cxx	2023-05-22 18:46:38.000000000 +0100
-+++ b/src/decoder/plugins/FfmpegIo.cxx	2023-12-17 16:45:32.172757417 +0000
-@@ -26,6 +26,7 @@
- 
- extern "C" {
- #include <libavutil/mem.h>
-+#include <libavutil/error.h>
- }
- 
- AvioStream::~AvioStream()
diff --git a/media-sound/mpd/mpd-0.23.13-r5.ebuild b/media-sound/mpd/mpd-0.23.13-r5.ebuild
deleted file mode 100644
index fe9bf348..00000000
--- a/media-sound/mpd/mpd-0.23.13-r5.ebuild
+++ /dev/null
@@ -1,294 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit flag-o-matic linux-info meson systemd xdg
-
-DESCRIPTION="The Music Player Daemon (mpd)"
-HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
-SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
-IUSE="+alsa ao +audiofile bzip2 cdio chromaprint +cue +curl doc +dbus
-	+eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify
-	jack lame libmpdclient libsamplerate libsoxr +mad mikmod mms
-	modplug mpg123 musepack +network nfs openal openmpt opus oss pipe pipewire pulseaudio qobuz
-	recorder samba selinux sid signalfd snapcast sndfile sndio soundcloud sqlite systemd
-	test twolame udisks vorbis wavpack webdav wildmidi upnp
-	zeroconf zip zlib"
-
-OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pipewire pulseaudio snapcast sndio recorder"
-DECODER_PLUGINS="audiofile faad ffmpeg flac fluidsynth mad mikmod
-	modplug mpg123 musepack opus openmpt flac sid vorbis wavpack wildmidi"
-ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
-
-REQUIRED_USE="
-	|| ( ${OUTPUT_PLUGINS} )
-	|| ( ${DECODER_PLUGINS} )
-	network? ( || ( ${ENCODER_PLUGINS} ) )
-	recorder? ( || ( ${ENCODER_PLUGINS} ) )
-	qobuz? ( curl soundcloud )
-	soundcloud? ( curl qobuz )
-	udisks? ( dbus )
-	upnp? ( curl expat )
-	webdav? ( curl expat )
-"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	acct-user/mpd
-	dev-libs/libfmt:=
-	dev-libs/libpcre2
-	media-libs/libogg
-	sys-libs/liburing:=
-	alsa? (
-		media-libs/alsa-lib
-		media-sound/alsa-utils
-	)
-	ao? ( media-libs/libao:=[alsa?,pulseaudio?] )
-	audiofile? ( media-libs/audiofile:= )
-	bzip2? ( app-arch/bzip2 )
-	cdio? (
-		dev-libs/libcdio:=
-		dev-libs/libcdio-paranoia
-	)
-	chromaprint? ( media-libs/chromaprint )
-	curl? ( net-misc/curl )
-	dbus? ( sys-apps/dbus )
-	doc? ( dev-python/sphinx )
-	expat? ( dev-libs/expat )
-	faad? ( media-libs/faad2 )
-	ffmpeg? ( media-video/ffmpeg:= )
-	flac? ( media-libs/flac:= )
-	fluidsynth? ( media-sound/fluidsynth )
-	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
-	icu? (
-		dev-libs/icu:=
-		virtual/libiconv
-	)
-	id3tag? ( media-libs/libid3tag:= )
-	jack? ( virtual/jack )
-	lame? ( network? ( media-sound/lame ) )
-	libmpdclient? ( media-libs/libmpdclient )
-	libsamplerate? ( media-libs/libsamplerate )
-	libsoxr? ( media-libs/soxr )
-	mad? ( media-libs/libmad )
-	mikmod? ( media-libs/libmikmod )
-	mms? ( media-libs/libmms )
-	modplug? ( media-libs/libmodplug )
-	mpg123? ( media-sound/mpg123 )
-	musepack? ( media-sound/musepack-tools )
-	network? ( >=media-libs/libshout-2.4.0 )
-	nfs? ( net-fs/libnfs )
-	openal? ( media-libs/openal )
-	openmpt? ( media-libs/libopenmpt )
-	opus? ( media-libs/opus )
-	pulseaudio? ( media-libs/libpulse )
-	pipewire? ( media-video/pipewire:= )
-	qobuz? ( dev-libs/libgcrypt:0 )
-	samba? ( net-fs/samba )
-	selinux? ( sec-policy/selinux-mpd )
-	sid? ( || (
-		media-libs/libsidplay:2
-		media-libs/libsidplayfp
-	) )
-	snapcast? ( media-sound/snapcast )
-	sndfile? ( media-libs/libsndfile )
-	sndio? ( media-sound/sndio )
-	soundcloud? ( >=dev-libs/yajl-2:= )
-	sqlite? ( dev-db/sqlite:3 )
-	systemd? ( sys-apps/systemd:= )
-	twolame? ( media-sound/twolame )
-	udisks? ( sys-fs/udisks:2 )
-	upnp? ( net-libs/libupnp:0 )
-	vorbis? ( media-libs/libvorbis )
-	wavpack? ( media-sound/wavpack )
-	wildmidi? ( media-sound/wildmidi )
-	zeroconf? ( net-dns/avahi[dbus] )
-	zip? ( dev-libs/zziplib:= )
-	zlib? ( sys-libs/zlib:= )"
-
-DEPEND="${RDEPEND}
-	dev-libs/boost:=
-	test? ( dev-cpp/gtest )"
-
-BDEPEND="virtual/pkgconfig"
-
-PATCHES=(
-	"${FILESDIR}/${P}-ffmpeg61.patch"
-)
-
-pkg_setup() {
-	if use eventfd; then
-		CONFIG_CHECK+=" ~EVENTFD"
-		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
-	fi
-
-	if use signalfd; then
-		CONFIG_CHECK+=" ~SIGNALFD"
-		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
-	fi
-
-	if use inotify; then
-		CONFIG_CHECK+=" ~INOTIFY_USER"
-		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
-	fi
-
-	if use eventfd || use signalfd || use inotify; then
-		linux-info_pkg_setup
-	fi
-
-	elog "If you will be starting mpd via ${EROOT}/etc/init.d/mpd, please make sure that MPD's pid_file is _set_."
-}
-
-src_prepare() {
-	sed -i \
-		-e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
-		-e 's:^#user.*$:user "mpd":' \
-		-e 's:^#bind_to_address.*any.*$:bind_to_address "localhost":' \
-		-e 's:^#bind_to_address.*$:bind_to_address "/var/lib/mpd/socket":' \
-		-e 's:^#music_directory.*$:music_directory "/var/lib/mpd/music":' \
-		-e 's:^#playlist_directory.*$:playlist_directory "/var/lib/mpd/playlists":' \
-		-e 's:^#db_file.*$:db_file "/var/lib/mpd/database":' \
-		-e 's:^#log_file.*$:log_file "/var/lib/mpd/log":' \
-		-e 's:^#pid_file.*$:pid_file "/var/lib/mpd/pid":' \
-		-e 's:^#state_file.*$:state_file "/var/lib/mpd/state":' \
-		doc/mpdconf.example || die
-	default
-}
-
-src_configure() {
-	local emesonargs=(
-		$(meson_feature bzip2)
-		$(meson_feature cdio cdio_paranoia)
-		$(meson_feature chromaprint)
-		$(meson_use cue)
-		$(meson_feature curl)
-		$(meson_feature dbus)
-		$(meson_use eventfd)
-		$(meson_feature expat)
-		$(meson_feature icu)
-		$(meson_feature id3tag)
-		$(meson_use inotify)
-		-Dipv6=enabled
-		$(meson_feature cdio iso9660)
-		$(meson_feature libmpdclient)
-		$(meson_feature libsamplerate)
-		$(meson_feature mms)
-		$(meson_feature nfs)
-		$(meson_use signalfd)
-		$(meson_feature samba smbclient)
-		$(meson_feature libsoxr soxr)
-		$(meson_feature sqlite)
-		$(meson_feature systemd)
-		$(meson_use test)
-		$(meson_feature udisks)
-		-Dupnp=$(usex upnp pupnp disabled)
-		$(meson_feature webdav)
-		-Dzeroconf=$(usex zeroconf avahi disabled)
-		$(meson_feature zlib)
-		$(meson_feature zip zzip)
-	)
-
-	emesonargs+=(
-		$(meson_feature alsa)
-		$(meson_feature ao)
-		$(meson_use fifo)
-		$(meson_feature jack)
-		$(meson_feature openal)
-		$(meson_feature oss)
-		$(meson_use pipe)
-		$(meson_feature pipewire)
-		$(meson_feature pulseaudio pulse)
-		$(meson_use recorder)
-		$(meson_use snapcast)
-		$(meson_feature sndio)
-	)
-
-	if use samba || use upnp; then
-		emesonargs+=( -Dneighbor=true )
-	fi
-
-	append-lfs-flags
-	append-ldflags "-L${ESYSROOT}/usr/$(get_libdir)/sidplay/builders"
-
-	if use network; then
-		emesonargs+=(
-			-Dshine=disabled
-			-Dshout=enabled
-			$(meson_feature vorbis vorbisenc)
-			-Dhttpd=true
-			$(meson_feature lame)
-			$(meson_feature twolame)
-			$(meson_use audiofile wave_encoder)
-		)
-	fi
-
-	emesonargs+=(
-		# media-libs/adplug is not packaged anymore
-		-Dadplug=disabled
-		$(meson_feature audiofile)
-		$(meson_feature faad)
-		$(meson_feature ffmpeg)
-		$(meson_feature flac)
-		$(meson_feature fluidsynth)
-		$(meson_feature gme)
-		$(meson_feature mad)
-		$(meson_feature mikmod)
-		$(meson_feature modplug)
-		$(meson_feature musepack mpcdec)
-		$(meson_feature mpg123)
-		$(meson_feature openmpt)
-		$(meson_feature opus)
-		$(meson_feature sid sidplay)
-		$(meson_feature sndfile)
-		$(meson_feature vorbis)
-		$(meson_feature wavpack)
-		$(meson_feature wildmidi)
-		$(meson_feature qobuz)
-		$(meson_feature soundcloud)
-
-		--libdir="/usr/$(get_libdir)"
-		$(meson_feature doc documentation)
-		-Dsolaris_output=disabled
-
-		-Ddatabase=true
-		-Ddaemon=true
-		-Ddsd=true
-		-Dio_uring=enabled
-		-Dtcp=true
-
-		-Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
-		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
-
-		$(meson_feature icu iconv)
-	)
-
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	insinto /etc
-	newins doc/mpdconf.example mpd.conf
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}"/${PN}-0.21.1.logrotate ${PN}
-
-	newinitd "${FILESDIR}"/${PN}-0.21.4.init ${PN}
-
-	sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' "${ED}"/etc/mpd.conf || die "sed failed"
-
-	keepdir /var/lib/mpd
-	keepdir /var/lib/mpd/music
-	keepdir /var/lib/mpd/playlists
-
-	rm -r "${ED}"/usr/share/doc/mpd || die
-
-	fowners mpd:audio -R /var/lib/mpd
-}