blob: 4f976f3aff6b918173b15be3e7fc33caf0b37a12 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8} )
inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
HOMEPAGE="https://fwupd.org"
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
IUSE="agent amt dell gtk-doc elogind flashrom minimal introspection +man nvme policykit synaptics systemd test thunderbolt tpm uefi"
REQUIRED_USE="${PYTHON_REQUIRED_USE}
^^ ( elogind minimal systemd )
dell? ( uefi )
minimal? ( !introspection )
"
RESTRICT="!test? ( test )"
BDEPEND="$(vala_depend)
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc )
introspection? ( dev-libs/gobject-introspection )
man? (
app-text/docbook-sgml-utils
sys-apps/help2man
)
test? (
thunderbolt? ( dev-util/umockdev )
net-libs/gnutls[tools]
)
"
CDEPEND="${PYTHON_DEPS}
>=app-arch/gcab-1.0
app-arch/libarchive:=
dev-db/sqlite
>=dev-libs/glib-2.45.8:2
dev-libs/json-glib
dev-libs/libgpg-error
dev-libs/libgudev:=
>=dev-libs/libgusb-0.3.5[introspection?]
>=dev-libs/libjcat-0.1.0[gpg,pkcs7]
>=dev-libs/libxmlb-0.1.13:=
$(python_gen_cond_dep '
dev-python/pillow[${PYTHON_MULTI_USEDEP}]
dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
')
>=net-libs/libsoup-2.51.92:2.4[introspection?]
net-misc/curl
virtual/libelf:0=
virtual/udev
dell? (
>=sys-libs/libsmbios-2.4.0
)
elogind? ( >=sys-auth/elogind-211 )
flashrom? ( >=sys-apps/flashrom-1.2-r3 )
policykit? (
>=sys-auth/polkit-0.103
)
systemd? ( >=sys-apps/systemd-211 )
tpm? ( app-crypt/tpm2-tss )
uefi? (
media-libs/fontconfig
media-libs/freetype
sys-boot/gnu-efi
sys-boot/efibootmgr
sys-libs/efivar
x11-libs/cairo
)
"
# Block sci-chemistry/chemical-mime-data for bug #701900
RDEPEND="
!<sci-chemistry/chemical-mime-data-0.1.94-r4
${CDEPEND}
sys-apps/dbus
"
DEPEND="
${CDEPEND}
x11-libs/pango[introspection]
"
PATCHES=(
"${FILESDIR}/${PN}-1.3.9-logind_plugin.patch"
)
pkg_setup() {
python-single-r1_pkg_setup
if use nvme; then
kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
fi
}
src_prepare() {
default
# c.f. https://github.com/fwupd/fwupd/issues/1414
sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
-i plugins/thunderbolt/meson.build || die
sed '/platform-integrity/d' \
-i plugins/meson.build || die #753521
vala_src_prepare
}
src_configure() {
local emesonargs=(
--localstatedir "${EPREFIX}"/var
-Dbuild="$(usex minimal standalone all)"
$(meson_use agent)
$(meson_use amt plugin_amt)
$(meson_use dell plugin_dell)
$(meson_use elogind)
$(meson_use flashrom plugin_flashrom)
$(meson_use gtk-doc gtkdoc)
$(meson_use man)
$(meson_use nvme plugin_nvme)
$(meson_use introspection)
$(meson_use policykit polkit)
$(meson_use synaptics plugin_synaptics)
$(meson_use systemd)
$(meson_use test tests)
$(meson_use thunderbolt plugin_thunderbolt)
$(meson_use tpm)
$(meson_use uefi plugin_uefi)
# Dependencies are not available (yet?)
-Dplugin_modem_manager="false"
-Dconsolekit="false"
)
use ppc64 && emesonargs+=( -Dplugin_msr="false" )
export CACHE_DIRECTORY="${T}"
meson_src_configure
}
src_install() {
meson_src_install
if ! use minimal ; then
sed "s@%SEAT_MANAGER%@elogind@" \
"${FILESDIR}"/${PN}-r1 \
> "${T}"/${PN} || die
doinitd "${T}"/${PN}
if ! use systemd ; then
# Don't timeout when fwupd is running (#673140)
sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
-i "${ED}"/etc/${PN}/daemon.conf || die
fi
fi
}
pkg_postinst() {
xdg_pkg_postinst
elog "In case you are using openrc as init system"
elog "and you're upgrading from <fwupd-1.1.0, you"
elog "need to start the fwupd daemon via the openrc"
elog "init script that comes with this package."
}
|