blob: f085bc1c576bd6a2f06581555c6eea93af688daa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit systemd
MY_PV="${PV//_pre*}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Backend implementation for xdg-desktop-portal using GTK+"
HOMEPAGE="https://flatpak.org/ https://github.com/flatpak/xdg-desktop-portal-gtk"
SRC_URI="https://github.com/flatpak/${PN}/releases/download/${MY_PV}/${MY_P}.tar.xz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
IUSE="wayland X"
BDEPEND="
dev-util/gdbus-codegen
sys-devel/gettext
virtual/pkgconfig
"
DEPEND="
dev-libs/glib:2
gnome-base/gsettings-desktop-schemas
media-libs/fontconfig
sys-apps/dbus
>=sys-apps/xdg-desktop-portal-1.14.0
x11-libs/cairo[X?]
x11-libs/gdk-pixbuf:2
x11-libs/gtk+:3[wayland?,X?]
"
RDEPEND="${DEPEND}"
S="${WORKDIR}/${MY_P}"
src_configure() {
# As done in Fedora:
# All backends that are disabled are instead provided by
# xdg-desktop-portal-gnome to keep this package free of GNOME dependencies.
# The appchooser and settings backends are enabled for non-GNOME GTK
# applications.
local myeconfargs=(
--with-systemduserunitdir="$(systemd_get_userunitdir)"
--enable-appchooser
--enable-settings
--disable-background
--disable-lockdown
--disable-screencast
--disable-screenshot
--disable-wallpaper
)
econf "${myeconfargs[@]}"
}
|