dev-python/zeroconf : import an older version from gentoo

  * newer versions of dev-python/zeroconf depend on >=dev-python/cython-3
  * some other packages in the tree depend on <dev-python/cython-3
  * drop the package when everything is compatible with >=dev-python/cython-3

2 files changed, 57 insertions, 0 deletions

diff --git a/dev-python/zeroconf/Manifest b/dev-python/zeroconf/Manifest
new file mode 100644
index 00000000..bda362c5
--- /dev/null
+++ b/dev-python/zeroconf/Manifest
@@ -0,0 +1 @@
+DIST zeroconf-0.82.1.tar.gz 147915 BLAKE2B 608d077e042f1b74f25f44b5b64350782944d0f4da96bb17a32bf9cbedfe5c1b751a8731a65c5cac86cc458425f2e38d0549317e7216c577567d0852a7a6c7ed SHA512 a02e9b1c6ce976de815f902f5607d6b0fecba4abc403234cbeeeef1abe450c3894e6c117bb554ba76c27250c748b36b862abb8ed059f0da8d31e5b10e5f1c2e1
diff --git a/dev-python/zeroconf/zeroconf-0.82.1-r10.ebuild b/dev-python/zeroconf/zeroconf-0.82.1-r10.ebuild
new file mode 100644
index 00000000..2caf1f2c
--- /dev/null
+++ b/dev-python/zeroconf/zeroconf-0.82.1-r10.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
+HOMEPAGE="
+	https://github.com/python-zeroconf/python-zeroconf/
+	https://pypi.org/project/zeroconf/
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-3.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+# the build system uses custom build script that uses distutils to build
+# C extensions, sigh
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.6.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+python_test() {
+	local -x SKIP_IPV6=1
+	local EPYTEST_DESELECT=(
+		# network
+		tests/test_core.py::Framework::test_close_multiple_times
+		tests/test_core.py::Framework::test_launch_and_close
+		tests/test_core.py::Framework::test_launch_and_close_context_manager
+
+		# fragile to timeouts (?)
+		tests/services/test_browser.py::test_service_browser_expire_callbacks
+		tests/utils/test_asyncio.py::test_run_coro_with_timeout
+	)
+
+	epytest -o addopts=
+}