blob: 4915685b8472c5b14d3b48ae5ce0021a1cf6c0d0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYTHON_COMPAT=( python3_{10..12} )
PYTHON_REQ_USE="xml(+)"
inherit distutils-r1 pypi
DESCRIPTION="Easily create mock objects on D-Bus for software testing"
HOMEPAGE="
https://github.com/martinpitt/python-dbusmock/
https://pypi.org/project/python-dbusmock/
"
LICENSE="LGPL-3+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/dbus-python[${PYTHON_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}]
"
distutils_enable_tests pytest
EPYTEST_IGNORE=(
# linter tests, fragile to newer linter versions
tests/test_code.py
)
src_prepare() {
# dev-python/dbus-python uses autotools, so no .dist-info there
sed -i '/dbus-python/d' pyproject.toml setup.cfg || die
distutils-r1_src_prepare
}
python_test() {
# Tests break if XDG_DATA_DIRS is modified by flatpak install
unset XDG_DATA_DIRS
distutils-r1_python_test
}
|
