blob: edff6ecff9739e267576c5d6db00f666088e8863 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6..8} )
DISTUTILS_USE_SETUPTOOLS=rdepend
DISTUTILS_SINGLE_IMPL=true
inherit distutils-r1 eutils
DESCRIPTION="Download media files from Yle Areena"
HOMEPAGE="https://aajanki.github.io/yle-dl/ https://github.com/aajanki/yle-dl"
SRC_URI="https://github.com/aajanki/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="libav test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
# Requires an active internet connection during tests,
# FEATURES="-network-sandbox" to test.
RESTRICT="test"
RDEPEND="${PYTHON_DEPS}
!libav? ( media-video/ffmpeg )
net-misc/wget
$(python_gen_cond_dep '
>=dev-python/attrs-18.1.0[${PYTHON_MULTI_USEDEP}]
>=dev-python/configargparse-0.13.0[${PYTHON_MULTI_USEDEP}]
dev-python/future[${PYTHON_MULTI_USEDEP}]
dev-python/lxml[${PYTHON_MULTI_USEDEP}]
dev-python/mini-amf[${PYTHON_MULTI_USEDEP}]
dev-python/progress[${PYTHON_MULTI_USEDEP}]
dev-python/pycryptodome[${PYTHON_MULTI_USEDEP}]
dev-python/requests[${PYTHON_MULTI_USEDEP}]
')
"
DEPEND="
test? (
${RDEPEND}
media-video/ffmpeg[gnutls]
$(python_gen_cond_dep '
dev-python/pytest[${PYTHON_MULTI_USEDEP}]
')
)
"
BDEPEND="${PYTHON_DEPS}"
distutils_enable_tests setup.py
DOCS=( COPYING ChangeLog README.fi README.md yledl.conf.sample )
src_prepare() {
default
# Gentoo doesn't ship pycryptodomex with pycryptodome
sed -i 's/pycryptodomex/pycryptodome/g' setup.py || die
}
src_install() {
docompress -x "/usr/share/doc/${PF}/yledl.conf.sample"
distutils-r1_src_install
}
pkg_postinst() {
elog "Sample configuration file has been installed to "
elog " /usr/share/doc/yle-dl-${PV}/yledl.conf.sample"
elog ""
elog "Optional download engines: "
optfeature "php download engine using rtmpdump" "dev-lang/php:*[bcmath,cli,curl,simplexml] media-video/rtmpdump"
optfeature "youtube-dl download engine" net-misc/youtube-dl
}
|