blob: 3722d7fef3a7d82e7f36a9208d03012e2e502123 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools unpacker
DESCRIPTION="Ice Window Manager with Themes"
HOMEPAGE="https://ice-wm.org/ https://github.com/ice-wm/icewm"
LICENSE="GPL-2"
SRC_URI="https://github.com/ice-wm/icewm/releases/download/${PV}/${P}.tar.lz"
SLOT="0"
KEYWORDS="amd64 ~ppc ~ppc64 ~sparc x86"
IUSE="+alsa ao bidi debug +gdk-pixbuf imlib nls truetype xinerama"
# Tests broken in all versions, patches welcome, bug #323907, #389533
RESTRICT="test"
REQUIRED_USE="|| ( alsa ao )"
#?? ( gdk-pixbuf imlib )
#fix for icewm preversion package names
S="${WORKDIR}/${P/_}"
# These are the core dependencies of icewm.
# Look into configure.ac and search for PKG_CHECK_MODULES([CORE]
CORE_DEPEND="
media-libs/fontconfig
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrender
"
RDEPEND="
${CORE_DEPEND}
dev-libs/glib:2
x11-libs/libICE
x11-libs/libSM
x11-libs/libXft
x11-libs/libXpm
x11-libs/libXrandr
alsa? (
media-libs/alsa-lib
media-libs/libsndfile[alsa]
)
ao? (
media-libs/libao
media-libs/libsndfile
)
bidi? ( dev-libs/fribidi )
gdk-pixbuf? (
x11-libs/gdk-pixbuf-xlib
>=x11-libs/gdk-pixbuf-2.42.0:2
)
!gdk-pixbuf? (
imlib? (
gnome-base/librsvg:2
media-libs/imlib2
)
!imlib? (
media-libs/libpng:0=
media-libs/libjpeg-turbo:=
)
)
xinerama? ( x11-libs/libXinerama )
"
DEPEND="
${RDEPEND}
x11-base/xorg-proto
gdk-pixbuf? ( gnome-base/librsvg:2 )
"
BDEPEND="
$(unpacker_src_uri_depends)
app-text/asciidoc
virtual/pkgconfig
nls? ( >=sys-devel/gettext-0.19.8 )
"
pkg_pretend() {
if use gdk-pixbuf && use imlib ; then
einfo 'Conflicting USE flags have been enabled:'
einfo '"gdk-pixbuf" and "imlib" exclude each other!'
einfo 'Using "gdk-pixbuf".'
fi
}
src_prepare() {
default
eautoreconf
}
src_configure() {
local icesound
if use alsa && use ao ; then
icesound="alsa,ao"
elif use alsa ; then
icesound="alsa"
elif use ao ; then
icesound="ao"
fi
local myconf=(
--enable-logevents
--enable-xrandr
--with-cfgdir="${EPREFIX}"/etc/icewm
--with-docdir="${EPREFIX}"/usr/share/doc/${PF}/html
--with-icesound="${icesound}"
--with-libdir="${EPREFIX}"/usr/share/icewm
$(use_enable bidi fribidi)
$(use_enable debug)
$(use_enable debug logevents)
$(use_enable gdk-pixbuf)
$(use_enable imlib imlib2)
$(use_enable nls i18n)
$(use_enable nls)
$(use_enable xinerama)
)
if use truetype ; then
myconf+=(
--enable-shape
)
else
myconf+=(
--disable-xfreetype
--enable-corefonts
)
fi
econf "${myconf[@]}"
}
src_install() {
local DOCS=( AUTHORS ChangeLog NEWS README.md TODO VERSION )
default
docinto html
dodoc doc/icewm.html
dodoc man/*.html
exeinto /etc/X11/Sessions
doexe "${FILESDIR}/icewm"
}
|