blob: 7d4f0574c4849694b6be7bf0b9885326a95e0df4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit gnome.org meson vala virtualx xdg-utils
DESCRIPTION="A cheesy program to take pictures and videos from your webcam"
HOMEPAGE="https://wiki.gnome.org/Apps/Cheese"
LICENSE="GPL-2+"
SLOT="0/8" # subslot = libcheese soname version
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="gtk-doc +introspection test X"
RESTRICT="test" # Tests fail
REQUIRED_USE="test? ( X )"
COMMON_DEPEND="
>=dev-libs/glib-2.39.90:2
>=x11-libs/gtk+-3.13.4:3[introspection?]
>=gnome-base/gnome-desktop-2.91.6:3=
>=media-libs/libcanberra-0.26[gtk3]
>=media-libs/clutter-1.13.2:1.0[introspection?]
>=media-libs/clutter-gtk-0.91.8:1.0
media-libs/clutter-gst:3.0
media-libs/cogl:1.0=[introspection?]
media-video/gnome-video-effects
x11-libs/gdk-pixbuf:2[jpeg,introspection?]
>=media-libs/gstreamer-1.4:1.0[introspection?]
>=media-libs/gst-plugins-base-1.4:1.0[introspection?,ogg,pango,theora,vorbis,X?]
introspection? ( >=dev-libs/gobject-introspection-0.6.7:= )
X? (
x11-base/xorg-proto
x11-libs/libX11
)
"
DEPEND="
${COMMON_DEPEND}
test? ( x11-libs/libXtst )
"
RDEPEND="${COMMON_DEPEND}
>=media-libs/gst-plugins-bad-1.4:1.0
>=media-libs/gst-plugins-good-1.4:1.0
>=media-plugins/gst-plugins-jpeg-1.4:1.0
>=media-plugins/gst-plugins-v4l2-1.4:1.0
>=media-plugins/gst-plugins-vpx-1.4:1.0
"
BDEPEND="
$(vala_depend)
app-text/docbook-xml-dtd:4.3
dev-util/itstool
dev-libs/appstream-glib
>=dev-util/intltool-0.50
dev-libs/libxslt
dev-libs/libxml2:2
dev-util/glib-utils
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${P}-buildfix.patch
"${FILESDIR}"/${P}-help-No-more-menu-bars-in-3.34-UI.patch
)
src_prepare() {
vala_src_prepare
default
}
src_configure() {
local emesonargs=(
$(meson_use gtk-doc gtk_doc)
$(meson_use introspection)
$(meson_use test tests)
-Dman=true
)
meson_src_configure
# Hack: version.xml is not generated if gtk-doc is not enabled
echo ${PV} > docs/reference/version.xml
}
src_test() {
virtx meson_src_test
}
pkg_postinst() {
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}
|
