blob: b08f76f5d66f715ba25997d6cb10721ff14b5037 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson
DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors"
HOMEPAGE="https://github.com/Alexays/Waybar"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
else
SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64"
S="${WORKDIR}/${PN^}-${PV}"
fi
LICENSE="MIT"
SLOT="0"
IUSE="evdev experimental jack libinput logind mpd mpris network +popups pipewire pulseaudio sndio test tray +udev upower wifi"
RESTRICT="!test? ( test )"
BDEPEND="
>=app-text/scdoc-1.9.2
dev-util/gdbus-codegen
virtual/pkgconfig
"
RDEPEND="
dev-cpp/cairomm:0
dev-cpp/glibmm:2
dev-cpp/gtkmm:3.0
dev-libs/glib:2
dev-libs/jsoncpp:=
dev-libs/libinput:=
dev-libs/libsigc++:2
>=dev-libs/libfmt-7.0.0:=
>=dev-libs/spdlog-1.8.5:=
dev-libs/date:=
dev-libs/wayland
gui-libs/wlroots:=
x11-libs/gtk+:3[wayland]
x11-libs/libxkbcommon
evdev? ( dev-libs/libevdev:= )
jack? ( virtual/jack )
libinput? ( dev-libs/libinput:= )
logind? (
|| ( sys-apps/systemd
sys-auth/elogind )
)
mpd? ( media-libs/libmpdclient )
mpris? ( >=media-sound/playerctl-2 )
network? ( dev-libs/libnl:3 )
popups? ( gui-libs/gtk-layer-shell )
pipewire? ( media-video/wireplumber:0/0.4 )
pulseaudio? ( media-sound/pulseaudio[daemon] )
sndio? ( media-sound/sndio:= )
tray? (
dev-libs/libdbusmenu[gtk3]
dev-libs/libappindicator
)
udev? ( virtual/libudev:= )
upower? ( sys-power/upower )
wifi? ( sys-apps/util-linux )
"
DEPEND="${RDEPEND}
dev-libs/wayland-protocols
test? ( dev-cpp/catch:0 )
"
PATCHES=(
"${FILESDIR}/systemd-0.9.17.patch"
)
src_configure() {
local emesonargs=(
-Dman-pages=enabled
-Dsystemd=enabled
$(meson_feature evdev libevdev)
$(meson_feature jack)
$(meson_feature libinput)
$(meson_feature logind)
$(meson_feature mpd)
$(meson_feature mpris)
$(meson_feature network libnl)
$(meson_feature popups gtk-layer-shell)
$(meson_feature pulseaudio)
$(meson_feature pipewire wireplumber)
$(meson_feature sndio)
$(meson_feature test tests)
$(meson_feature tray dbusmenu-gtk)
$(meson_feature udev libudev)
$(meson_feature upower upower_glib)
$(meson_feature wifi rfkill)
$(meson_use experimental)
)
meson_src_configure
}
|