blob: 33f15293fb0196eafa3222e8aad41e61e49303a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYTHON_COMPAT=( python3_{10..12} )
PYTHON_REQ_USE="xml(+)"
inherit distutils-r1 pypi
DESCRIPTION="Easily create mock objects on D-Bus for software testing"
HOMEPAGE="
https://github.com/martinpitt/python-dbusmock/
https://pypi.org/project/python-dbusmock/
"
LICENSE="LGPL-3+"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
RDEPEND="
dev-python/dbus-python[${PYTHON_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
sys-power/upower
)
"
distutils_enable_tests pytest
EPYTEST_IGNORE=(
# linter tests, fragile to newer linter versions
tests/test_code.py
)
src_prepare() {
# dev-python/dbus-python uses autotools, so no .dist-info there
sed -i '/dbus-python/d' pyproject.toml setup.cfg || die
distutils-r1_src_prepare
}
python_test() {
# tests are fragile to long socket paths
local -x TMPDIR=/tmp
# Tests break if XDG_DATA_DIRS is modified by flatpak install
unset XDG_DATA_DIRS
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest
}
|
