blob: 5372479ee926395ca0279fa9a245b1eb2d6393f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1
MY_P=python-xmlsec-${PV}
DESCRIPTION="Python bindings for the XML Security Library"
HOMEPAGE="
https://github.com/xmlsec/python-xmlsec/
https://pypi.org/project/xmlsec/
"
SRC_URI="
https://github.com/xmlsec/python-xmlsec/archive/${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
DEPEND="
dev-libs/xmlsec:=[openssl]
"
RDEPEND="
${DEPEND}
dev-python/lxml[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/pkgconfig[${PYTHON_USEDEP}]
dev-python/setuptools-scm[${PYTHON_USEDEP}]
dev-python/wheel[${PYTHON_USEDEP}]
test? (
dev-python/hypothesis[${PYTHON_USEDEP}]
)
"
EPYTEST_DESELECT=(
# Fragile based on black version?
tests/test_type_stubs.py::test_xmlsec_constants_stub
)
distutils_enable_tests pytest
src_configure() {
export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
export PYXMLSEC_OPTIMIZE_SIZE=
if use debug; then
# we don't want to use PYXMLSEC_ENABLE_DEBUG envvar,
# as it forces -O0
export CPPFLAGS="${CPPFLAGS} -DPYXMLSEC_ENABLE_DEBUG=1"
fi
}
|
