blob: 7b1d4ea364a6e64093d50fdee586f8e7d6218094 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
FORTRAN_NEEDED=fortran
DISTUTILS_USE_PEP517=meson-python
PYTHON_COMPAT=( python3_{9..11} )
PYTHON_REQ_USE="threads(+)"
inherit fortran-2 distutils-r1 multiprocessing
DESCRIPTION="Scientific algorithms library for Python"
HOMEPAGE="
https://scipy.org/
https://github.com/scipy/scipy/
https://pypi.org/project/scipy/
"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
# Need submodules, so git for now.
EGIT_REPO_URI="https://github.com/scipy/scipy"
EGIT_BRANCH="maintenance/$(ver_cut 1-2).x"
EGIT_SUBMODULES=( '*' )
else
# Upstream is often behind with doc updates
DOC_PV=1.10.0
MY_PV=${PV/_rc/rc}
MY_P=${PN}-${MY_PV}
SRC_URI="
mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz
doc? (
https://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-html-${DOC_PV}.zip
)"
S="${WORKDIR}"/${MY_P}
if [[ ${PV} != *rc* ]] ; then
KEYWORDS="~amd64 arm ~arm64 -hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
fi
fi
LICENSE="BSD LGPL-2"
SLOT="0"
IUSE="doc +fortran test-rust"
# umfpack is technically optional but it's preferred to have it available.
DEPEND="
>=dev-python/numpy-1.19.5[lapack,${PYTHON_USEDEP}]
sci-libs/arpack:=
sci-libs/umfpack
virtual/cblas
>=virtual/lapack-3.8
"
RDEPEND="
${DEPEND}
dev-python/pillow[${PYTHON_USEDEP}]
"
BDEPEND="
dev-lang/swig
>=dev-python/cython-0.29.18[${PYTHON_USEDEP}]
>=dev-python/meson-python-0.11[${PYTHON_USEDEP}]
dev-python/pybind11[${PYTHON_USEDEP}]
>=dev-util/meson-0.62.2
dev-util/patchelf
virtual/pkgconfig
doc? ( app-arch/unzip )
fortran? ( dev-python/pythran[${PYTHON_USEDEP}] )
test? (
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
test-rust? (
dev-python/pooch[${PYTHON_USEDEP}]
)
"
EPYTEST_DESELECT=(
linalg/tests/test_decomp.py::TestSchur::test_sort
linalg/tests/test_solvers.py::test_solve_discrete_are
optimize/tests/test_milp.py::test_milp_timeout_16545
# Network
datasets/tests/test_data.py::TestDatasets::test_existence_all
datasets/tests/test_data.py::TestDatasets::test_ascent
datasets/tests/test_data.py::TestDatasets::test_face
datasets/tests/test_data.py::TestDatasets::test_electrocardiogram
)
distutils_enable_tests pytest
src_unpack() {
default
if use doc; then
unzip -qo "${DISTDIR}"/${PN}-html-${DOC_PV}.zip -d html || die
fi
}
python_configure_all() {
export SCIPY_USE_PYTHRAN=$(usex fortran 1 0)
DISTUTILS_ARGS=(
-Dblas=blas
-Dlapack=lapack
)
}
python_test() {
cd "${T}" || die
if ! has_version -b "dev-python/pooch[${PYTHON_USEDEP}]" ; then
EPYTEST_IGNORE+=(
datasets/tests/test_data.py
)
fi
epytest -n "$(makeopts_jobs)" --pyargs scipy
}
python_install_all() {
use doc && local HTML_DOCS=( "${WORKDIR}"/html/. )
distutils-r1_python_install_all
}
|