blob: 2b8ee8636dd3033d7a2703d22a2d9ddd25204d0c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic xdg
DESCRIPTION="Environment and programming language for real time audio synthesis"
HOMEPAGE="https://supercollider.github.io/"
SRC_URI="https://github.com/supercollider/supercollider/releases/download/Version-${PV}/SuperCollider-${PV}-Source.tar.bz2"
S="${WORKDIR}/SuperCollider-${PV}-Source"
LICENSE="GPL-2 gpl3? ( GPL-3 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ableton-link cpu_flags_x86_sse cpu_flags_x86_sse2 debug emacs +fftw gedit +gpl3 jack qt5 server +sndfile static-libs vim webengine X +zeroconf"
REQUIRED_USE="
qt5? ( X )
webengine? ( qt5 )
"
BDEPEND="
virtual/pkgconfig
qt5? ( dev-qt/linguist-tools:5 )
"
RDEPEND="
dev-cpp/yaml-cpp:=
dev-libs/boost:=
media-libs/alsa-lib
sys-libs/readline:0=
virtual/libudev:=
fftw? ( sci-libs/fftw:3.0= )
jack? ( virtual/jack )
!jack? ( media-libs/portaudio )
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtprintsupport:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
)
sndfile? ( media-libs/libsndfile )
webengine? (
dev-qt/qtwebchannel:5
dev-qt/qtwebengine:5[widgets]
dev-qt/qtwebsockets:5
)
X? (
x11-libs/libX11
x11-libs/libXt
)
zeroconf? ( net-dns/avahi )
"
DEPEND="${RDEPEND}
dev-libs/icu
emacs? ( >=app-editors/emacs-23.1:* )
gedit? ( app-editors/gedit )
qt5? ( dev-qt/qtconcurrent:5 )
vim? ( app-editors/vim )
"
PATCHES=(
"${FILESDIR}/${P}-boost-1.84.patch" # bug 921595
"${FILESDIR}/${P}-gcc-13.patch" # bug 905127
"${FILESDIR}/${P}-no-ccache.patch" # bug 922095
)
src_configure() {
local mycmakeargs=(
-DSC_CLANG_USES_LIBSTDCPP=ON
-DINSTALL_HELP=ON
-DSYSTEM_BOOST=ON
-DSYSTEM_YAMLCPP=ON
-DUSE_CCACHE=OFF
-DSC_ABLETON_LINK=$(usex ableton-link)
-DSSE=$(usex cpu_flags_x86_sse)
-DSSE2=$(usex cpu_flags_x86_sse2)
-DSC_EL=$(usex emacs)
-DFFT_GREEN=$(usex !fftw)
-DSC_ED=$(usex gedit)
-DNO_GPL3=$(usex !gpl3)
-DAUDIOAPI=$(usex jack jack portaudio)
-DSC_IDE=$(usex qt5)
-DSC_QT=$(usex qt5)
-DSCLANG_SERVER=$(usex server)
-DSUPERNOVA=$(usex server)
-DNO_LIBSNDFILE=$(usex !sndfile)
-DLIBSCSYNTH=$(usex !static-libs)
-DSC_VIM=$(usex vim)
-DNO_X11=$(usex !X)
-DNO_AVAHI=$(usex !zeroconf)
)
use qt5 && mycmakeargs+=(
-DSC_USE_QTWEBENGINE=$(usex webengine)
)
use debug && mycmakeargs+=(
-DSC_MEMORY_DEBUGGING=ON
-DSN_MEMORY_DEBUGGING=ON
-DGC_SANITYCHECK=ON
)
append-flags $(usex debug '' -DNDEBUG)
cmake_src_configure
}
src_install() {
cmake_src_install
use emacs && newdoc editors/sc-el/README.md README.emacs
use gedit && newdoc editors/sced/README.md README.gedit
use vim && newdoc editors/scvim/README.md README.vim
}
src_test() {
export QT_QPA_PLATFORM=offscreen
cmake_src_test
}
pkg_preinst() {
xdg_pkg_preinst
}
pkg_postinst() {
einfo "Notice: SuperCollider is not very intuitive to get up and running."
einfo "The best course of action to make sure that the installation was"
einfo "successful and get you started with using SuperCollider is to take"
einfo "a look through ${EROOT}/usr/share/doc/${PF}/README.md.bz2"
xdg_pkg_postinst
}
pkg_postrm() {
xdg_pkg_postrm
}
|
