blob: 864663a977579bbeaea0fd58b401889ce67534dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 2014-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson
DESCRIPTION="Base functions required by all Gentoo systems"
HOMEPAGE="https://gitweb.gentoo.org/proj/gentoo-functions.git"
if [[ ${PV} == 9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/gentoo-functions.git"
else
SRC_URI="https://gitweb.gentoo.org/proj/gentoo-functions.git/snapshot/${P}.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
fi
LICENSE="GPL-2 public-domain"
SLOT="0"
IUSE="test"
RESTRICT="!test? ( test )"
# Specifically needs GNU find, as well.
RDEPEND=">=sys-apps/findutils-4.9"
src_configure() {
local emesonargs=(
# Deliberately avoid /usr as consumers assume we're at /lib/gentoo.
--prefix="${EPREFIX:-/}"
--mandir="${EPREFIX}/usr/share/man"
$(meson_use test tests)
)
meson_src_configure
}
src_install() {
meson_src_install
if [[ ${EPREFIX} ]]; then
while read -r; do
if [[ ${REPLY} == $'\t'genfun_prefix= ]]; then
printf 'genfun_prefix=%q\n' "${EPREFIX}"
else
printf '%s\n' "${REPLY}"
fi || ! break
done < "${ED}/lib/gentoo/functions.sh" > "${T}/functions.sh" \
&& mv -- "${T}/functions.sh" "${ED}/lib/gentoo/functions.sh" \
|| die
fi
}
|