blob: be2de6bbc614877f1d56236e68351937cc3ddbc8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools flag-o-matic
DESCRIPTION="A framework for layer 2 attacks"
HOMEPAGE="http://www.yersinia.net/"
SRC_URI="https://github.com/tomac/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="gtk ncurses"
RDEPEND="
>=net-libs/libnet-1.1.2
>=net-libs/libpcap-0.9.4
ncurses? ( >=sys-libs/ncurses-5.5:= )
gtk? (
dev-libs/glib:2
x11-libs/gdk-pixbuf
=x11-libs/gtk+-2*
)
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
DOCS=( AUTHORS ChangeLog FAQ README THANKS TODO )
PATCHES=(
"${FILESDIR}"/${PN}-0.7.1-no-ncurses.patch
"${FILESDIR}"/${PN}-0.7.3-tinfo.patch
"${FILESDIR}"/${PN}-0.8.2-configure-clang16.patch
"${FILESDIR}"/${PN}-0.8.2-configure-clang16-deux.patch
)
src_prepare() {
default
if ! use gtk; then
# bug #514802
sed -i -e '/AM_GLIB_GNU_GETTEXT/d' configure.in || die
fi
eautoreconf
}
src_configure() {
append-cflags -fcommon
econf \
--enable-admin \
--with-pcap-includes=/usr/include \
$(use_with ncurses) \
$(use_enable gtk)
}
src_compile() {
emake CFLAGS="${CFLAGS}"
}
|
