blob: d1f4f1c97f13adbe869bfa17d3c327a041807a4d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs flag-o-matic
DESCRIPTION="SYSLINUX, PXELINUX, ISOLINUX, EXTLINUX and MEMDISK bootloaders"
HOMEPAGE="https://www.syslinux.org/"
MY_P=${P/_/-}
SRC_URI="https://git.zytor.com/syslinux/syslinux.git/snapshot/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
#KEYWORDS="-* ~amd64 ~x86"
IUSE="abi_x86_32 abi_x86_64 +bios +efi"
REQUIRED_USE="|| ( bios efi )
efi? ( || ( abi_x86_32 abi_x86_64 ) )"
RESTRICT="test"
BDEPEND="
dev-lang/perl
bios? ( dev-lang/nasm )
"
RDEPEND="
sys-apps/util-linux
sys-fs/mtools
dev-perl/Crypt-PasswdMD5
dev-perl/Digest-SHA1
"
DEPEND="${RDEPEND}
efi? ( sys-boot/gnu-efi[abi_x86_32(-)?,abi_x86_64(-)?] )
virtual/os-headers
"
S=${WORKDIR}/${MY_P}
QA_EXECSTACK="usr/share/syslinux/*"
QA_WX_LOAD="usr/share/syslinux/*"
QA_PRESTRIPPED="usr/share/syslinux/.*"
QA_FLAGS_IGNORED=".*"
src_prepare() {
local PATCHES=(
"${FILESDIR}/6.04_pre1"
"${FILESDIR}/6.04_pre3"
)
default
}
efimake() {
local ABI="${1}"
local libdir="$(get_libdir)"
shift
local args=(
EFIINC="${ESYSROOT}/usr/include/efi"
LIBDIR="${ESYSROOT}/usr/${libdir}"
LIBEFI="${ESYSROOT}/usr/${libdir}/libefi.a"
"${@}"
)
emake "${args[@]}"
}
src_compile() {
filter-lto #863722
local DATE=$(date -u -r NEWS +%Y%m%d)
local HEXDATE=$(printf '0x%08x' "${DATE}")
tc-export AR CC LD OBJCOPY RANLIB
unset LDFLAGS
if use bios; then
emake bios DATE="${DATE}" HEXDATE="${HEXDATE}"
fi
if use efi; then
if use abi_x86_32; then
efimake x86 efi32 DATE="${DATE}" HEXDATE="${HEXDATE}"
fi
if use abi_x86_64; then
efimake amd64 efi64 DATE="${DATE}" HEXDATE="${HEXDATE}"
fi
fi
}
src_install() {
local firmware=( $(usev bios) )
if use efi; then
use abi_x86_32 && firmware+=( efi32 )
use abi_x86_64 && firmware+=( efi64 )
fi
local args=(
INSTALLROOT="${ED}"
MANDIR='$(DATADIR)/man'
"${firmware[@]}"
install
)
emake -j1 "${args[@]}"
mv "${ED}"/usr/bin/keytab-{lilo,syslinux} || die
einstalldocs
dostrip -x /usr/share/syslinux
}
|