blob: 4f9c9456987e9c92db482e10e50be5d883a7f3b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
MY_P="${P/_/-}"
DESCRIPTION="A portable high-level Jabber/XMPP client library for C++"
HOMEPAGE="https://camaya.net/gloox/"
SRC_URI="https://camaya.net/download/${MY_P}.tar.bz2"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-3"
# Check upstream changelog: https://camaya.net/gloox/changelog/
SLOT="0/18"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug gnutls idn ssl static-libs test +xhtmlim zlib"
RESTRICT="!test? ( test )"
DEPEND="
idn? ( net-dns/libidn:= )
gnutls? ( net-libs/gnutls:= )
ssl? ( dev-libs/openssl:0= )
zlib? ( sys-libs/zlib )
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig"
src_prepare() {
default
eautoreconf
}
src_configure() {
local myeconfargs=(
--without-examples # not installed anyway so don't build them
$(usex debug "--enable-debug" '')
$(use_enable static-libs static)
$(use_enable xhtmlim)
$(use_with idn libidn)
$(use_with gnutls)
$(use_with ssl openssl)
$(use_with test tests)
$(use_with zlib)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${ED}" -name "*.la" -delete || die
}
|
