summaryrefslogtreecommitdiff
path: root/media-gfx/pinta/pinta-2.1.1-r1.ebuild
blob: 17049a054f72ca8b7c95a2d0a3117299065b54fc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DOTNET_PKG_COMPAT=7.0
NUGETS="
atksharp@3.24.24.38
benchmarkdotnet.annotations@0.13.2
benchmarkdotnet@0.13.2
cairosharp@3.24.24.38
commandlineparser@2.4.3
gdksharp@3.24.24.38
giosharp@3.24.24.38
glibsharp@3.24.24.38
gtksharp@3.24.24.38
iced@1.17.0
microsoft.bcl.asyncinterfaces@1.1.0
microsoft.bcl.asyncinterfaces@6.0.0
microsoft.codeanalysis.analyzers@2.6.2-beta2
microsoft.codeanalysis.common@3.0.0
microsoft.codeanalysis.csharp@3.0.0
microsoft.codecoverage@17.4.1
microsoft.diagnostics.netcore.client@0.2.251802
microsoft.diagnostics.runtime@2.2.332302
microsoft.diagnostics.tracing.traceevent@3.0.2
microsoft.dotnet.platformabstractions@3.1.6
microsoft.extensions.configuration.abstractions@2.1.1
microsoft.extensions.configuration.binder@2.1.1
microsoft.extensions.configuration@2.1.1
microsoft.extensions.dependencyinjection.abstractions@2.1.1
microsoft.extensions.logging.abstractions@2.1.1
microsoft.extensions.logging@2.1.1
microsoft.extensions.options@2.1.1
microsoft.extensions.primitives@2.1.1
microsoft.net.test.sdk@17.4.1
microsoft.netcore.platforms@1.1.0
microsoft.netcore.platforms@2.0.0
microsoft.testplatform.objectmodel@17.4.1
microsoft.testplatform.testhost@17.4.1
netstandard.library@2.0.0
newtonsoft.json@13.0.1
ngettext@0.6.7
nuget.frameworks@5.11.0
nunit3testadapter@4.3.1
nunit@3.13.3
pangosharp@3.24.24.38
paragonclipper@6.4.2
perfolizer@0.2.1
sharpziplib@1.4.1
system.codedom@6.0.0
system.collections.immutable@1.5.0
system.collections.immutable@5.0.0
system.management@6.0.0
system.memory@4.5.1
system.memory@4.5.3
system.reflection.emit.lightweight@4.7.0
system.reflection.emit@4.7.0
system.reflection.metadata@1.6.0
system.runtime.compilerservices.unsafe@4.5.0
system.runtime.compilerservices.unsafe@4.5.3
system.runtime.compilerservices.unsafe@5.0.0
system.security.principal.windows@4.7.0
system.text.encoding.codepages@4.5.0
system.threading.tasks.extensions@4.5.4
tmds.dbus@0.11.0
"

inherit autotools dotnet-pkg xdg

DESCRIPTION="Pinta is a free, open source program for drawing and image editing"
HOMEPAGE="https://www.pinta-project.com/
	https://github.com/PintaProject/Pinta/"

if [[ "${PV}" == *9999* ]] ; then
	inherit git-r3

	EGIT_REPO_URI="https://github.com/PintaProject/${PN^}.git"
else
	SRC_URI="https://github.com/PintaProject/${PN^}/archive/${PV}.tar.gz
		-> ${P}.tar.gz"
	S="${WORKDIR}/${P^}"

	KEYWORDS="amd64"
fi

SRC_URI+=" ${NUGET_URIS} "

LICENSE="MIT"
SLOT="0"

RDEPEND="
	 x11-libs/gtk+:3[introspection]
"
BDEPEND="
	${RDEPEND}
	dev-util/intltool
"

src_unpack() {
	dotnet-pkg_src_unpack

	if [[ -n "${EGIT_REPO_URI}" ]] ; then
		git-r3_src_unpack
	fi
}

src_prepare() {
	default

	eautoreconf
}

src_configure() {
	econf

	dotnet-pkg_src_configure
}

src_compile() {
	emake
}

src_install() {
	emake DESTDIR="${ED}" install

	local pinta_home="/usr/$(get_libdir)/${PN}"

	mv "${ED}/usr/bin/pinta" "${ED}/${pinta_home}" || die
	sed -e 's|dotnet|${DOTNET_ROOT}/dotnet|g' -i "${ED}/${pinta_home}/pinta" \
		|| die                                              # No interpolation!
	dotnet-pkg-base_dolauncher "${pinta_home}/${PN}" "${PN}"

	rm "${ED}/usr/share/man/man1/${PN}.1.gz" || die
	doman xdg/${PN}.1
}