blob: c2e7d49eaf06f81846375827d11adbe88ecbf7b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 pypi
DESCRIPTION="Improved build system generator for Python C/C++/Fortran/Cython extensions"
HOMEPAGE="
https://github.com/scikit-build/scikit-build/
https://pypi.org/project/scikit-build/
"
SLOT="0"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/distro[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
>=dev-python/setuptools-42.0.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/tomli[${PYTHON_USEDEP}]
' 3.{9..10})
>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
dev-python/hatch-vcs[${PYTHON_USEDEP}]
test? (
>=dev-python/build-0.7[${PYTHON_USEDEP}]
>=dev-python/cython-0.25.1[${PYTHON_USEDEP}]
>=dev-python/pytest-mock-1.10.4[${PYTHON_USEDEP}]
>=dev-python/pytest-virtualenv-1.2.5[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/virtualenv[${PYTHON_USEDEP}]
)
"
distutils_enable_sphinx docs \
dev-python/sphinx-rtd-theme \
dev-python/sphinx-issues
distutils_enable_tests pytest
src_prepare() {
# not packaged
sed -i -e '/cmakedomain/d' docs/conf.py || die
distutils-r1_src_prepare
}
python_test() {
epytest -m "not isolated and not nosetuptoolsscm"
rm -r "${BUILD_DIR}/install$(python_get_sitedir)"/{easy-install.pth,*.egg,*.egg-link} || die
}
|
