blob: 064e5677230617480abd89b877e3b0ca350a07b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit flag-o-matic python-any-r1 xdg cmake
DESCRIPTION="A PSP emulator written in C++"
HOMEPAGE="https://www.ppsspp.org/
https://github.com/hrydgard/ppsspp/"
SRC_URI="https://github.com/hrydgard/${PN}/releases/download/v${PV}/${P}.tar.xz"
LICENSE="Apache-2.0 BSD BSD-2 GPL-2 JSON MIT"
SLOT="0"
KEYWORDS="amd64"
IUSE="discord qt5 test"
RESTRICT="!test? ( test )"
RDEPEND="
app-arch/snappy:=
app-arch/zstd:=
dev-libs/libzip:=
media-libs/glew:=
media-libs/libpng:=
media-libs/libsdl2[joystick]
media-video/ffmpeg:0/56.58.58
sys-libs/zlib:=
virtual/opengl
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5[-gles2-only]
dev-qt/qtmultimedia:5[-gles2-only]
dev-qt/qtopengl:5[-gles2-only]
dev-qt/qtwidgets:5[-gles2-only]
)
!qt5? ( media-libs/libsdl2[X,opengl,sound,video] )
"
DEPEND="${RDEPEND}"
BDEPEND="${PYTHON_DEPS}"
PATCHES=(
"${FILESDIR}"/${PN}-CMakeLists-flags.patch
"${FILESDIR}"/${PN}-disable-ccache-autodetection.patch
"${FILESDIR}"/${PN}-1.15.4-backport-ce83fec.patch
)
pkg_setup() {
python-any-r1_pkg_setup
}
src_configure() {
# bug https://bugs.gentoo.org/926079
filter-lto
local -a mycmakeargs=(
-DBUILD_SHARED_LIBS=OFF
-DCMAKE_SKIP_RPATH=ON
-DHEADLESS=false
-DUSE_SYSTEM_FFMPEG=ON
-DUSE_SYSTEM_LIBZIP=ON
-DUSE_SYSTEM_SNAPPY=ON
-DUSE_SYSTEM_ZSTD=ON
-DUSE_DISCORD=$(usex discord)
-DUSING_QT_UI=$(usex qt5)
-DUNITTEST=$(usex test)
)
cmake_src_configure
}
src_test() {
cmake_src_test -E glslang-testsuite
}
|
